summaryrefslogtreecommitdiff
path: root/src/vm_ppcspe.dasc
diff options
context:
space:
mode:
Diffstat (limited to 'src/vm_ppcspe.dasc')
-rw-r--r--src/vm_ppcspe.dasc3705
1 files changed, 3705 insertions, 0 deletions
diff --git a/src/vm_ppcspe.dasc b/src/vm_ppcspe.dasc
new file mode 100644
index 00000000..a7ef3ccd
--- /dev/null
+++ b/src/vm_ppcspe.dasc
@@ -0,0 +1,3705 @@
1|// Low-level VM code for PowerPC/e500 CPUs.
2|// Bytecode interpreter, fast functions and helper functions.
3|// Copyright (C) 2005-2012 Mike Pall. See Copyright Notice in luajit.h
4|
5|.arch ppc
6|.section code_op, code_sub
7|
8|.actionlist build_actionlist
9|.globals GLOB_
10|.globalnames globnames
11|.externnames extnames
12|
13|// Note: The ragged indentation of the instructions is intentional.
14|// The starting columns indicate data dependencies.
15|
16|//-----------------------------------------------------------------------
17|
18|// Fixed register assignments for the interpreter.
19|// Don't use: r1 = sp, r2 and r13 = reserved and/or small data area ptr
20|
21|// The following must be C callee-save (but BASE is often refetched).
22|.define BASE, r14 // Base of current Lua stack frame.
23|.define KBASE, r15 // Constants of current Lua function.
24|.define PC, r16 // Next PC.
25|.define DISPATCH, r17 // Opcode dispatch table.
26|.define LREG, r18 // Register holding lua_State (also in SAVE_L).
27|.define MULTRES, r19 // Size of multi-result: (nresults+1)*8.
28|
29|// Constants for vectorized type-comparisons (hi+low GPR). C callee-save.
30|.define TISNUM, r22
31|.define TISSTR, r23
32|.define TISTAB, r24
33|.define TISFUNC, r25
34|.define TISNIL, r26
35|.define TOBIT, r27
36|.define ZERO, TOBIT // Zero in lo word.
37|
38|// The following temporaries are not saved across C calls, except for RA.
39|.define RA, r20 // Callee-save.
40|.define RB, r10
41|.define RC, r11
42|.define RD, r12
43|.define INS, r7 // Overlaps CARG5.
44|
45|.define TMP0, r0
46|.define TMP1, r8
47|.define TMP2, r9
48|.define TMP3, r6 // Overlaps CARG4.
49|
50|// Saved temporaries.
51|.define SAVE0, r21
52|
53|// Calling conventions.
54|.define CARG1, r3
55|.define CARG2, r4
56|.define CARG3, r5
57|.define CARG4, r6 // Overlaps TMP3.
58|.define CARG5, r7 // Overlaps INS.
59|
60|.define CRET1, r3
61|.define CRET2, r4
62|
63|// Stack layout while in interpreter. Must match with lj_frame.h.
64|.define SAVE_LR, 188(sp)
65|.define CFRAME_SPACE, 184 // Delta for sp.
66|// Back chain for sp: 184(sp) <-- sp entering interpreter
67|.define SAVE_r31, 176(sp) // 64 bit register saves.
68|.define SAVE_r30, 168(sp)
69|.define SAVE_r29, 160(sp)
70|.define SAVE_r28, 152(sp)
71|.define SAVE_r27, 144(sp)
72|.define SAVE_r26, 136(sp)
73|.define SAVE_r25, 128(sp)
74|.define SAVE_r24, 120(sp)
75|.define SAVE_r23, 112(sp)
76|.define SAVE_r22, 104(sp)
77|.define SAVE_r21, 96(sp)
78|.define SAVE_r20, 88(sp)
79|.define SAVE_r19, 80(sp)
80|.define SAVE_r18, 72(sp)
81|.define SAVE_r17, 64(sp)
82|.define SAVE_r16, 56(sp)
83|.define SAVE_r15, 48(sp)
84|.define SAVE_r14, 40(sp)
85|.define SAVE_CR, 36(sp)
86|.define UNUSED1, 32(sp)
87|.define SAVE_ERRF, 28(sp) // 32 bit C frame info.
88|.define SAVE_NRES, 24(sp)
89|.define SAVE_CFRAME, 20(sp)
90|.define SAVE_L, 16(sp)
91|.define SAVE_PC, 12(sp)
92|.define SAVE_MULTRES, 8(sp)
93|// Next frame lr: 4(sp)
94|// Back chain for sp: 0(sp) <-- sp while in interpreter
95|
96|.macro save_, reg; evstdd reg, SAVE_..reg; .endmacro
97|.macro rest_, reg; evldd reg, SAVE_..reg; .endmacro
98|
99|.macro saveregs
100| stwu sp, -CFRAME_SPACE(sp)
101| save_ r14; save_ r15; save_ r16; save_ r17; save_ r18; save_ r19
102| mflr r0; mfcr r12
103| save_ r20; save_ r21; save_ r22; save_ r23; save_ r24; save_ r25
104| stw r0, SAVE_LR; stw r12, SAVE_CR
105| save_ r26; save_ r27; save_ r28; save_ r29; save_ r30; save_ r31
106|.endmacro
107|
108|.macro restoreregs
109| lwz r0, SAVE_LR; lwz r12, SAVE_CR
110| rest_ r14; rest_ r15; rest_ r16; rest_ r17; rest_ r18; rest_ r19
111| mtlr r0; mtcrf 0x38, r12
112| rest_ r20; rest_ r21; rest_ r22; rest_ r23; rest_ r24; rest_ r25
113| rest_ r26; rest_ r27; rest_ r28; rest_ r29; rest_ r30; rest_ r31
114| addi sp, sp, CFRAME_SPACE
115|.endmacro
116|
117|// Type definitions. Some of these are only used for documentation.
118|.type L, lua_State, LREG
119|.type GL, global_State
120|.type TVALUE, TValue
121|.type GCOBJ, GCobj
122|.type STR, GCstr
123|.type TAB, GCtab
124|.type LFUNC, GCfuncL
125|.type CFUNC, GCfuncC
126|.type PROTO, GCproto
127|.type UPVAL, GCupval
128|.type NODE, Node
129|.type NARGS8, int
130|.type TRACE, GCtrace
131|
132|//-----------------------------------------------------------------------
133|
134|// These basic macros should really be part of DynASM.
135|.macro srwi, rx, ry, n; rlwinm rx, ry, 32-n, n, 31; .endmacro
136|.macro slwi, rx, ry, n; rlwinm rx, ry, n, 0, 31-n; .endmacro
137|.macro rotlwi, rx, ry, n; rlwinm rx, ry, n, 0, 31; .endmacro
138|.macro rotlw, rx, ry, rn; rlwnm rx, ry, rn, 0, 31; .endmacro
139|.macro subi, rx, ry, i; addi rx, ry, -i; .endmacro
140|
141|// Trap for not-yet-implemented parts.
142|.macro NYI; tw 4, sp, sp; .endmacro
143|
144|//-----------------------------------------------------------------------
145|
146|// Access to frame relative to BASE.
147|.define FRAME_PC, -8
148|.define FRAME_FUNC, -4
149|
150|// Instruction decode.
151|.macro decode_OP4, dst, ins; rlwinm dst, ins, 2, 22, 29; .endmacro
152|.macro decode_RA8, dst, ins; rlwinm dst, ins, 27, 21, 28; .endmacro
153|.macro decode_RB8, dst, ins; rlwinm dst, ins, 11, 21, 28; .endmacro
154|.macro decode_RC8, dst, ins; rlwinm dst, ins, 19, 21, 28; .endmacro
155|.macro decode_RD8, dst, ins; rlwinm dst, ins, 19, 13, 28; .endmacro
156|
157|.macro decode_OP1, dst, ins; rlwinm dst, ins, 0, 24, 31; .endmacro
158|.macro decode_RD4, dst, ins; rlwinm dst, ins, 18, 14, 29; .endmacro
159|
160|// Instruction fetch.
161|.macro ins_NEXT1
162| lwz INS, 0(PC)
163| addi PC, PC, 4
164|.endmacro
165|// Instruction decode+dispatch.
166|.macro ins_NEXT2
167| decode_OP4 TMP1, INS
168| decode_RB8 RB, INS
169| decode_RD8 RD, INS
170| lwzx TMP0, DISPATCH, TMP1
171| decode_RA8 RA, INS
172| decode_RC8 RC, INS
173| mtctr TMP0
174| bctr
175|.endmacro
176|.macro ins_NEXT
177| ins_NEXT1
178| ins_NEXT2
179|.endmacro
180|
181|// Instruction footer.
182|.if 1
183| // Replicated dispatch. Less unpredictable branches, but higher I-Cache use.
184| .define ins_next, ins_NEXT
185| .define ins_next_, ins_NEXT
186| .define ins_next1, ins_NEXT1
187| .define ins_next2, ins_NEXT2
188|.else
189| // Common dispatch. Lower I-Cache use, only one (very) unpredictable branch.
190| // Affects only certain kinds of benchmarks (and only with -j off).
191| .macro ins_next
192| b ->ins_next
193| .endmacro
194| .macro ins_next1
195| .endmacro
196| .macro ins_next2
197| b ->ins_next
198| .endmacro
199| .macro ins_next_
200| ->ins_next:
201| ins_NEXT
202| .endmacro
203|.endif
204|
205|// Call decode and dispatch.
206|.macro ins_callt
207| // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
208| lwz PC, LFUNC:RB->pc
209| lwz INS, 0(PC)
210| addi PC, PC, 4
211| decode_OP4 TMP1, INS
212| decode_RA8 RA, INS
213| lwzx TMP0, DISPATCH, TMP1
214| add RA, RA, BASE
215| mtctr TMP0
216| bctr
217|.endmacro
218|
219|.macro ins_call
220| // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, PC = caller PC
221| stw PC, FRAME_PC(BASE)
222| ins_callt
223|.endmacro
224|
225|//-----------------------------------------------------------------------
226|
227|// Macros to test operand types.
228|.macro checknum, reg; evcmpltu reg, TISNUM; .endmacro
229|.macro checkstr, reg; evcmpeq reg, TISSTR; .endmacro
230|.macro checktab, reg; evcmpeq reg, TISTAB; .endmacro
231|.macro checkfunc, reg; evcmpeq reg, TISFUNC; .endmacro
232|.macro checknil, reg; evcmpeq reg, TISNIL; .endmacro
233|.macro checkok, label; blt label; .endmacro
234|.macro checkfail, label; bge label; .endmacro
235|.macro checkanyfail, label; bns label; .endmacro
236|.macro checkallok, label; bso label; .endmacro
237|
238|.macro branch_RD
239| srwi TMP0, RD, 1
240| add PC, PC, TMP0
241| addis PC, PC, -(BCBIAS_J*4 >> 16)
242|.endmacro
243|
244|// Assumes DISPATCH is relative to GL.
245#define DISPATCH_GL(field) (GG_DISP2G + (int)offsetof(global_State, field))
246#define DISPATCH_J(field) (GG_DISP2J + (int)offsetof(jit_State, field))
247|
248#define PC2PROTO(field) ((int)offsetof(GCproto, field)-(int)sizeof(GCproto))
249|
250|.macro hotloop
251| NYI
252|.endmacro
253|
254|.macro hotcall
255| NYI
256|.endmacro
257|
258|// Set current VM state. Uses TMP0.
259|.macro li_vmstate, st; li TMP0, ~LJ_VMST_..st; .endmacro
260|.macro st_vmstate; stw TMP0, DISPATCH_GL(vmstate)(DISPATCH); .endmacro
261|
262|// Move table write barrier back. Overwrites mark and tmp.
263|.macro barrierback, tab, mark, tmp
264| lwz tmp, DISPATCH_GL(gc.grayagain)(DISPATCH)
265| // Assumes LJ_GC_BLACK is 0x04.
266| rlwinm mark, mark, 0, 30, 28 // black2gray(tab)
267| stw tab, DISPATCH_GL(gc.grayagain)(DISPATCH)
268| stb mark, tab->marked
269| stw tmp, tab->gclist
270|.endmacro
271|
272|//-----------------------------------------------------------------------
273
274/* Generate subroutines used by opcodes and other parts of the VM. */
275/* The .code_sub section should be last to help static branch prediction. */
276static void build_subroutines(BuildCtx *ctx)
277{
278 |.code_sub
279 |
280 |//-----------------------------------------------------------------------
281 |//-- Return handling ----------------------------------------------------
282 |//-----------------------------------------------------------------------
283 |
284 |->vm_returnp:
285 | // See vm_return. Also: TMP2 = previous base.
286 | andi. TMP0, PC, FRAME_P
287 | evsplati TMP1, LJ_TTRUE
288 | beq ->cont_dispatch
289 |
290 | // Return from pcall or xpcall fast func.
291 | lwz PC, FRAME_PC(TMP2) // Fetch PC of previous frame.
292 | mr BASE, TMP2 // Restore caller base.
293 | // Prepending may overwrite the pcall frame, so do it at the end.
294 | stwu TMP1, FRAME_PC(RA) // Prepend true to results.
295 |
296 |->vm_returnc:
297 | andi. TMP0, PC, FRAME_TYPE
298 | addi RD, RD, 8 // RD = (nresults+1)*8.
299 | mr MULTRES, RD
300 | beq ->BC_RET_Z // Handle regular return to Lua.
301 |
302 |->vm_return:
303 | // BASE = base, RA = resultptr, RD/MULTRES = (nresults+1)*8, PC = return
304 | // TMP0 = PC & FRAME_TYPE
305 | cmpwi TMP0, FRAME_C
306 | rlwinm TMP2, PC, 0, 0, 28
307 | li_vmstate C
308 | sub TMP2, BASE, TMP2 // TMP2 = previous base.
309 | bne ->vm_returnp
310 |
311 | addic. TMP1, RD, -8
312 | stw TMP2, L->base
313 | lwz TMP2, SAVE_NRES
314 | subi BASE, BASE, 8
315 | st_vmstate
316 | slwi TMP2, TMP2, 3
317 | beq >2
318 |1:
319 | addic. TMP1, TMP1, -8
320 | evldd TMP0, 0(RA)
321 | addi RA, RA, 8
322 | evstdd TMP0, 0(BASE)
323 | addi BASE, BASE, 8
324 | bne <1
325 |
326 |2:
327 | cmpw TMP2, RD // More/less results wanted?
328 | bne >6
329 |3:
330 | stw BASE, L->top // Store new top.
331 |
332 |->vm_leave_cp:
333 | lwz TMP0, SAVE_CFRAME // Restore previous C frame.
334 | li CRET1, 0 // Ok return status for vm_pcall.
335 | stw TMP0, L->cframe
336 |
337 |->vm_leave_unw:
338 | restoreregs
339 | blr
340 |
341 |6:
342 | ble >7 // Less results wanted?
343 | // More results wanted. Check stack size and fill up results with nil.
344 | lwz TMP1, L->maxstack
345 | cmplw BASE, TMP1
346 | bge >8
347 | evstdd TISNIL, 0(BASE)
348 | addi RD, RD, 8
349 | addi BASE, BASE, 8
350 | b <2
351 |
352 |7: // Less results wanted.
353 | sub TMP0, RD, TMP2
354 | cmpwi TMP2, 0 // LUA_MULTRET+1 case?
355 | sub TMP0, BASE, TMP0 // Subtract the difference.
356 | iseleq BASE, BASE, TMP0 // Either keep top or shrink it.
357 | b <3
358 |
359 |8: // Corner case: need to grow stack for filling up results.
360 | // This can happen if:
361 | // - A C function grows the stack (a lot).
362 | // - The GC shrinks the stack in between.
363 | // - A return back from a lua_call() with (high) nresults adjustment.
364 | stw BASE, L->top // Save current top held in BASE (yes).
365 | mr SAVE0, RD
366 | mr CARG2, TMP2
367 | mr CARG1, L
368 | bl extern lj_state_growstack // (lua_State *L, int n)
369 | lwz TMP2, SAVE_NRES
370 | mr RD, SAVE0
371 | slwi TMP2, TMP2, 3
372 | lwz BASE, L->top // Need the (realloced) L->top in BASE.
373 | b <2
374 |
375 |->vm_unwind_c: // Unwind C stack, return from vm_pcall.
376 | // (void *cframe, int errcode)
377 | mr sp, CARG1
378 | mr CRET1, CARG2
379 |->vm_unwind_c_eh: // Landing pad for external unwinder.
380 | lwz L, SAVE_L
381 | li TMP0, ~LJ_VMST_C
382 | lwz GL:TMP1, L->glref
383 | stw TMP0, GL:TMP1->vmstate
384 | b ->vm_leave_unw
385 |
386 |->vm_unwind_ff: // Unwind C stack, return from ff pcall.
387 | // (void *cframe)
388 | rlwinm sp, CARG1, 0, 0, 29
389 |->vm_unwind_ff_eh: // Landing pad for external unwinder.
390 | lwz L, SAVE_L
391 | evsplati TISNUM, LJ_TISNUM+1 // Setup type comparison constants.
392 | evsplati TISFUNC, LJ_TFUNC
393 | lus TOBIT, 0x4338
394 | evsplati TISTAB, LJ_TTAB
395 | li TMP0, 0
396 | lwz BASE, L->base
397 | evmergelo TOBIT, TOBIT, TMP0
398 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
399 | evsplati TISSTR, LJ_TSTR
400 | li TMP1, LJ_TFALSE
401 | evsplati TISNIL, LJ_TNIL
402 | li_vmstate INTERP
403 | lwz PC, FRAME_PC(BASE) // Fetch PC of previous frame.
404 | la RA, -8(BASE) // Results start at BASE-8.
405 | addi DISPATCH, DISPATCH, GG_G2DISP
406 | stw TMP1, 0(RA) // Prepend false to error message.
407 | li RD, 16 // 2 results: false + error message.
408 | st_vmstate
409 | b ->vm_returnc
410 |
411 |//-----------------------------------------------------------------------
412 |//-- Grow stack for calls -----------------------------------------------
413 |//-----------------------------------------------------------------------
414 |
415 |->vm_growstack_c: // Grow stack for C function.
416 | li CARG2, LUA_MINSTACK
417 | b >2
418 |
419 |->vm_growstack_l: // Grow stack for Lua function.
420 | // BASE = new base, RA = BASE+framesize*8, RC = nargs*8, PC = first PC
421 | add RC, BASE, RC
422 | sub RA, RA, BASE
423 | stw BASE, L->base
424 | addi PC, PC, 4 // Must point after first instruction.
425 | stw RC, L->top
426 | srwi CARG2, RA, 3
427 |2:
428 | // L->base = new base, L->top = top
429 | stw PC, SAVE_PC
430 | mr CARG1, L
431 | bl extern lj_state_growstack // (lua_State *L, int n)
432 | lwz BASE, L->base
433 | lwz RC, L->top
434 | lwz LFUNC:RB, FRAME_FUNC(BASE)
435 | sub RC, RC, BASE
436 | // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
437 | ins_callt // Just retry the call.
438 |
439 |//-----------------------------------------------------------------------
440 |//-- Entry points into the assembler VM ---------------------------------
441 |//-----------------------------------------------------------------------
442 |
443 |->vm_resume: // Setup C frame and resume thread.
444 | // (lua_State *L, TValue *base, int nres1 = 0, ptrdiff_t ef = 0)
445 | saveregs
446 | mr L, CARG1
447 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
448 | mr BASE, CARG2
449 | lbz TMP1, L->status
450 | stw L, SAVE_L
451 | li PC, FRAME_CP
452 | addi TMP0, sp, CFRAME_RESUME
453 | addi DISPATCH, DISPATCH, GG_G2DISP
454 | stw CARG3, SAVE_NRES
455 | cmplwi TMP1, 0
456 | stw CARG3, SAVE_ERRF
457 | stw TMP0, L->cframe
458 | stw CARG3, SAVE_CFRAME
459 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
460 | beq >3
461 |
462 | // Resume after yield (like a return).
463 | mr RA, BASE
464 | lwz BASE, L->base
465 | evsplati TISNUM, LJ_TISNUM+1 // Setup type comparison constants.
466 | lwz TMP1, L->top
467 | evsplati TISFUNC, LJ_TFUNC
468 | lus TOBIT, 0x4338
469 | evsplati TISTAB, LJ_TTAB
470 | lwz PC, FRAME_PC(BASE)
471 | li TMP2, 0
472 | evsplati TISSTR, LJ_TSTR
473 | sub RD, TMP1, BASE
474 | evmergelo TOBIT, TOBIT, TMP2
475 | stb CARG3, L->status
476 | andi. TMP0, PC, FRAME_TYPE
477 | li_vmstate INTERP
478 | addi RD, RD, 8
479 | evsplati TISNIL, LJ_TNIL
480 | mr MULTRES, RD
481 | st_vmstate
482 | beq ->BC_RET_Z
483 | b ->vm_return
484 |
485 |->vm_pcall: // Setup protected C frame and enter VM.
486 | // (lua_State *L, TValue *base, int nres1, ptrdiff_t ef)
487 | saveregs
488 | li PC, FRAME_CP
489 | stw CARG4, SAVE_ERRF
490 | b >1
491 |
492 |->vm_call: // Setup C frame and enter VM.
493 | // (lua_State *L, TValue *base, int nres1)
494 | saveregs
495 | li PC, FRAME_C
496 |
497 |1: // Entry point for vm_pcall above (PC = ftype).
498 | lwz TMP1, L:CARG1->cframe
499 | stw CARG3, SAVE_NRES
500 | mr L, CARG1
501 | stw CARG1, SAVE_L
502 | mr BASE, CARG2
503 | stw sp, L->cframe // Add our C frame to cframe chain.
504 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
505 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
506 | stw TMP1, SAVE_CFRAME
507 | addi DISPATCH, DISPATCH, GG_G2DISP
508 |
509 |3: // Entry point for vm_cpcall/vm_resume (BASE = base, PC = ftype).
510 | lwz TMP2, L->base // TMP2 = old base (used in vmeta_call).
511 | evsplati TISNUM, LJ_TISNUM+1 // Setup type comparison constants.
512 | lwz TMP1, L->top
513 | evsplati TISFUNC, LJ_TFUNC
514 | add PC, PC, BASE
515 | evsplati TISTAB, LJ_TTAB
516 | lus TOBIT, 0x4338
517 | li TMP0, 0
518 | sub PC, PC, TMP2 // PC = frame delta + frame type
519 | evsplati TISSTR, LJ_TSTR
520 | sub NARGS8:RC, TMP1, BASE
521 | evmergelo TOBIT, TOBIT, TMP0
522 | li_vmstate INTERP
523 | evsplati TISNIL, LJ_TNIL
524 | st_vmstate
525 |
526 |->vm_call_dispatch:
527 | // TMP2 = old base, BASE = new base, RC = nargs*8, PC = caller PC
528 | li TMP0, -8
529 | evlddx LFUNC:RB, BASE, TMP0
530 | checkfunc LFUNC:RB
531 | checkfail ->vmeta_call
532 |
533 |->vm_call_dispatch_f:
534 | ins_call
535 | // BASE = new base, RB = func, RC = nargs*8, PC = caller PC
536 |
537 |->vm_cpcall: // Setup protected C frame, call C.
538 | // (lua_State *L, lua_CFunction func, void *ud, lua_CPFunction cp)
539 | saveregs
540 | mr L, CARG1
541 | lwz TMP0, L:CARG1->stack
542 | stw CARG1, SAVE_L
543 | lwz TMP1, L->top
544 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
545 | sub TMP0, TMP0, TMP1 // Compute -savestack(L, L->top).
546 | lwz TMP1, L->cframe
547 | stw sp, L->cframe // Add our C frame to cframe chain.
548 | li TMP2, 0
549 | stw TMP0, SAVE_NRES // Neg. delta means cframe w/o frame.
550 | stw TMP2, SAVE_ERRF // No error function.
551 | stw TMP1, SAVE_CFRAME
552 | mtctr CARG4
553 | bctrl // (lua_State *L, lua_CFunction func, void *ud)
554 | mr. BASE, CRET1
555 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
556 | li PC, FRAME_CP
557 | addi DISPATCH, DISPATCH, GG_G2DISP
558 | bne <3 // Else continue with the call.
559 | b ->vm_leave_cp // No base? Just remove C frame.
560 |
561 |//-----------------------------------------------------------------------
562 |//-- Metamethod handling ------------------------------------------------
563 |//-----------------------------------------------------------------------
564 |
565 |// The lj_meta_* functions (except for lj_meta_cat) don't reallocate the
566 |// stack, so BASE doesn't need to be reloaded across these calls.
567 |
568 |//-- Continuation dispatch ----------------------------------------------
569 |
570 |->cont_dispatch:
571 | // BASE = meta base, RA = resultptr, RD = (nresults+1)*8
572 | lwz TMP0, -12(BASE) // Continuation.
573 | mr RB, BASE
574 | mr BASE, TMP2 // Restore caller BASE.
575 | lwz LFUNC:TMP1, FRAME_FUNC(TMP2)
576 | cmplwi TMP0, 0
577 | lwz PC, -16(RB) // Restore PC from [cont|PC].
578 | beq >1
579 | subi TMP2, RD, 8
580 | lwz TMP1, LFUNC:TMP1->pc
581 | evstddx TISNIL, RA, TMP2 // Ensure one valid arg.
582 | lwz KBASE, PC2PROTO(k)(TMP1)
583 | // BASE = base, RA = resultptr, RB = meta base
584 | mtctr TMP0
585 | bctr // Jump to continuation.
586 |
587 |1: // Tail call from C function.
588 | subi TMP1, RB, 16
589 | sub RC, TMP1, BASE
590 | b ->vm_call_tail
591 |
592 |->cont_cat: // RA = resultptr, RB = meta base
593 | lwz INS, -4(PC)
594 | subi CARG2, RB, 16
595 | decode_RB8 SAVE0, INS
596 | evldd TMP0, 0(RA)
597 | add TMP1, BASE, SAVE0
598 | stw BASE, L->base
599 | cmplw TMP1, CARG2
600 | sub CARG3, CARG2, TMP1
601 | decode_RA8 RA, INS
602 | evstdd TMP0, 0(CARG2)
603 | bne ->BC_CAT_Z
604 | evstddx TMP0, BASE, RA
605 | b ->cont_nop
606 |
607 |//-- Table indexing metamethods -----------------------------------------
608 |
609 |->vmeta_tgets1:
610 | evmergelo STR:RC, TISSTR, STR:RC
611 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
612 | decode_RB8 RB, INS
613 | evstdd STR:RC, 0(CARG3)
614 | add CARG2, BASE, RB
615 | b >1
616 |
617 |->vmeta_tgets:
618 | evmergelo TAB:RB, TISTAB, TAB:RB
619 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
620 | evmergelo STR:RC, TISSTR, STR:RC
621 | evstdd TAB:RB, 0(CARG2)
622 | la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
623 | evstdd STR:RC, 0(CARG3)
624 | b >1
625 |
626 |->vmeta_tgetb: // TMP0 = index
627 | efdcfsi TMP0, TMP0
628 | decode_RB8 RB, INS
629 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
630 | add CARG2, BASE, RB
631 | evstdd TMP0, 0(CARG3)
632 | b >1
633 |
634 |->vmeta_tgetv:
635 | decode_RB8 RB, INS
636 | decode_RC8 RC, INS
637 | add CARG2, BASE, RB
638 | add CARG3, BASE, RC
639 |1:
640 | stw BASE, L->base
641 | mr CARG1, L
642 | stw PC, SAVE_PC
643 | bl extern lj_meta_tget // (lua_State *L, TValue *o, TValue *k)
644 | // Returns TValue * (finished) or NULL (metamethod).
645 | cmplwi CRET1, 0
646 | beq >3
647 | evldd TMP0, 0(CRET1)
648 | evstddx TMP0, BASE, RA
649 | ins_next
650 |
651 |3: // Call __index metamethod.
652 | // BASE = base, L->top = new base, stack = cont/func/t/k
653 | subfic TMP1, BASE, FRAME_CONT
654 | lwz BASE, L->top
655 | stw PC, -16(BASE) // [cont|PC]
656 | add PC, TMP1, BASE
657 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
658 | li NARGS8:RC, 16 // 2 args for func(t, k).
659 | b ->vm_call_dispatch_f
660 |
661 |//-----------------------------------------------------------------------
662 |
663 |->vmeta_tsets1:
664 | evmergelo STR:RC, TISSTR, STR:RC
665 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
666 | decode_RB8 RB, INS
667 | evstdd STR:RC, 0(CARG3)
668 | add CARG2, BASE, RB
669 | b >1
670 |
671 |->vmeta_tsets:
672 | evmergelo TAB:RB, TISTAB, TAB:RB
673 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
674 | evmergelo STR:RC, TISSTR, STR:RC
675 | evstdd TAB:RB, 0(CARG2)
676 | la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
677 | evstdd STR:RC, 0(CARG3)
678 | b >1
679 |
680 |->vmeta_tsetb: // TMP0 = index
681 | efdcfsi TMP0, TMP0
682 | decode_RB8 RB, INS
683 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
684 | add CARG2, BASE, RB
685 | evstdd TMP0, 0(CARG3)
686 | b >1
687 |
688 |->vmeta_tsetv:
689 | decode_RB8 RB, INS
690 | decode_RC8 RC, INS
691 | add CARG2, BASE, RB
692 | add CARG3, BASE, RC
693 |1:
694 | stw BASE, L->base
695 | mr CARG1, L
696 | stw PC, SAVE_PC
697 | bl extern lj_meta_tset // (lua_State *L, TValue *o, TValue *k)
698 | // Returns TValue * (finished) or NULL (metamethod).
699 | cmplwi CRET1, 0
700 | evlddx TMP0, BASE, RA
701 | beq >3
702 | // NOBARRIER: lj_meta_tset ensures the table is not black.
703 | evstdd TMP0, 0(CRET1)
704 | ins_next
705 |
706 |3: // Call __newindex metamethod.
707 | // BASE = base, L->top = new base, stack = cont/func/t/k/(v)
708 | subfic TMP1, BASE, FRAME_CONT
709 | lwz BASE, L->top
710 | stw PC, -16(BASE) // [cont|PC]
711 | add PC, TMP1, BASE
712 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
713 | li NARGS8:RC, 24 // 3 args for func(t, k, v)
714 | evstdd TMP0, 16(BASE) // Copy value to third argument.
715 | b ->vm_call_dispatch_f
716 |
717 |//-- Comparison metamethods ---------------------------------------------
718 |
719 |->vmeta_comp:
720 | mr CARG1, L
721 | subi PC, PC, 4
722 | add CARG2, BASE, RA
723 | stw PC, SAVE_PC
724 | add CARG3, BASE, RD
725 | stw BASE, L->base
726 | decode_OP1 CARG4, INS
727 | bl extern lj_meta_comp // (lua_State *L, TValue *o1, *o2, int op)
728 | // Returns 0/1 or TValue * (metamethod).
729 |3:
730 | cmplwi CRET1, 1
731 | bgt ->vmeta_binop
732 |4:
733 | lwz INS, 0(PC)
734 | addi PC, PC, 4
735 | decode_RD4 TMP2, INS
736 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
737 | add TMP2, TMP2, TMP3
738 | isellt PC, PC, TMP2
739 |->cont_nop:
740 | ins_next
741 |
742 |->cont_ra: // RA = resultptr
743 | lwz INS, -4(PC)
744 | evldd TMP0, 0(RA)
745 | decode_RA8 TMP1, INS
746 | evstddx TMP0, BASE, TMP1
747 | b ->cont_nop
748 |
749 |->cont_condt: // RA = resultptr
750 | lwz TMP0, 0(RA)
751 | li TMP1, LJ_TTRUE
752 | cmplw TMP1, TMP0 // Branch if result is true.
753 | b <4
754 |
755 |->cont_condf: // RA = resultptr
756 | lwz TMP0, 0(RA)
757 | li TMP1, LJ_TFALSE
758 | cmplw TMP0, TMP1 // Branch if result is false.
759 | b <4
760 |
761 |->vmeta_equal:
762 | // CARG2, CARG3, CARG4 are already set by BC_ISEQV/BC_ISNEV.
763 | subi PC, PC, 4
764 | stw BASE, L->base
765 | mr CARG1, L
766 | stw PC, SAVE_PC
767 | bl extern lj_meta_equal // (lua_State *L, GCobj *o1, *o2, int ne)
768 | // Returns 0/1 or TValue * (metamethod).
769 | b <3
770 |
771 |//-- Arithmetic metamethods ---------------------------------------------
772 |
773 |->vmeta_arith_vn:
774 | add CARG3, BASE, RB
775 | add CARG4, KBASE, RC
776 | b >1
777 |
778 |->vmeta_arith_nv:
779 | add CARG3, KBASE, RC
780 | add CARG4, BASE, RB
781 | b >1
782 |
783 |->vmeta_unm:
784 | add CARG3, BASE, RD
785 | mr CARG4, CARG3
786 | b >1
787 |
788 |->vmeta_arith_vv:
789 | add CARG3, BASE, RB
790 | add CARG4, BASE, RC
791 |1:
792 | add CARG2, BASE, RA
793 | stw BASE, L->base
794 | mr CARG1, L
795 | stw PC, SAVE_PC
796 | decode_OP1 CARG5, INS // Caveat: CARG5 overlaps INS.
797 | bl extern lj_meta_arith // (lua_State *L, TValue *ra,*rb,*rc, BCReg op)
798 | // Returns NULL (finished) or TValue * (metamethod).
799 | cmplwi CRET1, 0
800 | beq ->cont_nop
801 |
802 | // Call metamethod for binary op.
803 |->vmeta_binop:
804 | // BASE = old base, CRET1 = new base, stack = cont/func/o1/o2
805 | sub TMP1, CRET1, BASE
806 | stw PC, -16(CRET1) // [cont|PC]
807 | mr TMP2, BASE
808 | addi PC, TMP1, FRAME_CONT
809 | mr BASE, CRET1
810 | li NARGS8:RC, 16 // 2 args for func(o1, o2).
811 | b ->vm_call_dispatch
812 |
813 |->vmeta_len:
814#ifdef LUAJIT_ENABLE_LUA52COMPAT
815 | mr SAVE0, CARG1
816#endif
817 | add CARG2, BASE, RD
818 | stw BASE, L->base
819 | mr CARG1, L
820 | stw PC, SAVE_PC
821 | bl extern lj_meta_len // (lua_State *L, TValue *o)
822 | // Returns NULL (retry) or TValue * (metamethod base).
823#ifdef LUAJIT_ENABLE_LUA52COMPAT
824 | cmplwi CRET1, 0
825 | bne ->vmeta_binop // Binop call for compatibility.
826 | mr CARG1, SAVE0
827 | b ->BC_LEN_Z
828#else
829 | b ->vmeta_binop // Binop call for compatibility.
830#endif
831 |
832 |//-- Call metamethod ----------------------------------------------------
833 |
834 |->vmeta_call: // Resolve and call __call metamethod.
835 | // TMP2 = old base, BASE = new base, RC = nargs*8
836 | mr CARG1, L
837 | stw TMP2, L->base // This is the callers base!
838 | subi CARG2, BASE, 8
839 | stw PC, SAVE_PC
840 | add CARG3, BASE, RC
841 | mr SAVE0, NARGS8:RC
842 | bl extern lj_meta_call // (lua_State *L, TValue *func, TValue *top)
843 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
844 | addi NARGS8:RC, SAVE0, 8 // Got one more argument now.
845 | ins_call
846 |
847 |->vmeta_callt: // Resolve __call for BC_CALLT.
848 | // BASE = old base, RA = new base, RC = nargs*8
849 | mr CARG1, L
850 | stw BASE, L->base
851 | subi CARG2, RA, 8
852 | stw PC, SAVE_PC
853 | add CARG3, RA, RC
854 | mr SAVE0, NARGS8:RC
855 | bl extern lj_meta_call // (lua_State *L, TValue *func, TValue *top)
856 | lwz TMP1, FRAME_PC(BASE)
857 | addi NARGS8:RC, SAVE0, 8 // Got one more argument now.
858 | lwz LFUNC:RB, FRAME_FUNC(RA) // Guaranteed to be a function here.
859 | b ->BC_CALLT_Z
860 |
861 |//-- Argument coercion for 'for' statement ------------------------------
862 |
863 |->vmeta_for:
864 | mr CARG1, L
865 | stw BASE, L->base
866 | mr CARG2, RA
867 | stw PC, SAVE_PC
868 | mr SAVE0, INS
869 | bl extern lj_meta_for // (lua_State *L, TValue *base)
870#if LJ_HASJIT
871 | decode_OP1 TMP0, SAVE0
872#endif
873 | decode_RA8 RA, SAVE0
874#if LJ_HASJIT
875 | cmpwi TMP0, BC_JFORI
876#endif
877 | decode_RD8 RD, SAVE0
878#if LJ_HASJIT
879 | beq =>BC_JFORI
880#endif
881 | b =>BC_FORI
882 |
883 |//-----------------------------------------------------------------------
884 |//-- Fast functions -----------------------------------------------------
885 |//-----------------------------------------------------------------------
886 |
887 |.macro .ffunc, name
888 |->ff_ .. name:
889 |.endmacro
890 |
891 |.macro .ffunc_1, name
892 |->ff_ .. name:
893 | cmplwi NARGS8:RC, 8
894 | evldd CARG1, 0(BASE)
895 | blt ->fff_fallback
896 |.endmacro
897 |
898 |.macro .ffunc_2, name
899 |->ff_ .. name:
900 | cmplwi NARGS8:RC, 16
901 | evldd CARG1, 0(BASE)
902 | evldd CARG2, 8(BASE)
903 | blt ->fff_fallback
904 |.endmacro
905 |
906 |.macro .ffunc_n, name
907 | .ffunc_1 name
908 | checknum CARG1
909 | checkfail ->fff_fallback
910 |.endmacro
911 |
912 |.macro .ffunc_nn, name
913 | .ffunc_2 name
914 | evmergehi TMP0, CARG1, CARG2
915 | checknum TMP0
916 | checkanyfail ->fff_fallback
917 |.endmacro
918 |
919 |// Inlined GC threshold check. Caveat: uses TMP0 and TMP1.
920 |.macro ffgccheck
921 | lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
922 | lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
923 | cmplw TMP0, TMP1
924 | bgel ->fff_gcstep
925 |.endmacro
926 |
927 |//-- Base library: checks -----------------------------------------------
928 |
929 |.ffunc assert
930 | cmplwi NARGS8:RC, 8
931 | evldd TMP0, 0(BASE)
932 | blt ->fff_fallback
933 | evaddw TMP1, TISNIL, TISNIL // Synthesize LJ_TFALSE.
934 | la RA, -8(BASE)
935 | evcmpltu cr1, TMP0, TMP1
936 | lwz PC, FRAME_PC(BASE)
937 | bge cr1, ->fff_fallback
938 | evstdd TMP0, 0(RA)
939 | addi RD, NARGS8:RC, 8 // Compute (nresults+1)*8.
940 | beq ->fff_res // Done if exactly 1 argument.
941 | li TMP1, 8
942 | subi RC, RC, 8
943 |1:
944 | cmplw TMP1, RC
945 | evlddx TMP0, BASE, TMP1
946 | evstddx TMP0, RA, TMP1
947 | addi TMP1, TMP1, 8
948 | bne <1
949 | b ->fff_res
950 |
951 |.ffunc type
952 | cmplwi NARGS8:RC, 8
953 | lwz CARG1, 0(BASE)
954 | blt ->fff_fallback
955 | li TMP2, ~LJ_TNUMX
956 | cmplw CARG1, TISNUM
957 | not TMP1, CARG1
958 | isellt TMP1, TMP2, TMP1
959 | slwi TMP1, TMP1, 3
960 | la TMP2, CFUNC:RB->upvalue
961 | evlddx STR:CRET1, TMP2, TMP1
962 | b ->fff_restv
963 |
964 |//-- Base library: getters and setters ---------------------------------
965 |
966 |.ffunc_1 getmetatable
967 | checktab CARG1
968 | evmergehi TMP1, CARG1, CARG1
969 | checkfail >6
970 |1: // Field metatable must be at same offset for GCtab and GCudata!
971 | lwz TAB:RB, TAB:CARG1->metatable
972 |2:
973 | evmr CRET1, TISNIL
974 | cmplwi TAB:RB, 0
975 | lwz STR:RC, DISPATCH_GL(gcroot[GCROOT_MMNAME+MM_metatable])(DISPATCH)
976 | beq ->fff_restv
977 | lwz TMP0, TAB:RB->hmask
978 | evmergelo CRET1, TISTAB, TAB:RB // Use metatable as default result.
979 | lwz TMP1, STR:RC->hash
980 | lwz NODE:TMP2, TAB:RB->node
981 | evmergelo STR:RC, TISSTR, STR:RC
982 | and TMP1, TMP1, TMP0 // idx = str->hash & tab->hmask
983 | slwi TMP0, TMP1, 5
984 | slwi TMP1, TMP1, 3
985 | sub TMP1, TMP0, TMP1
986 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
987 |3: // Rearranged logic, because we expect _not_ to find the key.
988 | evldd TMP0, NODE:TMP2->key
989 | evldd TMP1, NODE:TMP2->val
990 | evcmpeq TMP0, STR:RC
991 | lwz NODE:TMP2, NODE:TMP2->next
992 | checkallok >5
993 | cmplwi NODE:TMP2, 0
994 | beq ->fff_restv // Not found, keep default result.
995 | b <3
996 |5:
997 | checknil TMP1
998 | checkok ->fff_restv // Ditto for nil value.
999 | evmr CRET1, TMP1 // Return value of mt.__metatable.
1000 | b ->fff_restv
1001 |
1002 |6:
1003 | cmpwi TMP1, LJ_TUDATA
1004 | not TMP1, TMP1
1005 | beq <1
1006 | checknum CARG1
1007 | slwi TMP1, TMP1, 2
1008 | li TMP2, 4*~LJ_TNUMX
1009 | isellt TMP1, TMP2, TMP1
1010 | la TMP2, DISPATCH_GL(gcroot[GCROOT_BASEMT])(DISPATCH)
1011 | lwzx TAB:RB, TMP2, TMP1
1012 | b <2
1013 |
1014 |.ffunc_2 setmetatable
1015 | // Fast path: no mt for table yet and not clearing the mt.
1016 | evmergehi TMP0, TAB:CARG1, TAB:CARG2
1017 | checktab TMP0
1018 | checkanyfail ->fff_fallback
1019 | lwz TAB:TMP1, TAB:CARG1->metatable
1020 | cmplwi TAB:TMP1, 0
1021 | lbz TMP3, TAB:CARG1->marked
1022 | bne ->fff_fallback
1023 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
1024 | stw TAB:CARG2, TAB:CARG1->metatable
1025 | beq ->fff_restv
1026 | barrierback TAB:CARG1, TMP3, TMP0
1027 | b ->fff_restv
1028 |
1029 |.ffunc rawget
1030 | cmplwi NARGS8:RC, 16
1031 | evldd CARG2, 0(BASE)
1032 | blt ->fff_fallback
1033 | checktab CARG2
1034 | la CARG3, 8(BASE)
1035 | checkfail ->fff_fallback
1036 | mr CARG1, L
1037 | bl extern lj_tab_get // (lua_State *L, GCtab *t, cTValue *key)
1038 | // Returns cTValue *.
1039 | evldd CRET1, 0(CRET1)
1040 | b ->fff_restv
1041 |
1042 |//-- Base library: conversions ------------------------------------------
1043 |
1044 |.ffunc tonumber
1045 | // Only handles the number case inline (without a base argument).
1046 | cmplwi NARGS8:RC, 8
1047 | evldd CARG1, 0(BASE)
1048 | bne ->fff_fallback // Exactly one argument.
1049 | checknum CARG1
1050 | checkok ->fff_restv
1051 | b ->fff_fallback
1052 |
1053 |.ffunc_1 tostring
1054 | // Only handles the string or number case inline.
1055 | checkstr CARG1
1056 | // A __tostring method in the string base metatable is ignored.
1057 | checkok ->fff_restv // String key?
1058 | // Handle numbers inline, unless a number base metatable is present.
1059 | lwz TMP0, DISPATCH_GL(gcroot[GCROOT_BASEMT_NUM])(DISPATCH)
1060 | checknum CARG1
1061 | cmplwi cr1, TMP0, 0
1062 | stw BASE, L->base // Add frame since C call can throw.
1063 | crand 4*cr0+eq, 4*cr0+lt, 4*cr1+eq
1064 | stw PC, SAVE_PC // Redundant (but a defined value).
1065 | bne ->fff_fallback
1066 | ffgccheck
1067 | mr CARG1, L
1068 | mr CARG2, BASE
1069 | bl extern lj_str_fromnum // (lua_State *L, lua_Number *np)
1070 | // Returns GCstr *.
1071 | evmergelo STR:CRET1, TISSTR, STR:CRET1
1072 | b ->fff_restv
1073 |
1074 |//-- Base library: iterators -------------------------------------------
1075 |
1076 |.ffunc next
1077 | cmplwi NARGS8:RC, 8
1078 | evldd CARG2, 0(BASE)
1079 | blt ->fff_fallback
1080 | evstddx TISNIL, BASE, NARGS8:RC // Set missing 2nd arg to nil.
1081 | checktab TAB:CARG2
1082 | lwz PC, FRAME_PC(BASE)
1083 | checkfail ->fff_fallback
1084 | stw BASE, L->base // Add frame since C call can throw.
1085 | mr CARG1, L
1086 | stw BASE, L->top // Dummy frame length is ok.
1087 | la CARG3, 8(BASE)
1088 | stw PC, SAVE_PC
1089 | bl extern lj_tab_next // (lua_State *L, GCtab *t, TValue *key)
1090 | // Returns 0 at end of traversal.
1091 | cmplwi CRET1, 0
1092 | evmr CRET1, TISNIL
1093 | beq ->fff_restv // End of traversal: return nil.
1094 | evldd TMP0, 8(BASE) // Copy key and value to results.
1095 | la RA, -8(BASE)
1096 | evldd TMP1, 16(BASE)
1097 | evstdd TMP0, 0(RA)
1098 | li RD, (2+1)*8
1099 | evstdd TMP1, 8(RA)
1100 | b ->fff_res
1101 |
1102 |.ffunc_1 pairs
1103 | checktab TAB:CARG1
1104 | lwz PC, FRAME_PC(BASE)
1105 | checkfail ->fff_fallback
1106#ifdef LUAJIT_ENABLE_LUA52COMPAT
1107 | lwz TAB:TMP2, TAB:CARG1->metatable
1108 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1109 | cmplwi TAB:TMP2, 0
1110 | la RA, -8(BASE)
1111 | bne ->fff_fallback
1112#else
1113 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1114 | la RA, -8(BASE)
1115#endif
1116 | evstdd TISNIL, 8(BASE)
1117 | li RD, (3+1)*8
1118 | evstdd CFUNC:TMP0, 0(RA)
1119 | b ->fff_res
1120 |
1121 |.ffunc_2 ipairs_aux
1122 | checktab TAB:CARG1
1123 | lwz PC, FRAME_PC(BASE)
1124 | checkfail ->fff_fallback
1125 | checknum CARG2
1126 | lus TMP3, 0x3ff0
1127 | checkfail ->fff_fallback
1128 | efdctsi TMP2, CARG2
1129 | lwz TMP0, TAB:CARG1->asize
1130 | evmergelo TMP3, TMP3, ZERO
1131 | lwz TMP1, TAB:CARG1->array
1132 | efdadd CARG2, CARG2, TMP3
1133 | addi TMP2, TMP2, 1
1134 | la RA, -8(BASE)
1135 | cmplw TMP0, TMP2
1136 | slwi TMP3, TMP2, 3
1137 | evstdd CARG2, 0(RA)
1138 | ble >2 // Not in array part?
1139 | evlddx TMP1, TMP1, TMP3
1140 |1:
1141 | checknil TMP1
1142 | li RD, (0+1)*8
1143 | checkok ->fff_res // End of iteration, return 0 results.
1144 | li RD, (2+1)*8
1145 | evstdd TMP1, 8(RA)
1146 | b ->fff_res
1147 |2: // Check for empty hash part first. Otherwise call C function.
1148 | lwz TMP0, TAB:CARG1->hmask
1149 | cmplwi TMP0, 0
1150 | li RD, (0+1)*8
1151 | beq ->fff_res
1152 | mr CARG2, TMP2
1153 | bl extern lj_tab_getinth // (GCtab *t, int32_t key)
1154 | // Returns cTValue * or NULL.
1155 | cmplwi CRET1, 0
1156 | li RD, (0+1)*8
1157 | beq ->fff_res
1158 | evldd TMP1, 0(CRET1)
1159 | b <1
1160 |
1161 |.ffunc_1 ipairs
1162 | checktab TAB:CARG1
1163 | lwz PC, FRAME_PC(BASE)
1164 | checkfail ->fff_fallback
1165#ifdef LUAJIT_ENABLE_LUA52COMPAT
1166 | lwz TAB:TMP2, TAB:CARG1->metatable
1167 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1168 | cmplwi TAB:TMP2, 0
1169 | la RA, -8(BASE)
1170 | bne ->fff_fallback
1171#else
1172 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1173 | la RA, -8(BASE)
1174#endif
1175 | evsplati TMP1, 0
1176 | li RD, (3+1)*8
1177 | evstdd TMP1, 8(BASE)
1178 | evstdd CFUNC:TMP0, 0(RA)
1179 | b ->fff_res
1180 |
1181 |//-- Base library: catch errors ----------------------------------------
1182 |
1183 |.ffunc pcall
1184 | cmplwi NARGS8:RC, 8
1185 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1186 | blt ->fff_fallback
1187 | mr TMP2, BASE
1188 | la BASE, 8(BASE)
1189 | // Remember active hook before pcall.
1190 | rlwinm TMP3, TMP3, 32-HOOK_ACTIVE_SHIFT, 31, 31
1191 | subi NARGS8:RC, NARGS8:RC, 8
1192 | addi PC, TMP3, 8+FRAME_PCALL
1193 | b ->vm_call_dispatch
1194 |
1195 |.ffunc_2 xpcall
1196 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1197 | mr TMP2, BASE
1198 | checkfunc CARG2 // Traceback must be a function.
1199 | checkfail ->fff_fallback
1200 | la BASE, 16(BASE)
1201 | // Remember active hook before pcall.
1202 | rlwinm TMP3, TMP3, 32-HOOK_ACTIVE_SHIFT, 31, 31
1203 | evstdd CARG2, 0(TMP2) // Swap function and traceback.
1204 | subi NARGS8:RC, NARGS8:RC, 16
1205 | evstdd CARG1, 8(TMP2)
1206 | addi PC, TMP3, 16+FRAME_PCALL
1207 | b ->vm_call_dispatch
1208 |
1209 |//-- Coroutine library --------------------------------------------------
1210 |
1211 |.macro coroutine_resume_wrap, resume
1212 |.if resume
1213 |.ffunc_1 coroutine_resume
1214 | evmergehi TMP0, L:CARG1, L:CARG1
1215 |.else
1216 |.ffunc coroutine_wrap_aux
1217 | lwz L:CARG1, CFUNC:RB->upvalue[0].gcr
1218 |.endif
1219 |.if resume
1220 | cmpwi TMP0, LJ_TTHREAD
1221 | bne ->fff_fallback
1222 |.endif
1223 | lbz TMP0, L:CARG1->status
1224 | lwz TMP1, L:CARG1->cframe
1225 | lwz CARG2, L:CARG1->top
1226 | cmplwi cr0, TMP0, LUA_YIELD
1227 | lwz TMP2, L:CARG1->base
1228 | cmplwi cr1, TMP1, 0
1229 | lwz TMP0, L:CARG1->maxstack
1230 | cmplw cr7, CARG2, TMP2
1231 | lwz PC, FRAME_PC(BASE)
1232 | crorc 4*cr6+lt, 4*cr0+gt, 4*cr1+eq // st>LUA_YIELD || cframe!=0
1233 | add TMP2, CARG2, NARGS8:RC
1234 | crandc 4*cr6+gt, 4*cr7+eq, 4*cr0+eq // base==top && st!=LUA_YIELD
1235 | cmplw cr1, TMP2, TMP0
1236 | cror 4*cr6+lt, 4*cr6+lt, 4*cr6+gt
1237 | stw PC, SAVE_PC
1238 | cror 4*cr6+lt, 4*cr6+lt, 4*cr1+gt // cond1 || cond2 || stackov
1239 | stw BASE, L->base
1240 | blt cr6, ->fff_fallback
1241 |1:
1242 |.if resume
1243 | addi BASE, BASE, 8 // Keep resumed thread in stack for GC.
1244 | subi NARGS8:RC, NARGS8:RC, 8
1245 | subi TMP2, TMP2, 8
1246 |.endif
1247 | stw TMP2, L:CARG1->top
1248 | li TMP1, 0
1249 | stw BASE, L->top
1250 |2: // Move args to coroutine.
1251 | cmpw TMP1, NARGS8:RC
1252 | evlddx TMP0, BASE, TMP1
1253 | beq >3
1254 | evstddx TMP0, CARG2, TMP1
1255 | addi TMP1, TMP1, 8
1256 | b <2
1257 |3:
1258 | li CARG3, 0
1259 | mr L:SAVE0, L:CARG1
1260 | li CARG4, 0
1261 | bl ->vm_resume // (lua_State *L, TValue *base, 0, 0)
1262 | // Returns thread status.
1263 |4:
1264 | lwz TMP2, L:SAVE0->base
1265 | cmplwi CRET1, LUA_YIELD
1266 | lwz TMP3, L:SAVE0->top
1267 | li_vmstate INTERP
1268 | lwz BASE, L->base
1269 | st_vmstate
1270 | bgt >8
1271 | sub RD, TMP3, TMP2
1272 | lwz TMP0, L->maxstack
1273 | cmplwi RD, 0
1274 | add TMP1, BASE, RD
1275 | beq >6 // No results?
1276 | cmplw TMP1, TMP0
1277 | li TMP1, 0
1278 | bgt >9 // Need to grow stack?
1279 |
1280 | subi TMP3, RD, 8
1281 | stw TMP2, L:SAVE0->top // Clear coroutine stack.
1282 |5: // Move results from coroutine.
1283 | cmplw TMP1, TMP3
1284 | evlddx TMP0, TMP2, TMP1
1285 | evstddx TMP0, BASE, TMP1
1286 | addi TMP1, TMP1, 8
1287 | bne <5
1288 |6:
1289 | andi. TMP0, PC, FRAME_TYPE
1290 |.if resume
1291 | li TMP1, LJ_TTRUE
1292 | la RA, -8(BASE)
1293 | stw TMP1, -8(BASE) // Prepend true to results.
1294 | addi RD, RD, 16
1295 |.else
1296 | mr RA, BASE
1297 | addi RD, RD, 8
1298 |.endif
1299 |7:
1300 | stw PC, SAVE_PC
1301 | mr MULTRES, RD
1302 | beq ->BC_RET_Z
1303 | b ->vm_return
1304 |
1305 |8: // Coroutine returned with error (at co->top-1).
1306 |.if resume
1307 | andi. TMP0, PC, FRAME_TYPE
1308 | la TMP3, -8(TMP3)
1309 | li TMP1, LJ_TFALSE
1310 | evldd TMP0, 0(TMP3)
1311 | stw TMP3, L:SAVE0->top // Remove error from coroutine stack.
1312 | li RD, (2+1)*8
1313 | stw TMP1, -8(BASE) // Prepend false to results.
1314 | la RA, -8(BASE)
1315 | evstdd TMP0, 0(BASE) // Copy error message.
1316 | b <7
1317 |.else
1318 | mr CARG1, L
1319 | mr CARG2, L:SAVE0
1320 | bl extern lj_ffh_coroutine_wrap_err // (lua_State *L, lua_State *co)
1321 |.endif
1322 |
1323 |9: // Handle stack expansion on return from yield.
1324 | mr CARG1, L
1325 | srwi CARG2, RD, 3
1326 | bl extern lj_state_growstack // (lua_State *L, int n)
1327 | li CRET1, 0
1328 | b <4
1329 |.endmacro
1330 |
1331 | coroutine_resume_wrap 1 // coroutine.resume
1332 | coroutine_resume_wrap 0 // coroutine.wrap
1333 |
1334 |.ffunc coroutine_yield
1335 | lwz TMP0, L->cframe
1336 | add TMP1, BASE, NARGS8:RC
1337 | stw BASE, L->base
1338 | andi. TMP0, TMP0, CFRAME_RESUME
1339 | stw TMP1, L->top
1340 | li CRET1, LUA_YIELD
1341 | beq ->fff_fallback
1342 | stw ZERO, L->cframe
1343 | stb CRET1, L->status
1344 | b ->vm_leave_unw
1345 |
1346 |//-- Math library -------------------------------------------------------
1347 |
1348 |.ffunc_n math_abs
1349 | efdabs CRET1, CARG1
1350 | // Fallthrough.
1351 |
1352 |->fff_restv:
1353 | // CRET1 = TValue result.
1354 | lwz PC, FRAME_PC(BASE)
1355 | la RA, -8(BASE)
1356 | evstdd CRET1, 0(RA)
1357 |->fff_res1:
1358 | // RA = results, PC = return.
1359 | li RD, (1+1)*8
1360 |->fff_res:
1361 | // RA = results, RD = (nresults+1)*8, PC = return.
1362 | andi. TMP0, PC, FRAME_TYPE
1363 | mr MULTRES, RD
1364 | bne ->vm_return
1365 | lwz INS, -4(PC)
1366 | decode_RB8 RB, INS
1367 |5:
1368 | cmplw RB, RD // More results expected?
1369 | decode_RA8 TMP0, INS
1370 | bgt >6
1371 | ins_next1
1372 | // Adjust BASE. KBASE is assumed to be set for the calling frame.
1373 | sub BASE, RA, TMP0
1374 | ins_next2
1375 |
1376 |6: // Fill up results with nil.
1377 | subi TMP1, RD, 8
1378 | addi RD, RD, 8
1379 | evstddx TISNIL, RA, TMP1
1380 | b <5
1381 |
1382 |.macro math_extern, func
1383 | .ffunc math_ .. func
1384 | cmplwi NARGS8:RC, 8
1385 | evldd CARG2, 0(BASE)
1386 | blt ->fff_fallback
1387 | checknum CARG2
1388 | evmergehi CARG1, CARG2, CARG2
1389 | checkfail ->fff_fallback
1390 | bl extern func
1391 | evmergelo CRET1, CRET1, CRET2
1392 | b ->fff_restv
1393 |.endmacro
1394 |
1395 |.macro math_extern2, func
1396 | .ffunc math_ .. func
1397 | cmplwi NARGS8:RC, 16
1398 | evldd CARG2, 0(BASE)
1399 | evldd CARG4, 8(BASE)
1400 | blt ->fff_fallback
1401 | evmergehi CARG1, CARG4, CARG2
1402 | checknum CARG1
1403 | evmergehi CARG3, CARG4, CARG4
1404 | checkanyfail ->fff_fallback
1405 | bl extern func
1406 | evmergelo CRET1, CRET1, CRET2
1407 | b ->fff_restv
1408 |.endmacro
1409 |
1410 |.macro math_round, func
1411 | .ffunc math_ .. func
1412 | cmplwi NARGS8:RC, 8
1413 | evldd CARG2, 0(BASE)
1414 | blt ->fff_fallback
1415 | checknum CARG2
1416 | evmergehi CARG1, CARG2, CARG2
1417 | checkfail ->fff_fallback
1418 | lwz PC, FRAME_PC(BASE)
1419 | bl ->vm_..func.._hilo;
1420 | la RA, -8(BASE)
1421 | evstdd CRET2, 0(RA)
1422 | b ->fff_res1
1423 |.endmacro
1424 |
1425 | math_round floor
1426 | math_round ceil
1427 |
1428 | math_extern sqrt
1429 | math_extern log
1430 | math_extern log10
1431 | math_extern exp
1432 | math_extern sin
1433 | math_extern cos
1434 | math_extern tan
1435 | math_extern asin
1436 | math_extern acos
1437 | math_extern atan
1438 | math_extern sinh
1439 | math_extern cosh
1440 | math_extern tanh
1441 | math_extern2 pow
1442 | math_extern2 atan2
1443 | math_extern2 fmod
1444 |
1445 |->ff_math_deg:
1446 |.ffunc_n math_rad
1447 | evldd CARG2, CFUNC:RB->upvalue[0]
1448 | efdmul CRET1, CARG1, CARG2
1449 | b ->fff_restv
1450 |
1451 |.ffunc math_ldexp
1452 | cmplwi NARGS8:RC, 16
1453 | evldd CARG2, 0(BASE)
1454 | evldd CARG4, 8(BASE)
1455 | blt ->fff_fallback
1456 | evmergehi CARG1, CARG4, CARG2
1457 | checknum CARG1
1458 | checkanyfail ->fff_fallback
1459 | efdctsi CARG3, CARG4
1460 | bl extern ldexp
1461 | evmergelo CRET1, CRET1, CRET2
1462 | b ->fff_restv
1463 |
1464 |.ffunc math_frexp
1465 | cmplwi NARGS8:RC, 8
1466 | evldd CARG2, 0(BASE)
1467 | blt ->fff_fallback
1468 | checknum CARG2
1469 | evmergehi CARG1, CARG2, CARG2
1470 | checkfail ->fff_fallback
1471 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
1472 | lwz PC, FRAME_PC(BASE)
1473 | bl extern frexp
1474 | lwz TMP1, DISPATCH_GL(tmptv)(DISPATCH)
1475 | evmergelo CRET1, CRET1, CRET2
1476 | efdcfsi CRET2, TMP1
1477 | la RA, -8(BASE)
1478 | evstdd CRET1, 0(RA)
1479 | li RD, (2+1)*8
1480 | evstdd CRET2, 8(RA)
1481 | b ->fff_res
1482 |
1483 |.ffunc math_modf
1484 | cmplwi NARGS8:RC, 8
1485 | evldd CARG2, 0(BASE)
1486 | blt ->fff_fallback
1487 | checknum CARG2
1488 | evmergehi CARG1, CARG2, CARG2
1489 | checkfail ->fff_fallback
1490 | la CARG3, -8(BASE)
1491 | lwz PC, FRAME_PC(BASE)
1492 | bl extern modf
1493 | evmergelo CRET1, CRET1, CRET2
1494 | la RA, -8(BASE)
1495 | evstdd CRET1, 0(BASE)
1496 | li RD, (2+1)*8
1497 | b ->fff_res
1498 |
1499 |.macro math_minmax, name, cmpop
1500 | .ffunc_1 name
1501 | checknum CARG1
1502 | li TMP1, 8
1503 | checkfail ->fff_fallback
1504 |1:
1505 | evlddx CARG2, BASE, TMP1
1506 | cmplw cr1, TMP1, NARGS8:RC
1507 | checknum CARG2
1508 | bge cr1, ->fff_restv // Ok, since CRET1 = CARG1.
1509 | checkfail ->fff_fallback
1510 | cmpop CARG2, CARG1
1511 | addi TMP1, TMP1, 8
1512 | crmove 4*cr0+lt, 4*cr0+gt
1513 | evsel CARG1, CARG2, CARG1
1514 | b <1
1515 |.endmacro
1516 |
1517 | math_minmax math_min, efdtstlt
1518 | math_minmax math_max, efdtstgt
1519 |
1520 |//-- String library -----------------------------------------------------
1521 |
1522 |.ffunc_1 string_len
1523 | checkstr STR:CARG1
1524 | checkfail ->fff_fallback
1525 | lwz TMP0, STR:CARG1->len
1526 | efdcfsi CRET1, TMP0
1527 | b ->fff_restv
1528 |
1529 |.ffunc string_byte // Only handle the 1-arg case here.
1530 | cmplwi NARGS8:RC, 8
1531 | evldd STR:CARG1, 0(BASE)
1532 | bne ->fff_fallback // Need exactly 1 argument.
1533 | checkstr STR:CARG1
1534 | la RA, -8(BASE)
1535 | checkfail ->fff_fallback
1536 | lwz TMP0, STR:CARG1->len
1537 | li RD, (0+1)*8
1538 | lbz TMP1, STR:CARG1[1] // Access is always ok (NUL at end).
1539 | li TMP2, (1+1)*8
1540 | cmplwi TMP0, 0
1541 | lwz PC, FRAME_PC(BASE)
1542 | efdcfsi CRET1, TMP1
1543 | iseleq RD, RD, TMP2
1544 | evstdd CRET1, 0(RA)
1545 | b ->fff_res
1546 |
1547 |.ffunc string_char // Only handle the 1-arg case here.
1548 | ffgccheck
1549 | cmplwi NARGS8:RC, 8
1550 | evldd CARG1, 0(BASE)
1551 | bne ->fff_fallback // Exactly 1 argument.
1552 | checknum CARG1
1553 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
1554 | checkfail ->fff_fallback
1555 | efdctsiz TMP0, CARG1
1556 | li CARG3, 1
1557 | cmplwi TMP0, 255
1558 | stb TMP0, 0(CARG2)
1559 | bgt ->fff_fallback
1560 |->fff_newstr:
1561 | mr CARG1, L
1562 | stw BASE, L->base
1563 | stw PC, SAVE_PC
1564 | bl extern lj_str_new // (lua_State *L, char *str, size_t l)
1565 | // Returns GCstr *.
1566 | lwz BASE, L->base
1567 | evmergelo STR:CRET1, TISSTR, STR:CRET1
1568 | b ->fff_restv
1569 |
1570 |.ffunc string_sub
1571 | ffgccheck
1572 | cmplwi NARGS8:RC, 16
1573 | evldd CARG3, 16(BASE)
1574 | evldd STR:CARG1, 0(BASE)
1575 | blt ->fff_fallback
1576 | evldd CARG2, 8(BASE)
1577 | li TMP2, -1
1578 | beq >1
1579 | checknum CARG3
1580 | checkfail ->fff_fallback
1581 | efdctsiz TMP2, CARG3
1582 |1:
1583 | checknum CARG2
1584 | checkfail ->fff_fallback
1585 | checkstr STR:CARG1
1586 | efdctsiz TMP1, CARG2
1587 | checkfail ->fff_fallback
1588 | lwz TMP0, STR:CARG1->len
1589 | cmplw TMP0, TMP2 // len < end? (unsigned compare)
1590 | add TMP3, TMP2, TMP0
1591 | blt >5
1592 |2:
1593 | cmpwi TMP1, 0 // start <= 0?
1594 | add TMP3, TMP1, TMP0
1595 | ble >7
1596 |3:
1597 | sub. CARG3, TMP2, TMP1
1598 | addi CARG2, STR:CARG1, #STR-1
1599 | addi CARG3, CARG3, 1
1600 | add CARG2, CARG2, TMP1
1601 | isellt CARG3, r0, CARG3
1602 | b ->fff_newstr
1603 |
1604 |5: // Negative end or overflow.
1605 | cmpw TMP0, TMP2
1606 | addi TMP3, TMP3, 1
1607 | iselgt TMP2, TMP3, TMP0 // end = end > len ? len : end+len+1
1608 | b <2
1609 |
1610 |7: // Negative start or underflow.
1611 | cmpwi cr1, TMP3, 0
1612 | iseleq TMP1, r0, TMP3
1613 | isel TMP1, r0, TMP1, 4*cr1+lt
1614 | addi TMP1, TMP1, 1 // start = 1 + (start ? start+len : 0)
1615 | b <3
1616 |
1617 |.ffunc string_rep // Only handle the 1-char case inline.
1618 | ffgccheck
1619 | cmplwi NARGS8:RC, 16
1620 | evldd CARG1, 0(BASE)
1621 | evldd CARG2, 8(BASE)
1622 | blt ->fff_fallback
1623 | checknum CARG2
1624 | checkfail ->fff_fallback
1625 | checkstr STR:CARG1
1626 | efdctsiz CARG3, CARG2
1627 | checkfail ->fff_fallback
1628 | lwz TMP0, STR:CARG1->len
1629 | cmpwi CARG3, 0
1630 | lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1631 | ble >2 // Count <= 0? (or non-int)
1632 | cmplwi TMP0, 1
1633 | subi TMP2, CARG3, 1
1634 | blt >2 // Zero length string?
1635 | cmplw cr1, TMP1, CARG3
1636 | bne ->fff_fallback // Fallback for > 1-char strings.
1637 | lbz TMP0, STR:CARG1[1]
1638 | lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1639 | blt cr1, ->fff_fallback
1640 |1: // Fill buffer with char. Yes, this is suboptimal code (do you care?).
1641 | cmplwi TMP2, 0
1642 | stbx TMP0, CARG2, TMP2
1643 | subi TMP2, TMP2, 1
1644 | bne <1
1645 | b ->fff_newstr
1646 |2: // Return empty string.
1647 | la STR:CRET1, DISPATCH_GL(strempty)(DISPATCH)
1648 | evmergelo CRET1, TISSTR, STR:CRET1
1649 | b ->fff_restv
1650 |
1651 |.ffunc string_reverse
1652 | ffgccheck
1653 | cmplwi NARGS8:RC, 8
1654 | evldd CARG1, 0(BASE)
1655 | blt ->fff_fallback
1656 | checkstr STR:CARG1
1657 | lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1658 | checkfail ->fff_fallback
1659 | lwz CARG3, STR:CARG1->len
1660 | la CARG1, #STR(STR:CARG1)
1661 | lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1662 | li TMP2, 0
1663 | cmplw TMP1, CARG3
1664 | subi TMP3, CARG3, 1
1665 | blt ->fff_fallback
1666 |1: // Reverse string copy.
1667 | cmpwi TMP3, 0
1668 | lbzx TMP1, CARG1, TMP2
1669 | blt ->fff_newstr
1670 | stbx TMP1, CARG2, TMP3
1671 | subi TMP3, TMP3, 1
1672 | addi TMP2, TMP2, 1
1673 | b <1
1674 |
1675 |.macro ffstring_case, name, lo
1676 | .ffunc name
1677 | ffgccheck
1678 | cmplwi NARGS8:RC, 8
1679 | evldd CARG1, 0(BASE)
1680 | blt ->fff_fallback
1681 | checkstr STR:CARG1
1682 | lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1683 | checkfail ->fff_fallback
1684 | lwz CARG3, STR:CARG1->len
1685 | la CARG1, #STR(STR:CARG1)
1686 | lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1687 | cmplw TMP1, CARG3
1688 | li TMP2, 0
1689 | blt ->fff_fallback
1690 |1: // ASCII case conversion.
1691 | cmplw TMP2, CARG3
1692 | lbzx TMP1, CARG1, TMP2
1693 | bge ->fff_newstr
1694 | subi TMP0, TMP1, lo
1695 | xori TMP3, TMP1, 0x20
1696 | cmplwi TMP0, 26
1697 | isellt TMP1, TMP3, TMP1
1698 | stbx TMP1, CARG2, TMP2
1699 | addi TMP2, TMP2, 1
1700 | b <1
1701 |.endmacro
1702 |
1703 |ffstring_case string_lower, 65
1704 |ffstring_case string_upper, 97
1705 |
1706 |//-- Table library ------------------------------------------------------
1707 |
1708 |.ffunc_1 table_getn
1709 | checktab CARG1
1710 | checkfail ->fff_fallback
1711 | bl extern lj_tab_len // (GCtab *t)
1712 | // Returns uint32_t (but less than 2^31).
1713 | efdcfsi CRET1, CRET1
1714 | b ->fff_restv
1715 |
1716 |//-- Bit library --------------------------------------------------------
1717 |
1718 |.macro .ffunc_bit, name
1719 | .ffunc_n bit_..name
1720 | efdadd CARG1, CARG1, TOBIT
1721 |.endmacro
1722 |
1723 |.ffunc_bit tobit
1724 |->fff_resbit:
1725 | efdcfsi CRET1, CARG1
1726 | b ->fff_restv
1727 |
1728 |.macro .ffunc_bit_op, name, ins
1729 | .ffunc_bit name
1730 | li TMP1, 8
1731 |1:
1732 | evlddx CARG2, BASE, TMP1
1733 | cmplw cr1, TMP1, NARGS8:RC
1734 | checknum CARG2
1735 | bge cr1, ->fff_resbit
1736 | checkfail ->fff_fallback
1737 | efdadd CARG2, CARG2, TOBIT
1738 | ins CARG1, CARG1, CARG2
1739 | addi TMP1, TMP1, 8
1740 | b <1
1741 |.endmacro
1742 |
1743 |.ffunc_bit_op band, and
1744 |.ffunc_bit_op bor, or
1745 |.ffunc_bit_op bxor, xor
1746 |
1747 |.ffunc_bit bswap
1748 | rotlwi TMP0, CARG1, 8
1749 | rlwimi TMP0, CARG1, 24, 0, 7
1750 | rlwimi TMP0, CARG1, 24, 16, 23
1751 | efdcfsi CRET1, TMP0
1752 | b ->fff_restv
1753 |
1754 |.ffunc_bit bnot
1755 | not TMP0, CARG1
1756 | efdcfsi CRET1, TMP0
1757 | b ->fff_restv
1758 |
1759 |.macro .ffunc_bit_sh, name, ins, shmod
1760 | .ffunc_nn bit_..name
1761 | efdadd CARG2, CARG2, TOBIT
1762 | efdadd CARG1, CARG1, TOBIT
1763 |.if shmod == 1
1764 | rlwinm CARG2, CARG2, 0, 27, 31
1765 |.elif shmod == 2
1766 | neg CARG2, CARG2
1767 |.endif
1768 | ins TMP0, CARG1, CARG2
1769 | efdcfsi CRET1, TMP0
1770 | b ->fff_restv
1771 |.endmacro
1772 |
1773 |.ffunc_bit_sh lshift, slw, 1
1774 |.ffunc_bit_sh rshift, srw, 1
1775 |.ffunc_bit_sh arshift, sraw, 1
1776 |.ffunc_bit_sh rol, rotlw, 0
1777 |.ffunc_bit_sh ror, rotlw, 2
1778 |
1779 |//-----------------------------------------------------------------------
1780 |
1781 |->fff_fallback: // Call fast function fallback handler.
1782 | // BASE = new base, RB = CFUNC, RC = nargs*8
1783 | lwz TMP3, CFUNC:RB->f
1784 | add TMP1, BASE, NARGS8:RC
1785 | lwz PC, FRAME_PC(BASE) // Fallback may overwrite PC.
1786 | addi TMP0, TMP1, 8*LUA_MINSTACK
1787 | lwz TMP2, L->maxstack
1788 | stw PC, SAVE_PC // Redundant (but a defined value).
1789 | cmplw TMP0, TMP2
1790 | stw BASE, L->base
1791 | stw TMP1, L->top
1792 | mr CARG1, L
1793 | bgt >5 // Need to grow stack.
1794 | mtctr TMP3
1795 | bctrl // (lua_State *L)
1796 | // Either throws an error, or recovers and returns -1, 0 or nresults+1.
1797 | lwz BASE, L->base
1798 | cmpwi CRET1, 0
1799 | slwi RD, CRET1, 3
1800 | la RA, -8(BASE)
1801 | bgt ->fff_res // Returned nresults+1?
1802 |1: // Returned 0 or -1: retry fast path.
1803 | lwz TMP0, L->top
1804 | lwz LFUNC:RB, FRAME_FUNC(BASE)
1805 | sub NARGS8:RC, TMP0, BASE
1806 | bne ->vm_call_tail // Returned -1?
1807 | ins_callt // Returned 0: retry fast path.
1808 |
1809 |// Reconstruct previous base for vmeta_call during tailcall.
1810 |->vm_call_tail:
1811 | andi. TMP0, PC, FRAME_TYPE
1812 | rlwinm TMP1, PC, 0, 0, 28
1813 | bne >3
1814 | lwz INS, -4(PC)
1815 | decode_RA8 TMP1, INS
1816 | addi TMP1, TMP1, 8
1817 |3:
1818 | sub TMP2, BASE, TMP1
1819 | b ->vm_call_dispatch // Resolve again for tailcall.
1820 |
1821 |5: // Grow stack for fallback handler.
1822 | li CARG2, LUA_MINSTACK
1823 | bl extern lj_state_growstack // (lua_State *L, int n)
1824 | lwz BASE, L->base
1825 | cmpw TMP0, TMP0 // Set 4*cr0+eq to force retry.
1826 | b <1
1827 |
1828 |->fff_gcstep: // Call GC step function.
1829 | // BASE = new base, RC = nargs*8
1830 | mflr SAVE0
1831 | stw BASE, L->base
1832 | add TMP0, BASE, NARGS8:RC
1833 | stw PC, SAVE_PC // Redundant (but a defined value).
1834 | stw TMP0, L->top
1835 | mr CARG1, L
1836 | bl extern lj_gc_step // (lua_State *L)
1837 | lwz BASE, L->base
1838 | mtlr SAVE0
1839 | lwz TMP0, L->top
1840 | sub NARGS8:RC, TMP0, BASE
1841 | lwz CFUNC:RB, FRAME_FUNC(BASE)
1842 | blr
1843 |
1844 |//-----------------------------------------------------------------------
1845 |//-- Special dispatch targets -------------------------------------------
1846 |//-----------------------------------------------------------------------
1847 |
1848 |->vm_record: // Dispatch target for recording phase.
1849#if LJ_HASJIT
1850 | NYI
1851#endif
1852 |
1853 |->vm_rethook: // Dispatch target for return hooks.
1854 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1855 | andi. TMP0, TMP3, HOOK_ACTIVE // Hook already active?
1856 | beq >1
1857 |5: // Re-dispatch to static ins.
1858 | addi TMP1, TMP1, GG_DISP2STATIC // Assumes decode_OP4 TMP1, INS.
1859 | lwzx TMP0, DISPATCH, TMP1
1860 | mtctr TMP0
1861 | bctr
1862 |
1863 |->vm_inshook: // Dispatch target for instr/line hooks.
1864 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1865 | lwz TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1866 | andi. TMP0, TMP3, HOOK_ACTIVE // Hook already active?
1867 | rlwinm TMP0, TMP3, 31-LUA_HOOKLINE, 31, 0
1868 | bne <5
1869 |
1870 | cmpwi cr1, TMP0, 0
1871 | addic. TMP2, TMP2, -1
1872 | beq cr1, <5
1873 | stw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1874 | beq >1
1875 | bge cr1, <5
1876 |1:
1877 | mr CARG1, L
1878 | stw MULTRES, SAVE_MULTRES
1879 | mr CARG2, PC
1880 | stw BASE, L->base
1881 | // SAVE_PC must hold the _previous_ PC. The callee updates it with PC.
1882 | bl extern lj_dispatch_ins // (lua_State *L, const BCIns *pc)
1883 |3:
1884 | lwz BASE, L->base
1885 |4: // Re-dispatch to static ins.
1886 | lwz INS, -4(PC)
1887 | decode_OP4 TMP1, INS
1888 | decode_RB8 RB, INS
1889 | addi TMP1, TMP1, GG_DISP2STATIC
1890 | decode_RD8 RD, INS
1891 | lwzx TMP0, DISPATCH, TMP1
1892 | decode_RA8 RA, INS
1893 | decode_RC8 RC, INS
1894 | mtctr TMP0
1895 | bctr
1896 |
1897 |->cont_hook: // Continue from hook yield.
1898 | addi PC, PC, 4
1899 | lwz MULTRES, -20(RB) // Restore MULTRES for *M ins.
1900 | b <4
1901 |
1902 |->vm_hotloop: // Hot loop counter underflow.
1903#if LJ_HASJIT
1904 | NYI
1905#endif
1906 |
1907 |->vm_callhook: // Dispatch target for call hooks.
1908 | mr CARG2, PC
1909#if LJ_HASJIT
1910 | b >1
1911#endif
1912 |
1913 |->vm_hotcall: // Hot call counter underflow.
1914#if LJ_HASJIT
1915 | ori CARG2, PC, 1
1916 |1:
1917#endif
1918 | add TMP0, BASE, RC
1919 | stw PC, SAVE_PC
1920 | mr CARG1, L
1921 | stw BASE, L->base
1922 | sub RA, RA, BASE
1923 | stw TMP0, L->top
1924 | bl extern lj_dispatch_call // (lua_State *L, const BCIns *pc)
1925 | // Returns ASMFunction.
1926 | lwz BASE, L->base
1927 | lwz TMP0, L->top
1928 | stw ZERO, SAVE_PC // Invalidate for subsequent line hook.
1929 | sub NARGS8:RC, TMP0, BASE
1930 | add RA, BASE, RA
1931 | lwz LFUNC:RB, FRAME_FUNC(BASE)
1932 | mtctr CRET1
1933 | bctr
1934 |
1935 |//-----------------------------------------------------------------------
1936 |//-- Trace exit handler -------------------------------------------------
1937 |//-----------------------------------------------------------------------
1938 |
1939 |->vm_exit_handler:
1940#if LJ_HASJIT
1941 | NYI
1942#endif
1943 |->vm_exit_interp:
1944#if LJ_HASJIT
1945 | NYI
1946#endif
1947 |
1948 |//-----------------------------------------------------------------------
1949 |//-- Math helper functions ----------------------------------------------
1950 |//-----------------------------------------------------------------------
1951 |
1952 |// FP value rounding. Called by math.floor/math.ceil fast functions
1953 |// and from JIT code.
1954 |//
1955 |// This can be inlined if the CPU has the frin/friz/frip/frim instructions.
1956 |// The alternative hard-float approaches have a deep dependency chain.
1957 |// The resulting latency is at least 3x-7x the double-precision FP latency
1958 |// (e500v2: 6cy, e600: 5cy, Cell: 10cy) or around 20-70 cycles.
1959 |//
1960 |// The soft-float approach is tedious, but much faster (e500v2: ~11cy/~6cy).
1961 |// However it relies on a fast way to transfer the FP value to GPRs
1962 |// (e500v2: 0cy for lo-word, 1cy for hi-word).
1963 |//
1964 |.macro vm_round, name, mode
1965 | // Used temporaries: TMP0, TMP1, TMP2, TMP3.
1966 |->name.._efd: // Input: CARG2, output: CRET2
1967 | evmergehi CARG1, CARG2, CARG2
1968 |->name.._hilo:
1969 | // Input: CARG1 (hi), CARG2 (hi, lo), output: CRET2
1970 | rlwinm TMP2, CARG1, 12, 21, 31
1971 | addic. TMP2, TMP2, -1023 // exp = exponent(x) - 1023
1972 | li TMP1, -1
1973 | cmplwi cr1, TMP2, 51 // 0 <= exp <= 51?
1974 | subfic TMP0, TMP2, 52
1975 | bgt cr1, >1
1976 | lus TMP3, 0xfff0
1977 | slw TMP0, TMP1, TMP0 // lomask = -1 << (52-exp)
1978 | sraw TMP1, TMP3, TMP2 // himask = (int32_t)0xfff00000 >> exp
1979 |.if mode == 2 // trunc(x):
1980 | evmergelo TMP0, TMP1, TMP0
1981 | evand CRET2, CARG2, TMP0 // hi &= himask, lo &= lomask
1982 |.else
1983 | andc TMP2, CARG2, TMP0
1984 | andc TMP3, CARG1, TMP1
1985 | or TMP2, TMP2, TMP3 // ztest = (hi&~himask) | (lo&~lomask)
1986 | srawi TMP3, CARG1, 31 // signmask = (int32_t)hi >> 31
1987 |.if mode == 0 // floor(x):
1988 | and. TMP2, TMP2, TMP3 // iszero = ((ztest & signmask) == 0)
1989 |.else // ceil(x):
1990 | andc. TMP2, TMP2, TMP3 // iszero = ((ztest & ~signmask) == 0)
1991 |.endif
1992 | and CARG2, CARG2, TMP0 // lo &= lomask
1993 | and CARG1, CARG1, TMP1 // hi &= himask
1994 | subc TMP0, CARG2, TMP0
1995 | iseleq TMP0, CARG2, TMP0 // lo = iszero ? lo : lo-lomask
1996 | sube TMP1, CARG1, TMP1
1997 | iseleq TMP1, CARG1, TMP1 // hi = iszero ? hi : hi-himask+carry
1998 | evmergelo CRET2, TMP1, TMP0
1999 |.endif
2000 | blr
2001 |1:
2002 | bgtlr // Already done if >=2^52, +-inf or nan.
2003 |.if mode == 2 // trunc(x):
2004 | rlwinm TMP1, CARG1, 0, 0, 0 // hi = sign(x)
2005 | li TMP0, 0
2006 | evmergelo CRET2, TMP1, TMP0
2007 |.else
2008 | rlwinm TMP2, CARG1, 0, 1, 31
2009 | srawi TMP0, CARG1, 31 // signmask = (int32_t)hi >> 31
2010 | or TMP2, TMP2, CARG2 // ztest = abs(hi) | lo
2011 | lus TMP1, 0x3ff0
2012 |.if mode == 0 // floor(x):
2013 | and. TMP2, TMP2, TMP0 // iszero = ((ztest & signmask) == 0)
2014 |.else // ceil(x):
2015 | andc. TMP2, TMP2, TMP0 // iszero = ((ztest & ~signmask) == 0)
2016 |.endif
2017 | li TMP0, 0
2018 | iseleq TMP1, r0, TMP1
2019 | rlwimi CARG1, TMP1, 0, 1, 31 // hi = sign(x) | (iszero ? 0.0 : 1.0)
2020 | evmergelo CRET2, CARG1, TMP0
2021 |.endif
2022 | blr
2023 |.endmacro
2024 |
2025 |->vm_floor:
2026 | mflr CARG3
2027 | bl ->vm_floor_hilo
2028 | mtlr CARG3
2029 | evmergehi CRET1, CRET2, CRET2
2030 | blr
2031 |
2032 | vm_round vm_floor, 0
2033 | vm_round vm_ceil, 1
2034#if LJ_HASJIT
2035 | vm_round vm_trunc, 2
2036#else
2037 |->vm_trunc_efd:
2038 |->vm_trunc_hilo:
2039#endif
2040 |
2041 |// Callable from C: double lj_vm_foldarith(double x, double y, int op)
2042 |// Compute x op y for basic arithmetic operators (+ - * / % ^ and unary -)
2043 |// and basic math functions. ORDER ARITH
2044 |->vm_foldarith:
2045 | evmergelo CARG2, CARG1, CARG2
2046 | cmplwi CARG5, 1
2047 | evmergelo CARG4, CARG3, CARG4
2048 | beq >1; bgt >2
2049 | efdadd CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2050 |1:
2051 | efdsub CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2052 |2:
2053 | cmplwi CARG5, 3; beq >1; bgt >2
2054 | efdmul CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2055 |1:
2056 | efddiv CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2057 |2:
2058 | cmplwi CARG5, 5; beq >1; bgt >2
2059 | evmr CARG3, CARG2; efddiv CRET2, CARG2, CARG4; evmr RB, CARG4
2060 | mflr RC; bl ->vm_floor_efd; mtlr RC
2061 | efdmul CRET2, CRET2, RB; efdsub CRET2, CARG3, CRET2
2062 | evmergehi CRET1, CRET2, CRET2; blr
2063 |1:
2064 | b extern pow
2065 |2:
2066 | cmplwi CARG5, 7; beq >1; bgt >2
2067 | xoris CARG1, CARG1, 0x8000; blr
2068 |1:
2069 | rlwinm CARG1, CARG1, 0, 1, 31; blr
2070 |2:
2071 | NYI // Other operations only needed by JIT compiler.
2072 |
2073 |//-----------------------------------------------------------------------
2074 |//-- Miscellaneous functions --------------------------------------------
2075 |//-----------------------------------------------------------------------
2076 |
2077 |//-----------------------------------------------------------------------
2078 |//-- FFI helper functions -----------------------------------------------
2079 |//-----------------------------------------------------------------------
2080 |
2081 |->vm_ffi_call:
2082#if LJ_HASFFI
2083 | NYI
2084#endif
2085 |
2086 |//-----------------------------------------------------------------------
2087}
2088
2089/* Generate the code for a single instruction. */
2090static void build_ins(BuildCtx *ctx, BCOp op, int defop)
2091{
2092 int vk = 0;
2093 |=>defop:
2094
2095 switch (op) {
2096
2097 /* -- Comparison ops ---------------------------------------------------- */
2098
2099 /* Remember: all ops branch for a true comparison, fall through otherwise. */
2100
2101 case BC_ISLT: case BC_ISGE: case BC_ISLE: case BC_ISGT:
2102 | // RA = src1*8, RD = src2*8, JMP with RD = target
2103 | evlddx TMP0, BASE, RA
2104 | addi PC, PC, 4
2105 | evlddx TMP1, BASE, RD
2106 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2107 | lwz TMP2, -4(PC)
2108 | evmergehi RB, TMP0, TMP1
2109 | decode_RD4 TMP2, TMP2
2110 | checknum RB
2111 | add TMP2, TMP2, TMP3
2112 | checkanyfail ->vmeta_comp
2113 | efdcmplt TMP0, TMP1
2114 if (op == BC_ISLE || op == BC_ISGT) {
2115 | efdcmpeq cr1, TMP0, TMP1
2116 | cror 4*cr0+gt, 4*cr0+gt, 4*cr1+gt
2117 }
2118 if (op == BC_ISLT || op == BC_ISLE) {
2119 | iselgt PC, TMP2, PC
2120 } else {
2121 | iselgt PC, PC, TMP2
2122 }
2123 | ins_next
2124 break;
2125
2126 case BC_ISEQV: case BC_ISNEV:
2127 vk = op == BC_ISEQV;
2128 | // RA = src1*8, RD = src2*8, JMP with RD = target
2129 | evlddx CARG2, BASE, RA
2130 | addi PC, PC, 4
2131 | evlddx CARG3, BASE, RD
2132 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2133 | lwz TMP2, -4(PC)
2134 | evmergehi RB, CARG2, CARG3
2135 | decode_RD4 TMP2, TMP2
2136 | checknum RB
2137 | add TMP2, TMP2, TMP3
2138 | checkanyfail >5
2139 | efdcmpeq CARG2, CARG3
2140 if (vk) {
2141 | iselgt PC, TMP2, PC
2142 } else {
2143 | iselgt PC, PC, TMP2
2144 }
2145 |1:
2146 | ins_next
2147 |
2148 |5: // Either or both types are not numbers.
2149 | evcmpeq CARG2, CARG3
2150 | not TMP3, RB
2151 | cmplwi cr1, TMP3, ~LJ_TISPRI // Primitive?
2152 | crorc 4*cr7+lt, 4*cr0+so, 4*cr0+lt // 1: Same tv or different type.
2153 | cmplwi cr6, TMP3, ~LJ_TISTABUD // Table or userdata?
2154 | crandc 4*cr7+gt, 4*cr0+lt, 4*cr1+gt // 2: Same type and primitive.
2155 | mr SAVE0, PC
2156 if (vk) {
2157 | isel PC, TMP2, PC, 4*cr7+gt
2158 } else {
2159 | isel TMP2, PC, TMP2, 4*cr7+gt
2160 }
2161 | cror 4*cr7+lt, 4*cr7+lt, 4*cr7+gt // 1 or 2.
2162 if (vk) {
2163 | isel PC, TMP2, PC, 4*cr0+so
2164 } else {
2165 | isel PC, PC, TMP2, 4*cr0+so
2166 }
2167 | blt cr7, <1 // Done if 1 or 2.
2168 | blt cr6, <1 // Done if not tab/ud.
2169 |
2170 | // Different tables or userdatas. Need to check __eq metamethod.
2171 | // Field metatable must be at same offset for GCtab and GCudata!
2172 | lwz TAB:TMP2, TAB:CARG2->metatable
2173 | li CARG4, 1-vk // ne = 0 or 1.
2174 | cmplwi TAB:TMP2, 0
2175 | beq <1 // No metatable?
2176 | lbz TMP2, TAB:TMP2->nomm
2177 | andi. TMP2, TMP2, 1<<MM_eq
2178 | bne <1 // Or 'no __eq' flag set?
2179 | mr PC, SAVE0 // Restore old PC.
2180 | b ->vmeta_equal // Handle __eq metamethod.
2181 break;
2182
2183 case BC_ISEQS: case BC_ISNES:
2184 vk = op == BC_ISEQS;
2185 | // RA = src*8, RD = str_const*8 (~), JMP with RD = target
2186 | evlddx TMP0, BASE, RA
2187 | srwi RD, RD, 1
2188 | lwz INS, 0(PC)
2189 | subfic RD, RD, -4
2190 | addi PC, PC, 4
2191 | lwzx STR:TMP1, KBASE, RD // KBASE-4-str_const*4
2192 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2193 | decode_RD4 TMP2, INS
2194 | evmergelo STR:TMP1, TISSTR, STR:TMP1
2195 | add TMP2, TMP2, TMP3
2196 | evcmpeq TMP0, STR:TMP1
2197 if (vk) {
2198 | isel PC, TMP2, PC, 4*cr0+so
2199 } else {
2200 | isel PC, PC, TMP2, 4*cr0+so
2201 }
2202 | ins_next
2203 break;
2204
2205 case BC_ISEQN: case BC_ISNEN:
2206 vk = op == BC_ISEQN;
2207 | // RA = src*8, RD = num_const*8, JMP with RD = target
2208 | evlddx TMP0, BASE, RA
2209 | addi PC, PC, 4
2210 | evlddx TMP1, KBASE, RD
2211 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2212 | lwz INS, -4(PC)
2213 | checknum TMP0
2214 | checkfail >5
2215 | efdcmpeq TMP0, TMP1
2216 |1:
2217 | decode_RD4 TMP2, INS
2218 | add TMP2, TMP2, TMP3
2219 if (vk) {
2220 | iselgt PC, TMP2, PC
2221 |5:
2222 } else {
2223 | iselgt PC, PC, TMP2
2224 }
2225 |3:
2226 | ins_next
2227 if (!vk) {
2228 |5:
2229 | decode_RD4 TMP2, INS
2230 | add PC, TMP2, TMP3
2231 | b <3
2232 }
2233 break;
2234
2235 case BC_ISEQP: case BC_ISNEP:
2236 vk = op == BC_ISEQP;
2237 | // RA = src*8, RD = primitive_type*8 (~), JMP with RD = target
2238 | lwzx TMP0, BASE, RA
2239 | srwi TMP1, RD, 3
2240 | lwz INS, 0(PC)
2241 | addi PC, PC, 4
2242 | not TMP1, TMP1
2243 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2244 | cmplw TMP0, TMP1
2245 | decode_RD4 TMP2, INS
2246 | add TMP2, TMP2, TMP3
2247 if (vk) {
2248 | iseleq PC, TMP2, PC
2249 } else {
2250 | iseleq PC, PC, TMP2
2251 }
2252 | ins_next
2253 break;
2254
2255 /* -- Unary test and copy ops ------------------------------------------- */
2256
2257 case BC_ISTC: case BC_ISFC: case BC_IST: case BC_ISF:
2258 | // RA = dst*8 or unused, RD = src*8, JMP with RD = target
2259 | evlddx TMP0, BASE, RD
2260 | evaddw TMP1, TISNIL, TISNIL // Synthesize LJ_TFALSE.
2261 | lwz INS, 0(PC)
2262 | evcmpltu TMP0, TMP1
2263 | addi PC, PC, 4
2264 if (op == BC_IST || op == BC_ISF) {
2265 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2266 | decode_RD4 TMP2, INS
2267 | add TMP2, TMP2, TMP3
2268 if (op == BC_IST) {
2269 | isellt PC, TMP2, PC
2270 } else {
2271 | isellt PC, PC, TMP2
2272 }
2273 } else {
2274 if (op == BC_ISTC) {
2275 | checkfail >1
2276 } else {
2277 | checkok >1
2278 }
2279 | addis PC, PC, -(BCBIAS_J*4 >> 16)
2280 | decode_RD4 TMP2, INS
2281 | evstddx TMP0, BASE, RA
2282 | add PC, PC, TMP2
2283 |1:
2284 }
2285 | ins_next
2286 break;
2287
2288 /* -- Unary ops --------------------------------------------------------- */
2289
2290 case BC_MOV:
2291 | // RA = dst*8, RD = src*8
2292 | ins_next1
2293 | evlddx TMP0, BASE, RD
2294 | evstddx TMP0, BASE, RA
2295 | ins_next2
2296 break;
2297 case BC_NOT:
2298 | // RA = dst*8, RD = src*8
2299 | ins_next1
2300 | lwzx TMP0, BASE, RD
2301 | subfic TMP1, TMP0, LJ_TTRUE
2302 | adde TMP0, TMP0, TMP1
2303 | stwx TMP0, BASE, RA
2304 | ins_next2
2305 break;
2306 case BC_UNM:
2307 | // RA = dst*8, RD = src*8
2308 | evlddx TMP0, BASE, RD
2309 | checknum TMP0
2310 | checkfail ->vmeta_unm
2311 | efdneg TMP0, TMP0
2312 | ins_next1
2313 | evstddx TMP0, BASE, RA
2314 | ins_next2
2315 break;
2316 case BC_LEN:
2317 | // RA = dst*8, RD = src*8
2318 | evlddx CARG1, BASE, RD
2319 | checkstr CARG1
2320 | checkfail >2
2321 | lwz CRET1, STR:CARG1->len
2322 |1:
2323 | ins_next1
2324 | efdcfsi TMP0, CRET1
2325 | evstddx TMP0, BASE, RA
2326 | ins_next2
2327 |2:
2328 | checktab CARG1
2329 | checkfail ->vmeta_len
2330#ifdef LUAJIT_ENABLE_LUA52COMPAT
2331 | lwz TAB:TMP2, TAB:CARG1->metatable
2332 | cmplwi TAB:TMP2, 0
2333 | bne >9
2334 |3:
2335#endif
2336 |->BC_LEN_Z:
2337 | bl extern lj_tab_len // (GCtab *t)
2338 | // Returns uint32_t (but less than 2^31).
2339 | b <1
2340#ifdef LUAJIT_ENABLE_LUA52COMPAT
2341 |9:
2342 | lbz TMP0, TAB:TMP2->nomm
2343 | andi. TMP0, TMP0, 1<<MM_len
2344 | bne <3 // 'no __len' flag set: done.
2345 | b ->vmeta_len
2346#endif
2347 break;
2348
2349 /* -- Binary ops -------------------------------------------------------- */
2350
2351 |.macro ins_arithpre, t0, t1
2352 | // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
2353 ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
2354 ||switch (vk) {
2355 ||case 0:
2356 | evlddx t0, BASE, RB
2357 | checknum t0
2358 | evlddx t1, KBASE, RC
2359 | checkfail ->vmeta_arith_vn
2360 || break;
2361 ||case 1:
2362 | evlddx t1, BASE, RB
2363 | checknum t1
2364 | evlddx t0, KBASE, RC
2365 | checkfail ->vmeta_arith_nv
2366 || break;
2367 ||default:
2368 | evlddx t0, BASE, RB
2369 | evlddx t1, BASE, RC
2370 | evmergehi TMP2, t0, t1
2371 | checknum TMP2
2372 | checkanyfail ->vmeta_arith_vv
2373 || break;
2374 ||}
2375 |.endmacro
2376 |
2377 |.macro ins_arith, ins
2378 | ins_arithpre TMP0, TMP1
2379 | ins_next1
2380 | ins TMP0, TMP0, TMP1
2381 | evstddx TMP0, BASE, RA
2382 | ins_next2
2383 |.endmacro
2384
2385 case BC_ADDVN: case BC_ADDNV: case BC_ADDVV:
2386 | ins_arith efdadd
2387 break;
2388 case BC_SUBVN: case BC_SUBNV: case BC_SUBVV:
2389 | ins_arith efdsub
2390 break;
2391 case BC_MULVN: case BC_MULNV: case BC_MULVV:
2392 | ins_arith efdmul
2393 break;
2394 case BC_DIVVN: case BC_DIVNV: case BC_DIVVV:
2395 | ins_arith efddiv
2396 break;
2397 case BC_MODVN:
2398 | ins_arithpre RD, SAVE0
2399 |->BC_MODVN_Z:
2400 | efddiv CARG2, RD, SAVE0
2401 | bl ->vm_floor_efd // floor(b/c)
2402 | efdmul TMP0, CRET2, SAVE0
2403 | ins_next1
2404 | efdsub TMP0, RD, TMP0 // b - floor(b/c)*c
2405 | evstddx TMP0, BASE, RA
2406 | ins_next2
2407 break;
2408 case BC_MODNV: case BC_MODVV:
2409 | ins_arithpre RD, SAVE0
2410 | b ->BC_MODVN_Z // Avoid 3 copies. It's slow anyway.
2411 break;
2412 case BC_POW:
2413 | evlddx CARG2, BASE, RB
2414 | evlddx CARG4, BASE, RC
2415 | evmergehi CARG1, CARG4, CARG2
2416 | checknum CARG1
2417 | evmergehi CARG3, CARG4, CARG4
2418 | checkanyfail ->vmeta_arith_vv
2419 | bl extern pow
2420 | evmergelo CRET2, CRET1, CRET2
2421 | evstddx CRET2, BASE, RA
2422 | ins_next
2423 break;
2424
2425 case BC_CAT:
2426 | // RA = dst*8, RB = src_start*8, RC = src_end*8
2427 | sub CARG3, RC, RB
2428 | stw BASE, L->base
2429 | add CARG2, BASE, RC
2430 | mr SAVE0, RB
2431 |->BC_CAT_Z:
2432 | stw PC, SAVE_PC
2433 | mr CARG1, L
2434 | srwi CARG3, CARG3, 3
2435 | bl extern lj_meta_cat // (lua_State *L, TValue *top, int left)
2436 | // Returns NULL (finished) or TValue * (metamethod).
2437 | cmplwi CRET1, 0
2438 | lwz BASE, L->base
2439 | bne ->vmeta_binop
2440 | evlddx TMP0, BASE, SAVE0 // Copy result from RB to RA.
2441 | evstddx TMP0, BASE, RA
2442 | ins_next
2443 break;
2444
2445 /* -- Constant ops ------------------------------------------------------ */
2446
2447 case BC_KSTR:
2448 | // RA = dst*8, RD = str_const*8 (~)
2449 | ins_next1
2450 | srwi TMP1, RD, 1
2451 | subfic TMP1, TMP1, -4
2452 | lwzx TMP0, KBASE, TMP1 // KBASE-4-str_const*4
2453 | evmergelo TMP0, TISSTR, TMP0
2454 | evstddx TMP0, BASE, RA
2455 | ins_next2
2456 break;
2457 case BC_KCDATA:
2458#if LJ_HASFFI
2459 | // RA = dst*8, RD = cdata_const*8 (~)
2460 | ins_next1
2461 | srwi TMP1, RD, 1
2462 | subfic TMP1, TMP1, -4
2463 | lwzx TMP0, KBASE, TMP1 // KBASE-4-cdata_const*4
2464 | li TMP2, LJ_TCDATA
2465 | evmergelo TMP0, TMP2, TMP0
2466 | evstddx TMP0, BASE, RA
2467 | ins_next2
2468#endif
2469 break;
2470 case BC_KSHORT:
2471 | // RA = dst*8, RD = int16_literal*8
2472 | srwi TMP1, RD, 3
2473 | extsh TMP1, TMP1
2474 | ins_next1
2475 | efdcfsi TMP0, TMP1
2476 | evstddx TMP0, BASE, RA
2477 | ins_next2
2478 break;
2479 case BC_KNUM:
2480 | // RA = dst*8, RD = num_const*8
2481 | evlddx TMP0, KBASE, RD
2482 | ins_next1
2483 | evstddx TMP0, BASE, RA
2484 | ins_next2
2485 break;
2486 case BC_KPRI:
2487 | // RA = dst*8, RD = primitive_type*8 (~)
2488 | srwi TMP1, RD, 3
2489 | not TMP0, TMP1
2490 | ins_next1
2491 | stwx TMP0, BASE, RA
2492 | ins_next2
2493 break;
2494 case BC_KNIL:
2495 | // RA = base*8, RD = end*8
2496 | evstddx TISNIL, BASE, RA
2497 | addi RA, RA, 8
2498 |1:
2499 | evstddx TISNIL, BASE, RA
2500 | cmpw RA, RD
2501 | addi RA, RA, 8
2502 | blt <1
2503 | ins_next_
2504 break;
2505
2506 /* -- Upvalue and function ops ------------------------------------------ */
2507
2508 case BC_UGET:
2509 | // RA = dst*8, RD = uvnum*8
2510 | ins_next1
2511 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2512 | srwi RD, RD, 1
2513 | addi RD, RD, offsetof(GCfuncL, uvptr)
2514 | lwzx UPVAL:RB, LFUNC:RB, RD
2515 | lwz TMP1, UPVAL:RB->v
2516 | evldd TMP0, 0(TMP1)
2517 | evstddx TMP0, BASE, RA
2518 | ins_next2
2519 break;
2520 case BC_USETV:
2521 | // RA = uvnum*8, RD = src*8
2522 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2523 | srwi RA, RA, 1
2524 | addi RA, RA, offsetof(GCfuncL, uvptr)
2525 | evlddx TMP1, BASE, RD
2526 | lwzx UPVAL:RB, LFUNC:RB, RA
2527 | lbz TMP3, UPVAL:RB->marked
2528 | lwz CARG2, UPVAL:RB->v
2529 | andi. TMP3, TMP3, LJ_GC_BLACK // isblack(uv)
2530 | lbz TMP0, UPVAL:RB->closed
2531 | evmergehi TMP2, TMP1, TMP1
2532 | evstdd TMP1, 0(CARG2)
2533 | cmplwi cr1, TMP0, 0
2534 | cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
2535 | subi TMP2, TMP2, (LJ_TISNUM+1)
2536 | bne >2 // Upvalue is closed and black?
2537 |1:
2538 | ins_next
2539 |
2540 |2: // Check if new value is collectable.
2541 | cmplwi TMP2, LJ_TISGCV - (LJ_TISNUM+1)
2542 | bge <1 // tvisgcv(v)
2543 | lbz TMP3, GCOBJ:TMP1->gch.marked
2544 | andi. TMP3, TMP3, LJ_GC_WHITES // iswhite(v)
2545 | la CARG1, GG_DISP2G(DISPATCH)
2546 | // Crossed a write barrier. Move the barrier forward.
2547 | beq <1
2548 | bl extern lj_gc_barrieruv // (global_State *g, TValue *tv)
2549 | b <1
2550 break;
2551 case BC_USETS:
2552 | // RA = uvnum*8, RD = str_const*8 (~)
2553 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2554 | srwi TMP1, RD, 1
2555 | srwi RA, RA, 1
2556 | subfic TMP1, TMP1, -4
2557 | addi RA, RA, offsetof(GCfuncL, uvptr)
2558 | lwzx STR:TMP1, KBASE, TMP1 // KBASE-4-str_const*4
2559 | lwzx UPVAL:RB, LFUNC:RB, RA
2560 | evmergelo STR:TMP1, TISSTR, STR:TMP1
2561 | lbz TMP3, UPVAL:RB->marked
2562 | lwz CARG2, UPVAL:RB->v
2563 | andi. TMP3, TMP3, LJ_GC_BLACK // isblack(uv)
2564 | lbz TMP3, STR:TMP1->marked
2565 | lbz TMP2, UPVAL:RB->closed
2566 | evstdd STR:TMP1, 0(CARG2)
2567 | bne >2
2568 |1:
2569 | ins_next
2570 |
2571 |2: // Check if string is white and ensure upvalue is closed.
2572 | andi. TMP3, TMP3, LJ_GC_WHITES // iswhite(str)
2573 | cmplwi cr1, TMP2, 0
2574 | cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
2575 | la CARG1, GG_DISP2G(DISPATCH)
2576 | // Crossed a write barrier. Move the barrier forward.
2577 | beq <1
2578 | bl extern lj_gc_barrieruv // (global_State *g, TValue *tv)
2579 | b <1
2580 break;
2581 case BC_USETN:
2582 | // RA = uvnum*8, RD = num_const*8
2583 | ins_next1
2584 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2585 | srwi RA, RA, 1
2586 | addi RA, RA, offsetof(GCfuncL, uvptr)
2587 | evlddx TMP0, KBASE, RD
2588 | lwzx UPVAL:RB, LFUNC:RB, RA
2589 | lwz TMP1, UPVAL:RB->v
2590 | evstdd TMP0, 0(TMP1)
2591 | ins_next2
2592 break;
2593 case BC_USETP:
2594 | // RA = uvnum*8, RD = primitive_type*8 (~)
2595 | ins_next1
2596 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2597 | srwi RA, RA, 1
2598 | addi RA, RA, offsetof(GCfuncL, uvptr)
2599 | srwi TMP0, RD, 3
2600 | lwzx UPVAL:RB, LFUNC:RB, RA
2601 | not TMP0, TMP0
2602 | lwz TMP1, UPVAL:RB->v
2603 | stw TMP0, 0(TMP1)
2604 | ins_next2
2605 break;
2606
2607 case BC_UCLO:
2608 | // RA = level*8, RD = target
2609 | lwz TMP1, L->openupval
2610 | branch_RD // Do this first since RD is not saved.
2611 | stw BASE, L->base
2612 | cmplwi TMP1, 0
2613 | mr CARG1, L
2614 | beq >1
2615 | add CARG2, BASE, RA
2616 | bl extern lj_func_closeuv // (lua_State *L, TValue *level)
2617 | lwz BASE, L->base
2618 |1:
2619 | ins_next
2620 break;
2621
2622 case BC_FNEW:
2623 | // RA = dst*8, RD = proto_const*8 (~) (holding function prototype)
2624 | srwi TMP1, RD, 1
2625 | stw BASE, L->base
2626 | subfic TMP1, TMP1, -4
2627 | stw PC, SAVE_PC
2628 | lwzx CARG2, KBASE, TMP1 // KBASE-4-tab_const*4
2629 | mr CARG1, L
2630 | lwz CARG3, FRAME_FUNC(BASE)
2631 | // (lua_State *L, GCproto *pt, GCfuncL *parent)
2632 | bl extern lj_func_newL_gc
2633 | // Returns GCfuncL *.
2634 | lwz BASE, L->base
2635 | evmergelo LFUNC:CRET1, TISFUNC, LFUNC:CRET1
2636 | evstddx LFUNC:CRET1, BASE, RA
2637 | ins_next
2638 break;
2639
2640 /* -- Table ops --------------------------------------------------------- */
2641
2642 case BC_TNEW:
2643 case BC_TDUP:
2644 | // RA = dst*8, RD = (hbits|asize)*8 | tab_const*8 (~)
2645 | lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
2646 | mr CARG1, L
2647 | lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
2648 | stw BASE, L->base
2649 | cmplw TMP0, TMP1
2650 | stw PC, SAVE_PC
2651 | bge >5
2652 |1:
2653 if (op == BC_TNEW) {
2654 | rlwinm CARG2, RD, 29, 21, 31
2655 | rlwinm CARG3, RD, 18, 27, 31
2656 | cmpwi CARG2, 0x7ff
2657 | li TMP1, 0x801
2658 | iseleq CARG2, TMP1, CARG2
2659 | bl extern lj_tab_new // (lua_State *L, int32_t asize, uint32_t hbits)
2660 | // Returns Table *.
2661 } else {
2662 | srwi TMP1, RD, 1
2663 | subfic TMP1, TMP1, -4
2664 | lwzx CARG2, KBASE, TMP1 // KBASE-4-tab_const*4
2665 | bl extern lj_tab_dup // (lua_State *L, Table *kt)
2666 | // Returns Table *.
2667 }
2668 | lwz BASE, L->base
2669 | evmergelo TAB:CRET1, TISTAB, TAB:CRET1
2670 | evstddx TAB:CRET1, BASE, RA
2671 | ins_next
2672 |5:
2673 | mr SAVE0, RD
2674 | bl extern lj_gc_step_fixtop // (lua_State *L)
2675 | mr RD, SAVE0
2676 | mr CARG1, L
2677 | b <1
2678 break;
2679
2680 case BC_GGET:
2681 | // RA = dst*8, RD = str_const*8 (~)
2682 case BC_GSET:
2683 | // RA = src*8, RD = str_const*8 (~)
2684 | lwz LFUNC:TMP2, FRAME_FUNC(BASE)
2685 | srwi TMP1, RD, 1
2686 | lwz TAB:RB, LFUNC:TMP2->env
2687 | subfic TMP1, TMP1, -4
2688 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
2689 if (op == BC_GGET) {
2690 | b ->BC_TGETS_Z
2691 } else {
2692 | b ->BC_TSETS_Z
2693 }
2694 break;
2695
2696 case BC_TGETV:
2697 | // RA = dst*8, RB = table*8, RC = key*8
2698 | evlddx TAB:RB, BASE, RB
2699 | evlddx RC, BASE, RC
2700 | checktab TAB:RB
2701 | checkfail ->vmeta_tgetv
2702 | checknum RC
2703 | checkfail >5
2704 | // Convert number key to integer
2705 | efdctsi TMP2, RC
2706 | lwz TMP0, TAB:RB->asize
2707 | efdcfsi TMP1, TMP2
2708 | cmplw cr0, TMP0, TMP2
2709 | efdcmpeq cr1, RC, TMP1
2710 | lwz TMP1, TAB:RB->array
2711 | crand 4*cr0+gt, 4*cr0+gt, 4*cr1+gt
2712 | slwi TMP2, TMP2, 3
2713 | ble ->vmeta_tgetv // Integer key and in array part?
2714 | evlddx TMP1, TMP1, TMP2
2715 | checknil TMP1
2716 | checkok >2
2717 |1:
2718 | evstddx TMP1, BASE, RA
2719 | ins_next
2720 |
2721 |2: // Check for __index if table value is nil.
2722 | lwz TAB:TMP2, TAB:RB->metatable
2723 | cmplwi TAB:TMP2, 0
2724 | beq <1 // No metatable: done.
2725 | lbz TMP0, TAB:TMP2->nomm
2726 | andi. TMP0, TMP0, 1<<MM_index
2727 | bne <1 // 'no __index' flag set: done.
2728 | b ->vmeta_tgetv
2729 |
2730 |5:
2731 | checkstr STR:RC // String key?
2732 | checkok ->BC_TGETS_Z
2733 | b ->vmeta_tgetv
2734 break;
2735 case BC_TGETS:
2736 | // RA = dst*8, RB = table*8, RC = str_const*8 (~)
2737 | evlddx TAB:RB, BASE, RB
2738 | srwi TMP1, RC, 1
2739 | checktab TAB:RB
2740 | subfic TMP1, TMP1, -4
2741 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
2742 | checkfail ->vmeta_tgets1
2743 |->BC_TGETS_Z:
2744 | // TAB:RB = GCtab *, STR:RC = GCstr *, RA = dst*8
2745 | lwz TMP0, TAB:RB->hmask
2746 | lwz TMP1, STR:RC->hash
2747 | lwz NODE:TMP2, TAB:RB->node
2748 | evmergelo STR:RC, TISSTR, STR:RC
2749 | and TMP1, TMP1, TMP0 // idx = str->hash & tab->hmask
2750 | slwi TMP0, TMP1, 5
2751 | slwi TMP1, TMP1, 3
2752 | sub TMP1, TMP0, TMP1
2753 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
2754 |1:
2755 | evldd TMP0, NODE:TMP2->key
2756 | evldd TMP1, NODE:TMP2->val
2757 | evcmpeq TMP0, STR:RC
2758 | checkanyfail >4
2759 | checknil TMP1
2760 | checkok >5 // Key found, but nil value?
2761 |3:
2762 | evstddx TMP1, BASE, RA
2763 | ins_next
2764 |
2765 |4: // Follow hash chain.
2766 | lwz NODE:TMP2, NODE:TMP2->next
2767 | cmplwi NODE:TMP2, 0
2768 | bne <1
2769 | // End of hash chain: key not found, nil result.
2770 | evmr TMP1, TISNIL
2771 |
2772 |5: // Check for __index if table value is nil.
2773 | lwz TAB:TMP2, TAB:RB->metatable
2774 | cmplwi TAB:TMP2, 0
2775 | beq <3 // No metatable: done.
2776 | lbz TMP0, TAB:TMP2->nomm
2777 | andi. TMP0, TMP0, 1<<MM_index
2778 | bne <3 // 'no __index' flag set: done.
2779 | b ->vmeta_tgets
2780 break;
2781 case BC_TGETB:
2782 | // RA = dst*8, RB = table*8, RC = index*8
2783 | evlddx TAB:RB, BASE, RB
2784 | srwi TMP0, RC, 3
2785 | checktab TAB:RB
2786 | checkfail ->vmeta_tgetb
2787 | lwz TMP1, TAB:RB->asize
2788 | lwz TMP2, TAB:RB->array
2789 | cmplw TMP0, TMP1
2790 | bge ->vmeta_tgetb
2791 | evlddx TMP1, TMP2, RC
2792 | checknil TMP1
2793 | checkok >5
2794 |1:
2795 | ins_next1
2796 | evstddx TMP1, BASE, RA
2797 | ins_next2
2798 |
2799 |5: // Check for __index if table value is nil.
2800 | lwz TAB:TMP2, TAB:RB->metatable
2801 | cmplwi TAB:TMP2, 0
2802 | beq <1 // No metatable: done.
2803 | lbz TMP2, TAB:TMP2->nomm
2804 | andi. TMP2, TMP2, 1<<MM_index
2805 | bne <1 // 'no __index' flag set: done.
2806 | b ->vmeta_tgetb // Caveat: preserve TMP0!
2807 break;
2808
2809 case BC_TSETV:
2810 | // RA = src*8, RB = table*8, RC = key*8
2811 | evlddx TAB:RB, BASE, RB
2812 | evlddx RC, BASE, RC
2813 | checktab TAB:RB
2814 | checkfail ->vmeta_tsetv
2815 | checknum RC
2816 | checkfail >5
2817 | // Convert number key to integer
2818 | efdctsi TMP2, RC
2819 | evlddx SAVE0, BASE, RA
2820 | lwz TMP0, TAB:RB->asize
2821 | efdcfsi TMP1, TMP2
2822 | cmplw cr0, TMP0, TMP2
2823 | efdcmpeq cr1, RC, TMP1
2824 | lwz TMP1, TAB:RB->array
2825 | crand 4*cr0+gt, 4*cr0+gt, 4*cr1+gt
2826 | slwi TMP0, TMP2, 3
2827 | ble ->vmeta_tsetv // Integer key and in array part?
2828 | lbz TMP3, TAB:RB->marked
2829 | evlddx TMP2, TMP1, TMP0
2830 | checknil TMP2
2831 | checkok >3
2832 |1:
2833 | andi. TMP2, TMP3, LJ_GC_BLACK // isblack(table)
2834 | evstddx SAVE0, TMP1, TMP0
2835 | bne >7
2836 |2:
2837 | ins_next
2838 |
2839 |3: // Check for __newindex if previous value is nil.
2840 | lwz TAB:TMP2, TAB:RB->metatable
2841 | cmplwi TAB:TMP2, 0
2842 | beq <1 // No metatable: done.
2843 | lbz TMP2, TAB:TMP2->nomm
2844 | andi. TMP2, TMP2, 1<<MM_newindex
2845 | bne <1 // 'no __newindex' flag set: done.
2846 | b ->vmeta_tsetv
2847 |
2848 |5:
2849 | checkstr STR:RC // String key?
2850 | checkok ->BC_TSETS_Z
2851 | b ->vmeta_tsetv
2852 |
2853 |7: // Possible table write barrier for the value. Skip valiswhite check.
2854 | barrierback TAB:RB, TMP3, TMP0
2855 | b <2
2856 break;
2857 case BC_TSETS:
2858 | // RA = src*8, RB = table*8, RC = str_const*8 (~)
2859 | evlddx TAB:RB, BASE, RB
2860 | srwi TMP1, RC, 1
2861 | checktab TAB:RB
2862 | subfic TMP1, TMP1, -4
2863 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
2864 | checkfail ->vmeta_tsets1
2865 |->BC_TSETS_Z:
2866 | // TAB:RB = GCtab *, STR:RC = GCstr *, RA = src*8
2867 | lwz TMP0, TAB:RB->hmask
2868 | lwz TMP1, STR:RC->hash
2869 | lwz NODE:TMP2, TAB:RB->node
2870 | evmergelo STR:RC, TISSTR, STR:RC
2871 | stb ZERO, TAB:RB->nomm // Clear metamethod cache.
2872 | and TMP1, TMP1, TMP0 // idx = str->hash & tab->hmask
2873 | evlddx SAVE0, BASE, RA
2874 | slwi TMP0, TMP1, 5
2875 | slwi TMP1, TMP1, 3
2876 | sub TMP1, TMP0, TMP1
2877 | lbz TMP3, TAB:RB->marked
2878 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
2879 |1:
2880 | evldd TMP0, NODE:TMP2->key
2881 | evldd TMP1, NODE:TMP2->val
2882 | evcmpeq TMP0, STR:RC
2883 | checkanyfail >5
2884 | checknil TMP1
2885 | checkok >4 // Key found, but nil value?
2886 |2:
2887 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
2888 | evstdd SAVE0, NODE:TMP2->val
2889 | bne >7
2890 |3:
2891 | ins_next
2892 |
2893 |4: // Check for __newindex if previous value is nil.
2894 | lwz TAB:TMP1, TAB:RB->metatable
2895 | cmplwi TAB:TMP1, 0
2896 | beq <2 // No metatable: done.
2897 | lbz TMP0, TAB:TMP1->nomm
2898 | andi. TMP0, TMP0, 1<<MM_newindex
2899 | bne <2 // 'no __newindex' flag set: done.
2900 | b ->vmeta_tsets
2901 |
2902 |5: // Follow hash chain.
2903 | lwz NODE:TMP2, NODE:TMP2->next
2904 | cmplwi NODE:TMP2, 0
2905 | bne <1
2906 | // End of hash chain: key not found, add a new one.
2907 |
2908 | // But check for __newindex first.
2909 | lwz TAB:TMP1, TAB:RB->metatable
2910 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
2911 | stw PC, SAVE_PC
2912 | mr CARG1, L
2913 | cmplwi TAB:TMP1, 0
2914 | stw BASE, L->base
2915 | beq >6 // No metatable: continue.
2916 | lbz TMP0, TAB:TMP1->nomm
2917 | andi. TMP0, TMP0, 1<<MM_newindex
2918 | beq ->vmeta_tsets // 'no __newindex' flag NOT set: check.
2919 |6:
2920 | mr CARG2, TAB:RB
2921 | evstdd STR:RC, 0(CARG3)
2922 | bl extern lj_tab_newkey // (lua_State *L, GCtab *t, TValue *k)
2923 | // Returns TValue *.
2924 | lwz BASE, L->base
2925 | evstdd SAVE0, 0(CRET1)
2926 | b <3 // No 2nd write barrier needed.
2927 |
2928 |7: // Possible table write barrier for the value. Skip valiswhite check.
2929 | barrierback TAB:RB, TMP3, TMP0
2930 | b <3
2931 break;
2932 case BC_TSETB:
2933 | // RA = src*8, RB = table*8, RC = index*8
2934 | evlddx TAB:RB, BASE, RB
2935 | srwi TMP0, RC, 3
2936 | checktab TAB:RB
2937 | checkfail ->vmeta_tsetb
2938 | lwz TMP1, TAB:RB->asize
2939 | lwz TMP2, TAB:RB->array
2940 | lbz TMP3, TAB:RB->marked
2941 | cmplw TMP0, TMP1
2942 | evlddx SAVE0, BASE, RA
2943 | bge ->vmeta_tsetb
2944 | evlddx TMP1, TMP2, RC
2945 | checknil TMP1
2946 | checkok >5
2947 |1:
2948 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
2949 | evstddx SAVE0, TMP2, RC
2950 | bne >7
2951 |2:
2952 | ins_next
2953 |
2954 |5: // Check for __newindex if previous value is nil.
2955 | lwz TAB:TMP1, TAB:RB->metatable
2956 | cmplwi TAB:TMP1, 0
2957 | beq <1 // No metatable: done.
2958 | lbz TMP1, TAB:TMP1->nomm
2959 | andi. TMP1, TMP1, 1<<MM_newindex
2960 | bne <1 // 'no __newindex' flag set: done.
2961 | b ->vmeta_tsetb // Caveat: preserve TMP0!
2962 |
2963 |7: // Possible table write barrier for the value. Skip valiswhite check.
2964 | barrierback TAB:RB, TMP3, TMP0
2965 | b <2
2966 break;
2967
2968 case BC_TSETM:
2969 | // RA = base*8 (table at base-1), RD = num_const*8 (start index)
2970 | add RA, BASE, RA
2971 |1:
2972 | add TMP3, KBASE, RD
2973 | lwz TAB:CARG2, -4(RA) // Guaranteed to be a table.
2974 | addic. TMP0, MULTRES, -8
2975 | lwz TMP3, 4(TMP3) // Integer constant is in lo-word.
2976 | srwi CARG3, TMP0, 3
2977 | beq >4 // Nothing to copy?
2978 | add CARG3, CARG3, TMP3
2979 | lwz TMP2, TAB:CARG2->asize
2980 | slwi TMP1, TMP3, 3
2981 | lbz TMP3, TAB:CARG2->marked
2982 | cmplw CARG3, TMP2
2983 | add TMP2, RA, TMP0
2984 | lwz TMP0, TAB:CARG2->array
2985 | bgt >5
2986 | add TMP1, TMP1, TMP0
2987 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
2988 |3: // Copy result slots to table.
2989 | evldd TMP0, 0(RA)
2990 | addi RA, RA, 8
2991 | cmpw cr1, RA, TMP2
2992 | evstdd TMP0, 0(TMP1)
2993 | addi TMP1, TMP1, 8
2994 | blt cr1, <3
2995 | bne >7
2996 |4:
2997 | ins_next
2998 |
2999 |5: // Need to resize array part.
3000 | stw BASE, L->base
3001 | mr CARG1, L
3002 | stw PC, SAVE_PC
3003 | mr SAVE0, RD
3004 | bl extern lj_tab_reasize // (lua_State *L, GCtab *t, int nasize)
3005 | // Must not reallocate the stack.
3006 | mr RD, SAVE0
3007 | b <1
3008 |
3009 |7: // Possible table write barrier for any value. Skip valiswhite check.
3010 | barrierback TAB:CARG2, TMP3, TMP0
3011 | b <4
3012 break;
3013
3014 /* -- Calls and vararg handling ----------------------------------------- */
3015
3016 case BC_CALLM:
3017 | // RA = base*8, (RB = (nresults+1)*8,) RC = extra_nargs*8
3018 | add NARGS8:RC, NARGS8:RC, MULTRES
3019 | // Fall through. Assumes BC_CALL follows.
3020 break;
3021 case BC_CALL:
3022 | // RA = base*8, (RB = (nresults+1)*8,) RC = (nargs+1)*8
3023 | evlddx LFUNC:RB, BASE, RA
3024 | mr TMP2, BASE
3025 | add BASE, BASE, RA
3026 | subi NARGS8:RC, NARGS8:RC, 8
3027 | checkfunc LFUNC:RB
3028 | addi BASE, BASE, 8
3029 | checkfail ->vmeta_call
3030 | ins_call
3031 break;
3032
3033 case BC_CALLMT:
3034 | // RA = base*8, (RB = 0,) RC = extra_nargs*8
3035 | add NARGS8:RC, NARGS8:RC, MULTRES
3036 | // Fall through. Assumes BC_CALLT follows.
3037 break;
3038 case BC_CALLT:
3039 | // RA = base*8, (RB = 0,) RC = (nargs+1)*8
3040 | evlddx LFUNC:RB, BASE, RA
3041 | add RA, BASE, RA
3042 | lwz TMP1, FRAME_PC(BASE)
3043 | subi NARGS8:RC, NARGS8:RC, 8
3044 | checkfunc LFUNC:RB
3045 | addi RA, RA, 8
3046 | checkfail ->vmeta_callt
3047 |->BC_CALLT_Z:
3048 | andi. TMP0, TMP1, FRAME_TYPE // Caveat: preserve cr0 until the crand.
3049 | lbz TMP3, LFUNC:RB->ffid
3050 | xori TMP2, TMP1, FRAME_VARG
3051 | cmplwi cr1, NARGS8:RC, 0
3052 | bne >7
3053 |1:
3054 | stw LFUNC:RB, FRAME_FUNC(BASE) // Copy function down, but keep PC.
3055 | li TMP2, 0
3056 | cmplwi cr7, TMP3, 1 // (> FF_C) Calling a fast function?
3057 | beq cr1, >3
3058 |2:
3059 | addi TMP3, TMP2, 8
3060 | evlddx TMP0, RA, TMP2
3061 | cmplw cr1, TMP3, NARGS8:RC
3062 | evstddx TMP0, BASE, TMP2
3063 | mr TMP2, TMP3
3064 | bne cr1, <2
3065 |3:
3066 | crand 4*cr0+eq, 4*cr0+eq, 4*cr7+gt
3067 | beq >5
3068 |4:
3069 | ins_callt
3070 |
3071 |5: // Tailcall to a fast function with a Lua frame below.
3072 | lwz INS, -4(TMP1)
3073 | decode_RA8 RA, INS
3074 | sub TMP1, BASE, RA
3075 | lwz LFUNC:TMP1, FRAME_FUNC-8(TMP1)
3076 | lwz TMP1, LFUNC:TMP1->pc
3077 | lwz KBASE, PC2PROTO(k)(TMP1) // Need to prepare KBASE.
3078 | b <4
3079 |
3080 |7: // Tailcall from a vararg function.
3081 | andi. TMP0, TMP2, FRAME_TYPEP
3082 | bne <1 // Vararg frame below?
3083 | sub BASE, BASE, TMP2 // Relocate BASE down.
3084 | lwz TMP1, FRAME_PC(BASE)
3085 | andi. TMP0, TMP1, FRAME_TYPE
3086 | b <1
3087 break;
3088
3089 case BC_ITERC:
3090 | // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 ((2+1)*8))
3091 | subi RA, RA, 24 // evldd doesn't support neg. offsets.
3092 | mr TMP2, BASE
3093 | evlddx LFUNC:RB, BASE, RA
3094 | add BASE, BASE, RA
3095 | evldd TMP0, 8(BASE)
3096 | evldd TMP1, 16(BASE)
3097 | evstdd LFUNC:RB, 24(BASE) // Copy callable.
3098 | checkfunc LFUNC:RB
3099 | evstdd TMP0, 32(BASE) // Copy state.
3100 | li NARGS8:RC, 16 // Iterators get 2 arguments.
3101 | evstdd TMP1, 40(BASE) // Copy control var.
3102 | addi BASE, BASE, 32
3103 | checkfail ->vmeta_call
3104 | ins_call
3105 break;
3106
3107 case BC_ITERN:
3108 | // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 (2+1)*8)
3109#if LJ_HASJIT
3110 | // NYI: add hotloop, record BC_ITERN.
3111#endif
3112 | add RA, BASE, RA
3113 | lwz TAB:RB, -12(RA)
3114 | lwz RC, -4(RA) // Get index from control var.
3115 | lwz TMP0, TAB:RB->asize
3116 | lwz TMP1, TAB:RB->array
3117 | addi PC, PC, 4
3118 |1: // Traverse array part.
3119 | cmplw RC, TMP0
3120 | slwi TMP3, RC, 3
3121 | bge >5 // Index points after array part?
3122 | evlddx TMP2, TMP1, TMP3
3123 | checknil TMP2
3124 | lwz INS, -4(PC)
3125 | checkok >4
3126 | efdcfsi TMP0, RC
3127 | addi RC, RC, 1
3128 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
3129 | evstdd TMP2, 8(RA)
3130 | decode_RD4 TMP1, INS
3131 | stw RC, -4(RA) // Update control var.
3132 | add PC, TMP1, TMP3
3133 | evstdd TMP0, 0(RA)
3134 |3:
3135 | ins_next
3136 |
3137 |4: // Skip holes in array part.
3138 | addi RC, RC, 1
3139 | b <1
3140 |
3141 |5: // Traverse hash part.
3142 | lwz TMP1, TAB:RB->hmask
3143 | sub RC, RC, TMP0
3144 | lwz TMP2, TAB:RB->node
3145 |6:
3146 | cmplw RC, TMP1 // End of iteration? Branch to ITERL+1.
3147 | slwi TMP3, RC, 5
3148 | bgt <3
3149 | slwi RB, RC, 3
3150 | sub TMP3, TMP3, RB
3151 | evlddx RB, TMP2, TMP3
3152 | add NODE:TMP3, TMP2, TMP3
3153 | checknil RB
3154 | lwz INS, -4(PC)
3155 | checkok >7
3156 | evldd TMP3, NODE:TMP3->key
3157 | addis TMP2, PC, -(BCBIAS_J*4 >> 16)
3158 | evstdd RB, 8(RA)
3159 | add RC, RC, TMP0
3160 | decode_RD4 TMP1, INS
3161 | evstdd TMP3, 0(RA)
3162 | addi RC, RC, 1
3163 | add PC, TMP1, TMP2
3164 | stw RC, -4(RA) // Update control var.
3165 | b <3
3166 |
3167 |7: // Skip holes in hash part.
3168 | addi RC, RC, 1
3169 | b <6
3170 break;
3171
3172 case BC_ISNEXT:
3173 | // RA = base*8, RD = target (points to ITERN)
3174 | add RA, BASE, RA
3175 | li TMP2, -24
3176 | evlddx CFUNC:TMP1, RA, TMP2
3177 | lwz TMP2, -16(RA)
3178 | lwz TMP3, -8(RA)
3179 | evmergehi TMP0, CFUNC:TMP1, CFUNC:TMP1
3180 | cmpwi cr0, TMP2, LJ_TTAB
3181 | cmpwi cr1, TMP0, LJ_TFUNC
3182 | cmpwi cr6, TMP3, LJ_TNIL
3183 | bne cr1, >5
3184 | lbz TMP1, CFUNC:TMP1->ffid
3185 | crand 4*cr0+eq, 4*cr0+eq, 4*cr6+eq
3186 | cmpwi cr7, TMP1, FF_next_N
3187 | srwi TMP0, RD, 1
3188 | crand 4*cr0+eq, 4*cr0+eq, 4*cr7+eq
3189 | add TMP3, PC, TMP0
3190 | bne cr0, >5
3191 | stw ZERO, -4(RA) // Initialize control var.
3192 | addis PC, TMP3, -(BCBIAS_J*4 >> 16)
3193 |1:
3194 | ins_next
3195 |5: // Despecialize bytecode if any of the checks fail.
3196 | li TMP0, BC_JMP
3197 | li TMP1, BC_ITERC
3198 | stb TMP0, -1(PC)
3199 | addis PC, TMP3, -(BCBIAS_J*4 >> 16)
3200 | stb TMP1, 3(PC)
3201 | b <1
3202 break;
3203
3204 case BC_VARG:
3205 | // RA = base*8, RB = (nresults+1)*8, RC = numparams*8
3206 | lwz TMP0, FRAME_PC(BASE)
3207 | add RC, BASE, RC
3208 | add RA, BASE, RA
3209 | addi RC, RC, FRAME_VARG
3210 | add TMP2, RA, RB
3211 | subi TMP3, BASE, 8 // TMP3 = vtop
3212 | sub RC, RC, TMP0 // RC = vbase
3213 | // Note: RC may now be even _above_ BASE if nargs was < numparams.
3214 | cmplwi cr1, RB, 0
3215 | sub. TMP1, TMP3, RC
3216 | beq cr1, >5 // Copy all varargs?
3217 | subi TMP2, TMP2, 16
3218 | ble >2 // No vararg slots?
3219 |1: // Copy vararg slots to destination slots.
3220 | evldd TMP0, 0(RC)
3221 | addi RC, RC, 8
3222 | evstdd TMP0, 0(RA)
3223 | cmplw RA, TMP2
3224 | cmplw cr1, RC, TMP3
3225 | bge >3 // All destination slots filled?
3226 | addi RA, RA, 8
3227 | blt cr1, <1 // More vararg slots?
3228 |2: // Fill up remainder with nil.
3229 | evstdd TISNIL, 0(RA)
3230 | cmplw RA, TMP2
3231 | addi RA, RA, 8
3232 | blt <2
3233 |3:
3234 | ins_next
3235 |
3236 |5: // Copy all varargs.
3237 | lwz TMP0, L->maxstack
3238 | li MULTRES, 8 // MULTRES = (0+1)*8
3239 | ble <3 // No vararg slots?
3240 | add TMP2, RA, TMP1
3241 | cmplw TMP2, TMP0
3242 | addi MULTRES, TMP1, 8
3243 | bgt >7
3244 |6:
3245 | evldd TMP0, 0(RC)
3246 | addi RC, RC, 8
3247 | evstdd TMP0, 0(RA)
3248 | cmplw RC, TMP3
3249 | addi RA, RA, 8
3250 | blt <6 // More vararg slots?
3251 | b <3
3252 |
3253 |7: // Grow stack for varargs.
3254 | mr CARG1, L
3255 | stw RA, L->top
3256 | sub SAVE0, RC, BASE // Need delta, because BASE may change.
3257 | stw BASE, L->base
3258 | sub RA, RA, BASE
3259 | stw PC, SAVE_PC
3260 | srwi CARG2, TMP1, 3
3261 | bl extern lj_state_growstack // (lua_State *L, int n)
3262 | lwz BASE, L->base
3263 | add RA, BASE, RA
3264 | add RC, BASE, SAVE0
3265 | subi TMP3, BASE, 8
3266 | b <6
3267 break;
3268
3269 /* -- Returns ----------------------------------------------------------- */
3270
3271 case BC_RETM:
3272 | // RA = results*8, RD = extra_nresults*8
3273 | add RD, RD, MULTRES // MULTRES >= 8, so RD >= 8.
3274 | // Fall through. Assumes BC_RET follows.
3275 break;
3276
3277 case BC_RET:
3278 | // RA = results*8, RD = (nresults+1)*8
3279 | lwz PC, FRAME_PC(BASE)
3280 | add RA, BASE, RA
3281 | mr MULTRES, RD
3282 |1:
3283 | andi. TMP0, PC, FRAME_TYPE
3284 | xori TMP1, PC, FRAME_VARG
3285 | bne ->BC_RETV_Z
3286 |
3287 |->BC_RET_Z:
3288 | // BASE = base, RA = resultptr, RD = (nresults+1)*8, PC = return
3289 | lwz INS, -4(PC)
3290 | cmpwi RD, 8
3291 | subi TMP2, BASE, 8
3292 | subi RC, RD, 8
3293 | decode_RB8 RB, INS
3294 | beq >3
3295 | li TMP1, 0
3296 |2:
3297 | addi TMP3, TMP1, 8
3298 | evlddx TMP0, RA, TMP1
3299 | cmpw TMP3, RC
3300 | evstddx TMP0, TMP2, TMP1
3301 | beq >3
3302 | addi TMP1, TMP3, 8
3303 | evlddx TMP0, RA, TMP3
3304 | cmpw TMP1, RC
3305 | evstddx TMP0, TMP2, TMP3
3306 | bne <2
3307 |3:
3308 |5:
3309 | cmplw RB, RD
3310 | decode_RA8 RA, INS
3311 | bgt >6
3312 | sub BASE, TMP2, RA
3313 | lwz LFUNC:TMP1, FRAME_FUNC(BASE)
3314 | ins_next1
3315 | lwz TMP1, LFUNC:TMP1->pc
3316 | lwz KBASE, PC2PROTO(k)(TMP1)
3317 | ins_next2
3318 |
3319 |6: // Fill up results with nil.
3320 | subi TMP1, RD, 8
3321 | addi RD, RD, 8
3322 | evstddx TISNIL, TMP2, TMP1
3323 | b <5
3324 |
3325 |->BC_RETV_Z: // Non-standard return case.
3326 | andi. TMP2, TMP1, FRAME_TYPEP
3327 | bne ->vm_return
3328 | // Return from vararg function: relocate BASE down.
3329 | sub BASE, BASE, TMP1
3330 | lwz PC, FRAME_PC(BASE)
3331 | b <1
3332 break;
3333
3334 case BC_RET0: case BC_RET1:
3335 | // RA = results*8, RD = (nresults+1)*8
3336 | lwz PC, FRAME_PC(BASE)
3337 | add RA, BASE, RA
3338 | mr MULTRES, RD
3339 | andi. TMP0, PC, FRAME_TYPE
3340 | xori TMP1, PC, FRAME_VARG
3341 | bne ->BC_RETV_Z
3342 |
3343 | lwz INS, -4(PC)
3344 | subi TMP2, BASE, 8
3345 | decode_RB8 RB, INS
3346 if (op == BC_RET1) {
3347 | evldd TMP0, 0(RA)
3348 | evstdd TMP0, 0(TMP2)
3349 }
3350 |5:
3351 | cmplw RB, RD
3352 | decode_RA8 RA, INS
3353 | bgt >6
3354 | sub BASE, TMP2, RA
3355 | lwz LFUNC:TMP1, FRAME_FUNC(BASE)
3356 | ins_next1
3357 | lwz TMP1, LFUNC:TMP1->pc
3358 | lwz KBASE, PC2PROTO(k)(TMP1)
3359 | ins_next2
3360 |
3361 |6: // Fill up results with nil.
3362 | subi TMP1, RD, 8
3363 | addi RD, RD, 8
3364 | evstddx TISNIL, TMP2, TMP1
3365 | b <5
3366 break;
3367
3368 /* -- Loops and branches ------------------------------------------------ */
3369
3370 case BC_FORL:
3371#if LJ_HASJIT
3372 | hotloop
3373#endif
3374 | // Fall through. Assumes BC_IFORL follows.
3375 break;
3376
3377 case BC_JFORI:
3378 case BC_JFORL:
3379#if !LJ_HASJIT
3380 break;
3381#endif
3382 case BC_FORI:
3383 case BC_IFORL:
3384 | // RA = base*8, RD = target (after end of loop or start of loop)
3385 vk = (op == BC_IFORL || op == BC_JFORL);
3386 | add RA, BASE, RA
3387 | evldd TMP1, FORL_IDX*8(RA)
3388 | evldd TMP3, FORL_STEP*8(RA)
3389 | evldd TMP2, FORL_STOP*8(RA)
3390 if (!vk) {
3391 | evcmpgtu cr0, TMP1, TISNUM
3392 | evcmpgtu cr7, TMP3, TISNUM
3393 | evcmpgtu cr1, TMP2, TISNUM
3394 | cror 4*cr0+lt, 4*cr0+lt, 4*cr7+lt
3395 | cror 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3396 | blt ->vmeta_for
3397 }
3398 if (vk) {
3399 | efdadd TMP1, TMP1, TMP3
3400 | evstdd TMP1, FORL_IDX*8(RA)
3401 }
3402 | evcmpgts TMP3, TISNIL
3403 | evstdd TMP1, FORL_EXT*8(RA)
3404 | bge >2
3405 | efdcmpgt TMP1, TMP2
3406 |1:
3407 if (op != BC_JFORL) {
3408 | srwi RD, RD, 1
3409 | add RD, PC, RD
3410 if (op == BC_JFORI) {
3411 | addis PC, RD, -(BCBIAS_J*4 >> 16)
3412 } else {
3413 | addis RD, RD, -(BCBIAS_J*4 >> 16)
3414 }
3415 }
3416 if (op == BC_FORI) {
3417 | iselgt PC, RD, PC
3418 } else if (op == BC_IFORL) {
3419 | iselgt PC, PC, RD
3420 } else {
3421 | ble =>BC_JLOOP
3422 }
3423 | ins_next
3424 |2:
3425 | efdcmpgt TMP2, TMP1
3426 | b <1
3427 break;
3428
3429 case BC_ITERL:
3430#if LJ_HASJIT
3431 | hotloop
3432#endif
3433 | // Fall through. Assumes BC_IITERL follows.
3434 break;
3435
3436 case BC_JITERL:
3437#if !LJ_HASJIT
3438 break;
3439#endif
3440 case BC_IITERL:
3441 | // RA = base*8, RD = target
3442 | evlddx TMP1, BASE, RA
3443 | subi RA, RA, 8
3444 | checknil TMP1
3445 | checkok >1 // Stop if iterator returned nil.
3446 if (op == BC_JITERL) {
3447 | NYI
3448 } else {
3449 | branch_RD // Otherwise save control var + branch.
3450 | evstddx TMP1, BASE, RA
3451 }
3452 |1:
3453 | ins_next
3454 break;
3455
3456 case BC_LOOP:
3457 | // RA = base*8, RD = target (loop extent)
3458 | // Note: RA/RD is only used by trace recorder to determine scope/extent
3459 | // This opcode does NOT jump, it's only purpose is to detect a hot loop.
3460#if LJ_HASJIT
3461 | hotloop
3462#endif
3463 | // Fall through. Assumes BC_ILOOP follows.
3464 break;
3465
3466 case BC_ILOOP:
3467 | // RA = base*8, RD = target (loop extent)
3468 | ins_next
3469 break;
3470
3471 case BC_JLOOP:
3472#if LJ_HASJIT
3473 | NYI
3474#endif
3475 break;
3476
3477 case BC_JMP:
3478 | // RA = base*8 (only used by trace recorder), RD = target
3479 | branch_RD
3480 | ins_next
3481 break;
3482
3483 /* -- Function headers -------------------------------------------------- */
3484
3485 case BC_FUNCF:
3486#if LJ_HASJIT
3487 | hotcall
3488#endif
3489 case BC_FUNCV: /* NYI: compiled vararg functions. */
3490 | // Fall through. Assumes BC_IFUNCF/BC_IFUNCV follow.
3491 break;
3492
3493 case BC_JFUNCF:
3494#if !LJ_HASJIT
3495 break;
3496#endif
3497 case BC_IFUNCF:
3498 | // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
3499 | lwz TMP2, L->maxstack
3500 | lbz TMP1, -4+PC2PROTO(numparams)(PC)
3501 | lwz KBASE, -4+PC2PROTO(k)(PC)
3502 | cmplw RA, TMP2
3503 | slwi TMP1, TMP1, 3
3504 | bgt ->vm_growstack_l
3505 | ins_next1
3506 |2:
3507 | cmplw NARGS8:RC, TMP1 // Check for missing parameters.
3508 | ble >3
3509 if (op == BC_JFUNCF) {
3510 | NYI
3511 } else {
3512 | ins_next2
3513 }
3514 |
3515 |3: // Clear missing parameters.
3516 | evstddx TISNIL, BASE, NARGS8:RC
3517 | addi NARGS8:RC, NARGS8:RC, 8
3518 | b <2
3519 break;
3520
3521 case BC_JFUNCV:
3522#if !LJ_HASJIT
3523 break;
3524#endif
3525 | NYI // NYI: compiled vararg functions
3526 break; /* NYI: compiled vararg functions. */
3527
3528 case BC_IFUNCV:
3529 | // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
3530 | lwz TMP2, L->maxstack
3531 | add TMP1, BASE, RC
3532 | add TMP0, RA, RC
3533 | stw LFUNC:RB, 4(TMP1) // Store copy of LFUNC.
3534 | addi TMP3, RC, 8+FRAME_VARG
3535 | lwz KBASE, -4+PC2PROTO(k)(PC)
3536 | cmplw TMP0, TMP2
3537 | stw TMP3, 0(TMP1) // Store delta + FRAME_VARG.
3538 | bge ->vm_growstack_l
3539 | lbz TMP2, -4+PC2PROTO(numparams)(PC)
3540 | mr RA, BASE
3541 | mr RC, TMP1
3542 | ins_next1
3543 | cmpwi TMP2, 0
3544 | addi BASE, TMP1, 8
3545 | beq >3
3546 |1:
3547 | cmplw RA, RC // Less args than parameters?
3548 | evldd TMP0, 0(RA)
3549 | bge >4
3550 | evstdd TISNIL, 0(RA) // Clear old fixarg slot (help the GC).
3551 | addi RA, RA, 8
3552 |2:
3553 | addic. TMP2, TMP2, -1
3554 | evstdd TMP0, 8(TMP1)
3555 | addi TMP1, TMP1, 8
3556 | bne <1
3557 |3:
3558 | ins_next2
3559 |
3560 |4: // Clear missing parameters.
3561 | evmr TMP0, TISNIL
3562 | b <2
3563 break;
3564
3565 case BC_FUNCC:
3566 case BC_FUNCCW:
3567 | // BASE = new base, RA = BASE+framesize*8, RB = CFUNC, RC = nargs*8
3568 if (op == BC_FUNCC) {
3569 | lwz TMP3, CFUNC:RB->f
3570 } else {
3571 | lwz TMP3, DISPATCH_GL(wrapf)(DISPATCH)
3572 }
3573 | add TMP1, RA, NARGS8:RC
3574 | lwz TMP2, L->maxstack
3575 | add RC, BASE, NARGS8:RC
3576 | stw BASE, L->base
3577 | cmplw TMP1, TMP2
3578 | stw RC, L->top
3579 | li_vmstate C
3580 | mtctr TMP3
3581 if (op == BC_FUNCCW) {
3582 | lwz CARG2, CFUNC:RB->f
3583 }
3584 | mr CARG1, L
3585 | bgt ->vm_growstack_c // Need to grow stack.
3586 | st_vmstate
3587 | bctrl // (lua_State *L [, lua_CFunction f])
3588 | // Returns nresults.
3589 | lwz TMP1, L->top
3590 | slwi RD, CRET1, 3
3591 | lwz BASE, L->base
3592 | li_vmstate INTERP
3593 | lwz PC, FRAME_PC(BASE) // Fetch PC of caller.
3594 | sub RA, TMP1, RD // RA = L->top - nresults*8
3595 | st_vmstate
3596 | b ->vm_returnc
3597 break;
3598
3599 /* ---------------------------------------------------------------------- */
3600
3601 default:
3602 fprintf(stderr, "Error: undefined opcode BC_%s\n", bc_names[op]);
3603 exit(2);
3604 break;
3605 }
3606}
3607
3608static int build_backend(BuildCtx *ctx)
3609{
3610 int op;
3611
3612 dasm_growpc(Dst, BC__MAX);
3613
3614 build_subroutines(ctx);
3615
3616 |.code_op
3617 for (op = 0; op < BC__MAX; op++)
3618 build_ins(ctx, (BCOp)op, op);
3619
3620 return BC__MAX;
3621}
3622
3623/* Emit pseudo frame-info for all assembler functions. */
3624static void emit_asm_debug(BuildCtx *ctx)
3625{
3626 int i;
3627 switch (ctx->mode) {
3628 case BUILD_elfasm:
3629 fprintf(ctx->fp, "\t.section .debug_frame,\"\",@progbits\n");
3630 fprintf(ctx->fp,
3631 ".Lframe0:\n"
3632 "\t.long .LECIE0-.LSCIE0\n"
3633 ".LSCIE0:\n"
3634 "\t.long 0xffffffff\n"
3635 "\t.byte 0x1\n"
3636 "\t.string \"\"\n"
3637 "\t.uleb128 0x1\n"
3638 "\t.sleb128 -4\n"
3639 "\t.byte 65\n"
3640 "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
3641 "\t.align 2\n"
3642 ".LECIE0:\n\n");
3643 fprintf(ctx->fp,
3644 ".LSFDE0:\n"
3645 "\t.long .LEFDE0-.LASFDE0\n"
3646 ".LASFDE0:\n"
3647 "\t.long .Lframe0\n"
3648 "\t.long .Lbegin\n"
3649 "\t.long %d\n"
3650 "\t.byte 0xe\n\t.uleb128 %d\n"
3651 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
3652 "\t.byte 0x5\n\t.uleb128 70\n\t.sleb128 37\n",
3653 (int)ctx->codesz, CFRAME_SIZE);
3654 for (i = 14; i <= 31; i++)
3655 fprintf(ctx->fp,
3656 "\t.byte %d\n\t.uleb128 %d\n"
3657 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n",
3658 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i));
3659 fprintf(ctx->fp,
3660 "\t.align 2\n"
3661 ".LEFDE0:\n\n");
3662 fprintf(ctx->fp, "\t.section .eh_frame,\"a\",@progbits\n");
3663 fprintf(ctx->fp,
3664 ".Lframe1:\n"
3665 "\t.long .LECIE1-.LSCIE1\n"
3666 ".LSCIE1:\n"
3667 "\t.long 0\n"
3668 "\t.byte 0x1\n"
3669 "\t.string \"zPR\"\n"
3670 "\t.uleb128 0x1\n"
3671 "\t.sleb128 -4\n"
3672 "\t.byte 65\n"
3673 "\t.uleb128 6\n" /* augmentation length */
3674 "\t.byte 0x1b\n" /* pcrel|sdata4 */
3675 "\t.long lj_err_unwind_dwarf-.\n"
3676 "\t.byte 0x1b\n" /* pcrel|sdata4 */
3677 "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
3678 "\t.align 2\n"
3679 ".LECIE1:\n\n");
3680 fprintf(ctx->fp,
3681 ".LSFDE1:\n"
3682 "\t.long .LEFDE1-.LASFDE1\n"
3683 ".LASFDE1:\n"
3684 "\t.long .LASFDE1-.Lframe1\n"
3685 "\t.long .Lbegin-.\n"
3686 "\t.long %d\n"
3687 "\t.uleb128 0\n" /* augmentation length */
3688 "\t.byte 0xe\n\t.uleb128 %d\n"
3689 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n"
3690 "\t.byte 0x5\n\t.uleb128 70\n\t.sleb128 37\n",
3691 (int)ctx->codesz, CFRAME_SIZE);
3692 for (i = 14; i <= 31; i++)
3693 fprintf(ctx->fp,
3694 "\t.byte %d\n\t.uleb128 %d\n"
3695 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n",
3696 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i));
3697 fprintf(ctx->fp,
3698 "\t.align 2\n"
3699 ".LEFDE1:\n\n");
3700 break;
3701 default:
3702 break;
3703 }
3704}
3705
generated by cgit v1.2.3-55-g6feb (git 2.39.1) at 2025-08-12 12:50:44 +0000