blob: 8f7e75145a3389e68e9081f62166bd89482b1ac5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
@setlocal
@pushd %~dp0
@set _C=Debug
:parse_args
@if /i "%1"=="release" set _C=Release
@if not "%1"=="" shift & goto parse_args
@if "%VCToolsVersion%"=="" call :StartDeveloperCommandPrompt
@echo build %_C%
:: Initialize required files/folders
call build_init.cmd
:: DTF
call dtf\dtf.cmd %_C% || exit /b
:: internal
call internal\internal.cmd %_C% || exit /b
:: libs
call libs\libs.cmd %_C% || exit /b
:: api
call api\api.cmd %_C% || exit /b
:: burn
call burn\burn.cmd %_C% || exit /b
:: wix
call wix\wix.cmd %_C% || exit /b
:: ext
call ext\ext.cmd %_C% || exit /b
:: samples
:: call samples\samples.cmd %_C% || exit /b
:: integration tests
call test\test.cmd %_C% || exit /b
goto LExit
:StartDeveloperCommandPrompt
echo Initializing developer command prompt
for /f "usebackq delims=" %%i in (`"%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe" -latest -property installationPath`) do (
if exist "%%i\Common7\Tools\vsdevcmd.bat" (
call "%%i\Common7\Tools\vsdevcmd.bat" -no_logo
exit /b
)
)
exit /b 2
:LExit
@popd
@endlocal
|
