aboutsummaryrefslogtreecommitdiff
path: root/src
diff options
context:
space:
mode:
authorMike Pall <mike>2011-07-03 15:01:50 +0200
committerMike Pall <mike>2011-07-03 15:01:50 +0200
commit161f1a5eb00ee58cc00834c031e95ffc8d3dfead (patch)
tree1650acf6b8adced2b618aec1dc270a59305a4df2 /src
parent8addfefb33cfcf32c758c59d34f2d2bbd55a4966 (diff)
downloadluajit-161f1a5eb00ee58cc00834c031e95ffc8d3dfead.tar.gz
luajit-161f1a5eb00ee58cc00834c031e95ffc8d3dfead.tar.bz2
luajit-161f1a5eb00ee58cc00834c031e95ffc8d3dfead.zip
PPC: Separate PPC vs. PPCSPE interpreter source files.
Diffstat (limited to 'src')
-rw-r--r--src/Makefile8
-rw-r--r--src/buildvm_ppcspe.dasc3710
-rw-r--r--src/buildvm_ppcspe.h10
3 files changed, 3715 insertions, 13 deletions
diff --git a/src/Makefile b/src/Makefile
index 9f7bcfcc..5c3e6a89 100644
--- a/src/Makefile
+++ b/src/Makefile
@@ -341,7 +341,7 @@ DASM_FLAGS_X86=
341DASM_FLAGS_X64= -D X64 341DASM_FLAGS_X64= -D X64
342DASM_FLAGS_X64WIN= -D X64 -D X64WIN 342DASM_FLAGS_X64WIN= -D X64 -D X64WIN
343DASM_FLAGS_ARM= 343DASM_FLAGS_ARM=
344DASM_FLAGS_PPCSPE= -D SPE 344DASM_FLAGS_PPCSPE=
345 345
346BUILDVM_O= buildvm.o buildvm_asm.o buildvm_peobj.o buildvm_lib.o buildvm_fold.o 346BUILDVM_O= buildvm.o buildvm_asm.o buildvm_peobj.o buildvm_lib.o buildvm_fold.o
347BUILDVM_T= buildvm 347BUILDVM_T= buildvm
@@ -478,7 +478,7 @@ distclean: clean
478 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_X64) -o buildvm_x64.h buildvm_x86.dasc 478 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_X64) -o buildvm_x64.h buildvm_x86.dasc
479 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_X64WIN) -o buildvm_x64win.h buildvm_x86.dasc 479 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_X64WIN) -o buildvm_x64win.h buildvm_x86.dasc
480 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_ARM) -o buildvm_arm.h buildvm_arm.dasc 480 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_ARM) -o buildvm_arm.h buildvm_arm.dasc
481 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_PPCSPE) -o buildvm_ppcspe.h buildvm_ppc.dasc 481 $(Q)$(DASM) $(DASM_DISTFLAGS) $(DASM_FLAGS_PPCSPE) -o buildvm_ppcspe.h buildvm_ppcspe.dasc
482 482
483depend: 483depend:
484 @for file in $(ALL_HDRGEN) $(ALL_DYNGEN); do \ 484 @for file in $(ALL_HDRGEN) $(ALL_DYNGEN); do \
@@ -516,9 +516,9 @@ buildvm_arm.h: buildvm_arm.dasc
516 $(E) "DYNASM $@" 516 $(E) "DYNASM $@"
517 $(Q)$(DASM) $(DASM_FLAGS) $(DASM_FLAGS_ARM) -o $@ buildvm_arm.dasc 517 $(Q)$(DASM) $(DASM_FLAGS) $(DASM_FLAGS_ARM) -o $@ buildvm_arm.dasc
518 518
519buildvm_ppcspe.h: buildvm_ppc.dasc 519buildvm_ppcspe.h: buildvm_ppcspe.dasc
520 $(E) "DYNASM $@" 520 $(E) "DYNASM $@"
521 $(Q)$(DASM) $(DASM_FLAGS) $(DASM_FLAGS_PPCSPE) -o $@ buildvm_ppc.dasc 521 $(Q)$(DASM) $(DASM_FLAGS) $(DASM_FLAGS_PPCSPE) -o $@ buildvm_ppcspe.dasc
522 522
523buildvm.o: $(ALL_DYNGEN) $(DASM_DIR)/dasm_*.h 523buildvm.o: $(ALL_DYNGEN) $(DASM_DIR)/dasm_*.h
524 524
diff --git a/src/buildvm_ppcspe.dasc b/src/buildvm_ppcspe.dasc
new file mode 100644
index 00000000..18e160e9
--- /dev/null
+++ b/src/buildvm_ppcspe.dasc
@@ -0,0 +1,3710 @@
1|// Low-level VM code for PowerPC/e500 CPUs.
2|// Bytecode interpreter, fast functions and helper functions.
3|// Copyright (C) 2005-2011 Mike Pall. See Copyright Notice in luajit.h
4|
5|.arch ppc
6|.section code_op, code_sub
7|
8|.actionlist build_actionlist
9|.globals GLOB_
10|.globalnames globnames
11|.externnames extnames
12|
13|// Note: The ragged indentation of the instructions is intentional.
14|// The starting columns indicate data dependencies.
15|
16|//-----------------------------------------------------------------------
17|
18|// Fixed register assignments for the interpreter.
19|// Don't use: r1 = sp, r2 and r13 = reserved and/or small data area ptr
20|
21|// The following must be C callee-save (but BASE is often refetched).
22|.define BASE, r14 // Base of current Lua stack frame.
23|.define KBASE, r15 // Constants of current Lua function.
24|.define PC, r16 // Next PC.
25|.define DISPATCH, r17 // Opcode dispatch table.
26|.define LREG, r18 // Register holding lua_State (also in SAVE_L).
27|.define MULTRES, r19 // Size of multi-result: (nresults+1)*8.
28|
29|// Constants for vectorized type-comparisons (hi+low GPR). C callee-save.
30|.define TISNUM, r22
31|.define TISSTR, r23
32|.define TISTAB, r24
33|.define TISFUNC, r25
34|.define TISNIL, r26
35|.define TOBIT, r27
36|.define ZERO, TOBIT // Zero in lo word.
37|
38|// The following temporaries are not saved across C calls, except for RA.
39|.define RA, r20 // Callee-save.
40|.define RB, r10
41|.define RC, r11
42|.define RD, r12
43|.define INS, r7 // Overlaps CARG5.
44|
45|.define TMP0, r0
46|.define TMP1, r8
47|.define TMP2, r9
48|.define TMP3, r6 // Overlaps CARG4.
49|
50|// Saved temporaries.
51|.define SAVE0, r21
52|
53|// Calling conventions.
54|.define CARG1, r3
55|.define CARG2, r4
56|.define CARG3, r5
57|.define CARG4, r6 // Overlaps TMP3.
58|.define CARG5, r7 // Overlaps INS.
59|
60|.define CRET1, r3
61|.define CRET2, r4
62|
63|// Stack layout while in interpreter. Must match with lj_frame.h.
64|.define SAVE_LR, 180(sp)
65|.define CFRAME_SPACE, 176 // Delta for sp.
66|// Back chain for sp: 176(sp) <-- sp entering interpreter
67|.define SAVE_r31, 168(sp) // 64 bit register saves.
68|.define SAVE_r30, 160(sp)
69|.define SAVE_r29, 152(sp)
70|.define SAVE_r28, 144(sp)
71|.define SAVE_r27, 136(sp)
72|.define SAVE_r26, 128(sp)
73|.define SAVE_r25, 120(sp)
74|.define SAVE_r24, 112(sp)
75|.define SAVE_r23, 104(sp)
76|.define SAVE_r22, 96(sp)
77|.define SAVE_r21, 88(sp)
78|.define SAVE_r20, 80(sp)
79|.define SAVE_r19, 72(sp)
80|.define SAVE_r18, 64(sp)
81|.define SAVE_r17, 56(sp)
82|.define SAVE_r16, 48(sp)
83|.define SAVE_r15, 40(sp)
84|.define SAVE_r14, 32(sp)
85|.define SAVE_ERRF, 28(sp) // 32 bit C frame info.
86|.define SAVE_NRES, 24(sp)
87|.define SAVE_CFRAME, 20(sp)
88|.define SAVE_L, 16(sp)
89|.define SAVE_PC, 12(sp)
90|.define SAVE_MULTRES, 8(sp)
91|// Next frame lr: 4(sp)
92|// Back chain for sp: 0(sp) <-- sp while in interpreter
93|
94|.macro save_, reg; evstdd reg, SAVE_..reg; .endmacro
95|.macro rest_, reg; evldd reg, SAVE_..reg; .endmacro
96|
97|.macro saveregs
98| stwu sp, -CFRAME_SPACE(sp)
99| save_ r14; save_ r15; save_ r16; save_ r17; save_ r18; save_ r19
100| mflr r0
101| save_ r20; save_ r21; save_ r22; save_ r23; save_ r24; save_ r25
102| stw r0, SAVE_LR
103| save_ r26; save_ r27; save_ r28; save_ r29; save_ r30; save_ r31
104|.endmacro
105|
106|.macro restoreregs
107| lwz r0, SAVE_LR
108| rest_ r14; rest_ r15; rest_ r16; rest_ r17; rest_ r18; rest_ r19
109| mtlr r0
110| rest_ r20; rest_ r21; rest_ r22; rest_ r23; rest_ r24; rest_ r25
111| rest_ r26; rest_ r27; rest_ r28; rest_ r29; rest_ r30; rest_ r31
112| addi sp, sp, CFRAME_SPACE
113|.endmacro
114|
115|// Type definitions. Some of these are only used for documentation.
116|.type L, lua_State, LREG
117|.type GL, global_State
118|.type TVALUE, TValue
119|.type GCOBJ, GCobj
120|.type STR, GCstr
121|.type TAB, GCtab
122|.type LFUNC, GCfuncL
123|.type CFUNC, GCfuncC
124|.type PROTO, GCproto
125|.type UPVAL, GCupval
126|.type NODE, Node
127|.type NARGS8, int
128|.type TRACE, GCtrace
129|
130|//-----------------------------------------------------------------------
131|
132|// These basic macros should really be part of DynASM.
133|.macro srwi, rx, ry, n; rlwinm rx, ry, 32-n, n, 31; .endmacro
134|.macro slwi, rx, ry, n; rlwinm rx, ry, n, 0, 31-n; .endmacro
135|.macro rotlwi, rx, ry, n; rlwinm rx, ry, n, 0, 31; .endmacro
136|.macro rotlw, rx, ry, rn; rlwnm rx, ry, rn, 0, 31; .endmacro
137|.macro subi, rx, ry, i; addi rx, ry, -i; .endmacro
138|
139|// Trap for not-yet-implemented parts.
140|.macro NYI; tw 4, sp, sp; .endmacro
141|
142|//-----------------------------------------------------------------------
143|
144|// Access to frame relative to BASE.
145|.define FRAME_PC, -8
146|.define FRAME_FUNC, -4
147|
148|// Instruction decode.
149|.macro decode_OP4, dst, ins; rlwinm dst, ins, 2, 22, 29; .endmacro
150|.macro decode_RA8, dst, ins; rlwinm dst, ins, 27, 21, 28; .endmacro
151|.macro decode_RB8, dst, ins; rlwinm dst, ins, 11, 21, 28; .endmacro
152|.macro decode_RC8, dst, ins; rlwinm dst, ins, 19, 21, 28; .endmacro
153|.macro decode_RD8, dst, ins; rlwinm dst, ins, 19, 13, 28; .endmacro
154|
155|.macro decode_OP1, dst, ins; rlwinm dst, ins, 0, 24, 31; .endmacro
156|.macro decode_RD4, dst, ins; rlwinm dst, ins, 18, 14, 29; .endmacro
157|
158|// Instruction fetch.
159|.macro ins_NEXT1
160| lwz INS, 0(PC)
161| addi PC, PC, 4
162|.endmacro
163|// Instruction decode+dispatch.
164|.macro ins_NEXT2
165| decode_OP4 TMP1, INS
166| decode_RB8 RB, INS
167| decode_RD8 RD, INS
168| lwzx TMP0, DISPATCH, TMP1
169| decode_RA8 RA, INS
170| decode_RC8 RC, INS
171| mtctr TMP0
172| bctr
173|.endmacro
174|.macro ins_NEXT
175| ins_NEXT1
176| ins_NEXT2
177|.endmacro
178|
179|// Instruction footer.
180|.if 1
181| // Replicated dispatch. Less unpredictable branches, but higher I-Cache use.
182| .define ins_next, ins_NEXT
183| .define ins_next_, ins_NEXT
184| .define ins_next1, ins_NEXT1
185| .define ins_next2, ins_NEXT2
186|.else
187| // Common dispatch. Lower I-Cache use, only one (very) unpredictable branch.
188| // Affects only certain kinds of benchmarks (and only with -j off).
189| .macro ins_next
190| b ->ins_next
191| .endmacro
192| .macro ins_next1
193| .endmacro
194| .macro ins_next2
195| b ->ins_next
196| .endmacro
197| .macro ins_next_
198| ->ins_next:
199| ins_NEXT
200| .endmacro
201|.endif
202|
203|// Call decode and dispatch.
204|.macro ins_callt
205| // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
206| lwz PC, LFUNC:RB->pc
207| lwz INS, 0(PC)
208| addi PC, PC, 4
209| decode_OP4 TMP1, INS
210| decode_RA8 RA, INS
211| lwzx TMP0, DISPATCH, TMP1
212| add RA, RA, BASE
213| mtctr TMP0
214| bctr
215|.endmacro
216|
217|.macro ins_call
218| // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, PC = caller PC
219| stw PC, FRAME_PC(BASE)
220| ins_callt
221|.endmacro
222|
223|//-----------------------------------------------------------------------
224|
225|// Macros to test operand types.
226|.macro checknum, reg; evcmpltu reg, TISNUM; .endmacro
227|.macro checkstr, reg; evcmpeq reg, TISSTR; .endmacro
228|.macro checktab, reg; evcmpeq reg, TISTAB; .endmacro
229|.macro checkfunc, reg; evcmpeq reg, TISFUNC; .endmacro
230|.macro checknil, reg; evcmpeq reg, TISNIL; .endmacro
231|.macro checkok, label; blt label; .endmacro
232|.macro checkfail, label; bge label; .endmacro
233|.macro checkanyfail, label; bns label; .endmacro
234|.macro checkallok, label; bso label; .endmacro
235|
236|.macro branch_RD
237| srwi TMP0, RD, 1
238| add PC, PC, TMP0
239| addis PC, PC, -(BCBIAS_J*4 >> 16)
240|.endmacro
241|
242|// Assumes DISPATCH is relative to GL.
243#define DISPATCH_GL(field) (GG_DISP2G + (int)offsetof(global_State, field))
244#define DISPATCH_J(field) (GG_DISP2J + (int)offsetof(jit_State, field))
245|
246#define PC2PROTO(field) ((int)offsetof(GCproto, field)-(int)sizeof(GCproto))
247|
248|.macro hotloop
249| NYI
250|.endmacro
251|
252|.macro hotcall
253| NYI
254|.endmacro
255|
256|// Set current VM state. Uses TMP0.
257|.macro li_vmstate, st; li TMP0, ~LJ_VMST_..st; .endmacro
258|.macro st_vmstate; stw TMP0, DISPATCH_GL(vmstate)(DISPATCH); .endmacro
259|
260|// Move table write barrier back. Overwrites mark and tmp.
261|.macro barrierback, tab, mark, tmp
262| lwz tmp, DISPATCH_GL(gc.grayagain)(DISPATCH)
263| // Assumes LJ_GC_BLACK is 0x04.
264| rlwinm mark, mark, 0, 30, 28 // black2gray(tab)
265| stw tab, DISPATCH_GL(gc.grayagain)(DISPATCH)
266| stb mark, tab->marked
267| stw tmp, tab->gclist
268|.endmacro
269|
270|//-----------------------------------------------------------------------
271
272/* Generate subroutines used by opcodes and other parts of the VM. */
273/* The .code_sub section should be last to help static branch prediction. */
274static void build_subroutines(BuildCtx *ctx)
275{
276 |.code_sub
277 |
278 |//-----------------------------------------------------------------------
279 |//-- Return handling ----------------------------------------------------
280 |//-----------------------------------------------------------------------
281 |
282 |->vm_returnp:
283 | // See vm_return. Also: TMP2 = previous base.
284 | andi. TMP0, PC, FRAME_P
285 | evsplati TMP1, LJ_TTRUE
286 | beq ->cont_dispatch
287 |
288 | // Return from pcall or xpcall fast func.
289 | lwz PC, FRAME_PC(TMP2) // Fetch PC of previous frame.
290 | mr BASE, TMP2 // Restore caller base.
291 | // Prepending may overwrite the pcall frame, so do it at the end.
292 | stwu TMP1, FRAME_PC(RA) // Prepend true to results.
293 |
294 |->vm_returnc:
295 | andi. TMP0, PC, FRAME_TYPE
296 | addi RD, RD, 8 // RD = (nresults+1)*8.
297 | mr MULTRES, RD
298 | beq ->BC_RET_Z // Handle regular return to Lua.
299 |
300 |->vm_return:
301 | // BASE = base, RA = resultptr, RD/MULTRES = (nresults+1)*8, PC = return
302 | // TMP0 = PC & FRAME_TYPE
303 | cmpwi TMP0, FRAME_C
304 | rlwinm TMP2, PC, 0, 0, 28
305 | li_vmstate C
306 | sub TMP2, BASE, TMP2 // TMP2 = previous base.
307 | bne ->vm_returnp
308 |
309 | addic. TMP1, RD, -8
310 | stw TMP2, L->base
311 | lwz TMP2, SAVE_NRES
312 | subi BASE, BASE, 8
313 | st_vmstate
314 | slwi TMP2, TMP2, 3
315 | beq >2
316 |1:
317 | addic. TMP1, TMP1, -8
318 | evldd TMP0, 0(RA)
319 | addi RA, RA, 8
320 | evstdd TMP0, 0(BASE)
321 | addi BASE, BASE, 8
322 | bne <1
323 |
324 |2:
325 | cmpw TMP2, RD // More/less results wanted?
326 | bne >6
327 |3:
328 | stw BASE, L->top // Store new top.
329 |
330 |->vm_leave_cp:
331 | lwz TMP0, SAVE_CFRAME // Restore previous C frame.
332 | li CRET1, 0 // Ok return status for vm_pcall.
333 | stw TMP0, L->cframe
334 |
335 |->vm_leave_unw:
336 | restoreregs
337 | blr
338 |
339 |6:
340 | ble >7 // Less results wanted?
341 | // More results wanted. Check stack size and fill up results with nil.
342 | lwz TMP1, L->maxstack
343 | cmplw BASE, TMP1
344 | bge >8
345 | evstdd TISNIL, 0(BASE)
346 | addi RD, RD, 8
347 | addi BASE, BASE, 8
348 | b <2
349 |
350 |7: // Less results wanted.
351 | sub TMP0, RD, TMP2
352 | cmpwi TMP2, 0 // LUA_MULTRET+1 case?
353 | sub TMP0, BASE, TMP0 // Subtract the difference.
354 | iseleq BASE, BASE, TMP0 // Either keep top or shrink it.
355 | b <3
356 |
357 |8: // Corner case: need to grow stack for filling up results.
358 | // This can happen if:
359 | // - A C function grows the stack (a lot).
360 | // - The GC shrinks the stack in between.
361 | // - A return back from a lua_call() with (high) nresults adjustment.
362 | stw BASE, L->top // Save current top held in BASE (yes).
363 | mr SAVE0, RD
364 | mr CARG2, TMP2
365 | mr CARG1, L
366 | bl extern lj_state_growstack // (lua_State *L, int n)
367 | lwz TMP2, SAVE_NRES
368 | mr RD, SAVE0
369 | slwi TMP2, TMP2, 3
370 | lwz BASE, L->top // Need the (realloced) L->top in BASE.
371 | b <2
372 |
373 |->vm_unwind_c: // Unwind C stack, return from vm_pcall.
374 | // (void *cframe, int errcode)
375 | mr sp, CARG1
376 | mr CRET1, CARG2
377 |->vm_unwind_c_eh: // Landing pad for external unwinder.
378 | lwz L, SAVE_L
379 | li TMP0, ~LJ_VMST_C
380 | lwz GL:TMP1, L->glref
381 | stw TMP0, GL:TMP1->vmstate
382 | b ->vm_leave_unw
383 |
384 |->vm_unwind_ff: // Unwind C stack, return from ff pcall.
385 | // (void *cframe)
386 | rlwinm sp, CARG1, 0, 0, 29
387 |->vm_unwind_ff_eh: // Landing pad for external unwinder.
388 | lwz L, SAVE_L
389 | evsplati TISNUM, LJ_TISNUM+1 // Setup type comparison constants.
390 | evsplati TISFUNC, LJ_TFUNC
391 | lus TOBIT, 0x4338
392 | evsplati TISTAB, LJ_TTAB
393 | li TMP0, 0
394 | lwz BASE, L->base
395 | evmergelo TOBIT, TOBIT, TMP0
396 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
397 | evsplati TISSTR, LJ_TSTR
398 | li TMP1, LJ_TFALSE
399 | evsplati TISNIL, LJ_TNIL
400 | li_vmstate INTERP
401 | lwz PC, FRAME_PC(BASE) // Fetch PC of previous frame.
402 | la RA, -8(BASE) // Results start at BASE-8.
403 | addi DISPATCH, DISPATCH, GG_G2DISP
404 | stw TMP1, 0(RA) // Prepend false to error message.
405 | li RD, 16 // 2 results: false + error message.
406 | st_vmstate
407 | b ->vm_returnc
408 |
409 |//-----------------------------------------------------------------------
410 |//-- Grow stack for calls -----------------------------------------------
411 |//-----------------------------------------------------------------------
412 |
413 |->vm_growstack_c: // Grow stack for C function.
414 | li CARG2, LUA_MINSTACK
415 | b >2
416 |
417 |->vm_growstack_l: // Grow stack for Lua function.
418 | // BASE = new base, RA = BASE+framesize*8, RC = nargs*8, PC = first PC
419 | add RC, BASE, RC
420 | sub RA, RA, BASE
421 | stw BASE, L->base
422 | addi PC, PC, 4 // Must point after first instruction.
423 | stw RC, L->top
424 | srwi CARG2, RA, 3
425 |2:
426 | // L->base = new base, L->top = top
427 | stw PC, SAVE_PC
428 | mr CARG1, L
429 | bl extern lj_state_growstack // (lua_State *L, int n)
430 | lwz BASE, L->base
431 | lwz RC, L->top
432 | lwz LFUNC:RB, FRAME_FUNC(BASE)
433 | sub RC, RC, BASE
434 | // BASE = new base, RB = LFUNC/CFUNC, RC = nargs*8, FRAME_PC(BASE) = PC
435 | ins_callt // Just retry the call.
436 |
437 |//-----------------------------------------------------------------------
438 |//-- Entry points into the assembler VM ---------------------------------
439 |//-----------------------------------------------------------------------
440 |
441 |->vm_resume: // Setup C frame and resume thread.
442 | // (lua_State *L, TValue *base, int nres1 = 0, ptrdiff_t ef = 0)
443 | saveregs
444 | mr L, CARG1
445 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
446 | mr BASE, CARG2
447 | lbz TMP1, L->status
448 | stw L, SAVE_L
449 | li PC, FRAME_CP
450 | addi TMP0, sp, CFRAME_RESUME
451 | addi DISPATCH, DISPATCH, GG_G2DISP
452 | stw CARG3, SAVE_NRES
453 | cmplwi TMP1, 0
454 | stw CARG3, SAVE_ERRF
455 | stw TMP0, L->cframe
456 | stw CARG3, SAVE_CFRAME
457 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
458 | beq >3
459 |
460 | // Resume after yield (like a return).
461 | mr RA, BASE
462 | lwz BASE, L->base
463 | evsplati TISNUM, LJ_TISNUM+1 // Setup type comparison constants.
464 | lwz TMP1, L->top
465 | evsplati TISFUNC, LJ_TFUNC
466 | lus TOBIT, 0x4338
467 | evsplati TISTAB, LJ_TTAB
468 | lwz PC, FRAME_PC(BASE)
469 | li TMP2, 0
470 | evsplati TISSTR, LJ_TSTR
471 | sub RD, TMP1, BASE
472 | evmergelo TOBIT, TOBIT, TMP2
473 | stb CARG3, L->status
474 | andi. TMP0, PC, FRAME_TYPE
475 | li_vmstate INTERP
476 | addi RD, RD, 8
477 | evsplati TISNIL, LJ_TNIL
478 | mr MULTRES, RD
479 | st_vmstate
480 | beq ->BC_RET_Z
481 | b ->vm_return
482 |
483 |->vm_pcall: // Setup protected C frame and enter VM.
484 | // (lua_State *L, TValue *base, int nres1, ptrdiff_t ef)
485 | saveregs
486 | li PC, FRAME_CP
487 | stw CARG4, SAVE_ERRF
488 | b >1
489 |
490 |->vm_call: // Setup C frame and enter VM.
491 | // (lua_State *L, TValue *base, int nres1)
492 | saveregs
493 | li PC, FRAME_C
494 |
495 |1: // Entry point for vm_pcall above (PC = ftype).
496 | lwz TMP1, L:CARG1->cframe
497 | stw CARG3, SAVE_NRES
498 | mr L, CARG1
499 | stw CARG1, SAVE_L
500 | mr BASE, CARG2
501 | stw sp, L->cframe // Add our C frame to cframe chain.
502 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
503 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
504 | stw TMP1, SAVE_CFRAME
505 | addi DISPATCH, DISPATCH, GG_G2DISP
506 |
507 |3: // Entry point for vm_cpcall/vm_resume (BASE = base, PC = ftype).
508 | lwz TMP2, L->base // TMP2 = old base (used in vmeta_call).
509 | evsplati TISNUM, LJ_TISNUM+1 // Setup type comparison constants.
510 | lwz TMP1, L->top
511 | evsplati TISFUNC, LJ_TFUNC
512 | add PC, PC, BASE
513 | evsplati TISTAB, LJ_TTAB
514 | lus TOBIT, 0x4338
515 | li TMP0, 0
516 | sub PC, PC, TMP2 // PC = frame delta + frame type
517 | evsplati TISSTR, LJ_TSTR
518 | sub NARGS8:RC, TMP1, BASE
519 | evmergelo TOBIT, TOBIT, TMP0
520 | li_vmstate INTERP
521 | evsplati TISNIL, LJ_TNIL
522 | st_vmstate
523 |
524 |->vm_call_dispatch:
525 | // TMP2 = old base, BASE = new base, RC = nargs*8, PC = caller PC
526 | li TMP0, -8
527 | evlddx LFUNC:RB, BASE, TMP0
528 | checkfunc LFUNC:RB
529 | checkfail ->vmeta_call
530 |
531 |->vm_call_dispatch_f:
532 | ins_call
533 | // BASE = new base, RB = func, RC = nargs*8, PC = caller PC
534 |
535 |->vm_cpcall: // Setup protected C frame, call C.
536 | // (lua_State *L, lua_CFunction func, void *ud, lua_CPFunction cp)
537 | saveregs
538 | mr L, CARG1
539 | lwz TMP0, L:CARG1->stack
540 | stw CARG1, SAVE_L
541 | lwz TMP1, L->top
542 | stw CARG1, SAVE_PC // Any value outside of bytecode is ok.
543 | sub TMP0, TMP0, TMP1 // Compute -savestack(L, L->top).
544 | lwz TMP1, L->cframe
545 | stw sp, L->cframe // Add our C frame to cframe chain.
546 | li TMP2, 0
547 | stw TMP0, SAVE_NRES // Neg. delta means cframe w/o frame.
548 | stw TMP2, SAVE_ERRF // No error function.
549 | stw TMP1, SAVE_CFRAME
550 | mtctr CARG4
551 | bctrl // (lua_State *L, lua_CFunction func, void *ud)
552 | mr. BASE, CRET1
553 | lwz DISPATCH, L->glref // Setup pointer to dispatch table.
554 | li PC, FRAME_CP
555 | addi DISPATCH, DISPATCH, GG_G2DISP
556 | bne <3 // Else continue with the call.
557 | b ->vm_leave_cp // No base? Just remove C frame.
558 |
559 |//-----------------------------------------------------------------------
560 |//-- Metamethod handling ------------------------------------------------
561 |//-----------------------------------------------------------------------
562 |
563 |// The lj_meta_* functions (except for lj_meta_cat) don't reallocate the
564 |// stack, so BASE doesn't need to be reloaded across these calls.
565 |
566 |//-- Continuation dispatch ----------------------------------------------
567 |
568 |->cont_dispatch:
569 | // BASE = meta base, RA = resultptr, RD = (nresults+1)*8
570 | lwz TMP0, -12(BASE) // Continuation.
571 | mr RB, BASE
572 | mr BASE, TMP2 // Restore caller BASE.
573 | lwz LFUNC:TMP1, FRAME_FUNC(TMP2)
574 | cmplwi TMP0, 0
575 | lwz PC, -16(RB) // Restore PC from [cont|PC].
576 | beq >1
577 | subi TMP2, RD, 8
578 | lwz TMP1, LFUNC:TMP1->pc
579 | evstddx TISNIL, RA, TMP2 // Ensure one valid arg.
580 | lwz KBASE, PC2PROTO(k)(TMP1)
581 | // BASE = base, RA = resultptr, RB = meta base
582 | mtctr TMP0
583 | bctr // Jump to continuation.
584 |
585 |1: // Tail call from C function.
586 | subi TMP1, RB, 16
587 | sub RC, TMP1, BASE
588 | b ->vm_call_tail
589 |
590 |->cont_cat: // RA = resultptr, RB = meta base
591 | lwz INS, -4(PC)
592 | subi CARG2, RB, 16
593 | decode_RB8 SAVE0, INS
594 | evldd TMP0, 0(RA)
595 | add TMP1, BASE, SAVE0
596 | stw BASE, L->base
597 | cmplw TMP1, CARG2
598 | sub CARG3, CARG2, TMP1
599 | decode_RA8 RA, INS
600 | evstdd TMP0, 0(CARG2)
601 | bne ->BC_CAT_Z
602 | evstddx TMP0, BASE, RA
603 | b ->cont_nop
604 |
605 |//-- Table indexing metamethods -----------------------------------------
606 |
607 |->vmeta_tgets1:
608 | evmergelo STR:RC, TISSTR, STR:RC
609 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
610 | decode_RB8 RB, INS
611 | evstdd STR:RC, 0(CARG3)
612 | add CARG2, BASE, RB
613 | b >1
614 |
615 |->vmeta_tgets:
616 | evmergelo TAB:RB, TISTAB, TAB:RB
617 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
618 | evmergelo STR:RC, TISSTR, STR:RC
619 | evstdd TAB:RB, 0(CARG2)
620 | la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
621 | evstdd STR:RC, 0(CARG3)
622 | b >1
623 |
624 |->vmeta_tgetb: // TMP0 = index
625 | efdcfsi TMP0, TMP0
626 | decode_RB8 RB, INS
627 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
628 | add CARG2, BASE, RB
629 | evstdd TMP0, 0(CARG3)
630 | b >1
631 |
632 |->vmeta_tgetv:
633 | decode_RB8 RB, INS
634 | decode_RC8 RC, INS
635 | add CARG2, BASE, RB
636 | add CARG3, BASE, RC
637 |1:
638 | stw BASE, L->base
639 | mr CARG1, L
640 | stw PC, SAVE_PC
641 | bl extern lj_meta_tget // (lua_State *L, TValue *o, TValue *k)
642 | // Returns TValue * (finished) or NULL (metamethod).
643 | cmplwi CRET1, 0
644 | beq >3
645 | evldd TMP0, 0(CRET1)
646 | evstddx TMP0, BASE, RA
647 | ins_next
648 |
649 |3: // Call __index metamethod.
650 | // BASE = base, L->top = new base, stack = cont/func/t/k
651 | subfic TMP1, BASE, FRAME_CONT
652 | lwz BASE, L->top
653 | stw PC, -16(BASE) // [cont|PC]
654 | add PC, TMP1, BASE
655 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
656 | li NARGS8:RC, 16 // 2 args for func(t, k).
657 | b ->vm_call_dispatch_f
658 |
659 |//-----------------------------------------------------------------------
660 |
661 |->vmeta_tsets1:
662 | evmergelo STR:RC, TISSTR, STR:RC
663 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
664 | decode_RB8 RB, INS
665 | evstdd STR:RC, 0(CARG3)
666 | add CARG2, BASE, RB
667 | b >1
668 |
669 |->vmeta_tsets:
670 | evmergelo TAB:RB, TISTAB, TAB:RB
671 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
672 | evmergelo STR:RC, TISSTR, STR:RC
673 | evstdd TAB:RB, 0(CARG2)
674 | la CARG3, DISPATCH_GL(tmptv2)(DISPATCH)
675 | evstdd STR:RC, 0(CARG3)
676 | b >1
677 |
678 |->vmeta_tsetb: // TMP0 = index
679 | efdcfsi TMP0, TMP0
680 | decode_RB8 RB, INS
681 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
682 | add CARG2, BASE, RB
683 | evstdd TMP0, 0(CARG3)
684 | b >1
685 |
686 |->vmeta_tsetv:
687 | decode_RB8 RB, INS
688 | decode_RC8 RC, INS
689 | add CARG2, BASE, RB
690 | add CARG3, BASE, RC
691 |1:
692 | stw BASE, L->base
693 | mr CARG1, L
694 | stw PC, SAVE_PC
695 | bl extern lj_meta_tset // (lua_State *L, TValue *o, TValue *k)
696 | // Returns TValue * (finished) or NULL (metamethod).
697 | cmplwi CRET1, 0
698 | evlddx TMP0, BASE, RA
699 | beq >3
700 | // NOBARRIER: lj_meta_tset ensures the table is not black.
701 | evstdd TMP0, 0(CRET1)
702 | ins_next
703 |
704 |3: // Call __newindex metamethod.
705 | // BASE = base, L->top = new base, stack = cont/func/t/k/(v)
706 | subfic TMP1, BASE, FRAME_CONT
707 | lwz BASE, L->top
708 | stw PC, -16(BASE) // [cont|PC]
709 | add PC, TMP1, BASE
710 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
711 | li NARGS8:RC, 24 // 3 args for func(t, k, v)
712 | evstdd TMP0, 16(BASE) // Copy value to third argument.
713 | b ->vm_call_dispatch_f
714 |
715 |//-- Comparison metamethods ---------------------------------------------
716 |
717 |->vmeta_comp:
718 | mr CARG1, L
719 | subi PC, PC, 4
720 | add CARG2, BASE, RA
721 | stw PC, SAVE_PC
722 | add CARG3, BASE, RD
723 | stw BASE, L->base
724 | decode_OP1 CARG4, INS
725 | bl extern lj_meta_comp // (lua_State *L, TValue *o1, *o2, int op)
726 | // Returns 0/1 or TValue * (metamethod).
727 |3:
728 | cmplwi CRET1, 1
729 | bgt ->vmeta_binop
730 |4:
731 | lwz INS, 0(PC)
732 | addi PC, PC, 4
733 | decode_RD4 TMP2, INS
734 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
735 | add TMP2, TMP2, TMP3
736 | isellt PC, PC, TMP2
737 |->cont_nop:
738 | ins_next
739 |
740 |->cont_ra: // RA = resultptr
741 | lwz INS, -4(PC)
742 | evldd TMP0, 0(RA)
743 | decode_RA8 TMP1, INS
744 | evstddx TMP0, BASE, TMP1
745 | b ->cont_nop
746 |
747 |->cont_condt: // RA = resultptr
748 | lwz TMP0, 0(RA)
749 | li TMP1, LJ_TTRUE
750 | cmplw TMP1, TMP0 // Branch if result is true.
751 | b <4
752 |
753 |->cont_condf: // RA = resultptr
754 | lwz TMP0, 0(RA)
755 | li TMP1, LJ_TFALSE
756 | cmplw TMP0, TMP1 // Branch if result is false.
757 | b <4
758 |
759 |->vmeta_equal:
760 | // CARG2, CARG3, CARG4 are already set by BC_ISEQV/BC_ISNEV.
761 | subi PC, PC, 4
762 | stw BASE, L->base
763 | mr CARG1, L
764 | stw PC, SAVE_PC
765 | bl extern lj_meta_equal // (lua_State *L, GCobj *o1, *o2, int ne)
766 | // Returns 0/1 or TValue * (metamethod).
767 | b <3
768 |
769 |//-- Arithmetic metamethods ---------------------------------------------
770 |
771 |->vmeta_arith_vn:
772 | add CARG3, BASE, RB
773 | add CARG4, KBASE, RC
774 | b >1
775 |
776 |->vmeta_arith_nv:
777 | add CARG3, KBASE, RC
778 | add CARG4, BASE, RB
779 | b >1
780 |
781 |->vmeta_unm:
782 | add CARG3, BASE, RD
783 | mr CARG4, CARG3
784 | b >1
785 |
786 |->vmeta_arith_vv:
787 | add CARG3, BASE, RB
788 | add CARG4, BASE, RC
789 |1:
790 | add CARG2, BASE, RA
791 | stw BASE, L->base
792 | mr CARG1, L
793 | stw PC, SAVE_PC
794 | decode_OP1 CARG5, INS // Caveat: CARG5 overlaps INS.
795 | bl extern lj_meta_arith // (lua_State *L, TValue *ra,*rb,*rc, BCReg op)
796 | // Returns NULL (finished) or TValue * (metamethod).
797 | cmplwi CRET1, 0
798 | beq ->cont_nop
799 |
800 | // Call metamethod for binary op.
801 |->vmeta_binop:
802 | // BASE = old base, CRET1 = new base, stack = cont/func/o1/o2
803 | sub TMP1, CRET1, BASE
804 | stw PC, -16(CRET1) // [cont|PC]
805 | addi PC, TMP1, FRAME_CONT
806 | mr BASE, CRET1
807 | li NARGS8:RC, 16 // 2 args for func(o1, o2).
808 | b ->vm_call_dispatch
809 |
810 |->vmeta_len:
811#ifdef LUAJIT_ENABLE_LUA52COMPAT
812 | mr SAVE0, CARG1
813#endif
814 | add CARG2, BASE, RD
815 | stw BASE, L->base
816 | mr CARG1, L
817 | stw PC, SAVE_PC
818 | bl extern lj_meta_len // (lua_State *L, TValue *o)
819 | // Returns NULL (retry) or TValue * (metamethod base).
820#ifdef LUAJIT_ENABLE_LUA52COMPAT
821 | cmplwi CRET1, 0
822 | bne ->vmeta_binop // Binop call for compatibility.
823 | mr CARG1, SAVE0
824 | b ->BC_LEN_Z
825#else
826 | b ->vmeta_binop // Binop call for compatibility.
827#endif
828 |
829 |//-- Call metamethod ----------------------------------------------------
830 |
831 |->vmeta_call: // Resolve and call __call metamethod.
832 | // TMP2 = old base, BASE = new base, RC = nargs*8
833 | mr CARG1, L
834 | stw TMP2, L->base // This is the callers base!
835 | subi CARG2, BASE, 8
836 | stw PC, SAVE_PC
837 | add CARG3, BASE, RC
838 | mr SAVE0, NARGS8:RC
839 | bl extern lj_meta_call // (lua_State *L, TValue *func, TValue *top)
840 | lwz LFUNC:RB, FRAME_FUNC(BASE) // Guaranteed to be a function here.
841 | addi NARGS8:RC, SAVE0, 8 // Got one more argument now.
842 | ins_call
843 |
844 |->vmeta_callt: // Resolve __call for BC_CALLT.
845 | // BASE = old base, RA = new base, RC = nargs*8
846 | mr CARG1, L
847 | stw BASE, L->base
848 | subi CARG2, RA, 8
849 | stw PC, SAVE_PC
850 | add CARG3, RA, RC
851 | mr SAVE0, NARGS8:RC
852 | bl extern lj_meta_call // (lua_State *L, TValue *func, TValue *top)
853 | lwz TMP1, FRAME_PC(BASE)
854 | addi NARGS8:RC, SAVE0, 8 // Got one more argument now.
855 | lwz LFUNC:RB, FRAME_FUNC(RA) // Guaranteed to be a function here.
856 | b ->BC_CALLT_Z
857 |
858 |//-- Argument coercion for 'for' statement ------------------------------
859 |
860 |->vmeta_for:
861 | mr CARG1, L
862 | stw BASE, L->base
863 | mr CARG2, RA
864 | stw PC, SAVE_PC
865 | mr SAVE0, INS
866 | bl extern lj_meta_for // (lua_State *L, TValue *base)
867#if LJ_HASJIT
868 | decode_OP1 TMP0, SAVE0
869#endif
870 | decode_RA8 RA, SAVE0
871#if LJ_HASJIT
872 | cmpwi TMP0, BC_JFORI
873#endif
874 | decode_RD8 RD, SAVE0
875#if LJ_HASJIT
876 | beq =>BC_JFORI
877#endif
878 | b =>BC_FORI
879 |
880 |//-----------------------------------------------------------------------
881 |//-- Fast functions -----------------------------------------------------
882 |//-----------------------------------------------------------------------
883 |
884 |.macro .ffunc, name
885 |->ff_ .. name:
886 |.endmacro
887 |
888 |.macro .ffunc_1, name
889 |->ff_ .. name:
890 | cmplwi NARGS8:RC, 8
891 | evldd CARG1, 0(BASE)
892 | blt ->fff_fallback
893 |.endmacro
894 |
895 |.macro .ffunc_2, name
896 |->ff_ .. name:
897 | cmplwi NARGS8:RC, 16
898 | evldd CARG1, 0(BASE)
899 | evldd CARG2, 8(BASE)
900 | blt ->fff_fallback
901 |.endmacro
902 |
903 |.macro .ffunc_n, name
904 | .ffunc_1 name
905 | checknum CARG1
906 | checkfail ->fff_fallback
907 |.endmacro
908 |
909 |.macro .ffunc_nn, name
910 | .ffunc_2 name
911 | evmergehi TMP0, CARG1, CARG2
912 | checknum TMP0
913 | checkanyfail ->fff_fallback
914 |.endmacro
915 |
916 |// Inlined GC threshold check. Caveat: uses TMP0 and TMP1.
917 |.macro ffgccheck
918 | lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
919 | lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
920 | cmplw TMP0, TMP1
921 | bgel ->fff_gcstep
922 |.endmacro
923 |
924 |//-- Base library: checks -----------------------------------------------
925 |
926 |.ffunc assert
927 | cmplwi NARGS8:RC, 8
928 | evldd TMP0, 0(BASE)
929 | blt ->fff_fallback
930 | evaddw TMP1, TISNIL, TISNIL // Synthesize LJ_TFALSE.
931 | la RA, -8(BASE)
932 | evcmpltu cr1, TMP0, TMP1
933 | lwz PC, FRAME_PC(BASE)
934 | bge cr1, ->fff_fallback
935 | evstdd TMP0, 0(RA)
936 | addi RD, NARGS8:RC, 8 // Compute (nresults+1)*8.
937 | beq ->fff_res // Done if exactly 1 argument.
938 | li TMP1, 8
939 | subi RC, RC, 8
940 |1:
941 | cmplw TMP1, RC
942 | evlddx TMP0, BASE, TMP1
943 | evstddx TMP0, RA, TMP1
944 | addi TMP1, TMP1, 8
945 | bne <1
946 | b ->fff_res
947 |
948 |.ffunc type
949 | cmplwi NARGS8:RC, 8
950 | lwz CARG1, 0(BASE)
951 | blt ->fff_fallback
952 | li TMP2, ~LJ_TNUMX
953 | cmplw CARG1, TISNUM
954 | not TMP1, CARG1
955 | isellt TMP1, TMP2, TMP1
956 | slwi TMP1, TMP1, 3
957 | la TMP2, CFUNC:RB->upvalue
958 | evlddx STR:CRET1, TMP2, TMP1
959 | b ->fff_restv
960 |
961 |//-- Base library: getters and setters ---------------------------------
962 |
963 |.ffunc_1 getmetatable
964 | checktab CARG1
965 | evmergehi TMP1, CARG1, CARG1
966 | checkfail >6
967 |1: // Field metatable must be at same offset for GCtab and GCudata!
968 | lwz TAB:RB, TAB:CARG1->metatable
969 |2:
970 | evmr CRET1, TISNIL
971 | cmplwi TAB:RB, 0
972 | lwz STR:RC, DISPATCH_GL(gcroot[GCROOT_MMNAME+MM_metatable])(DISPATCH)
973 | beq ->fff_restv
974 | lwz TMP0, TAB:RB->hmask
975 | evmergelo CRET1, TISTAB, TAB:RB // Use metatable as default result.
976 | lwz TMP1, STR:RC->hash
977 | lwz NODE:TMP2, TAB:RB->node
978 | evmergelo STR:RC, TISSTR, STR:RC
979 | and TMP1, TMP1, TMP0 // idx = str->hash & tab->hmask
980 | slwi TMP0, TMP1, 5
981 | slwi TMP1, TMP1, 3
982 | sub TMP1, TMP0, TMP1
983 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
984 |3: // Rearranged logic, because we expect _not_ to find the key.
985 | evldd TMP0, NODE:TMP2->key
986 | evldd TMP1, NODE:TMP2->val
987 | evcmpeq TMP0, STR:RC
988 | lwz NODE:TMP2, NODE:TMP2->next
989 | checkallok >5
990 | cmplwi NODE:TMP2, 0
991 | beq ->fff_restv // Not found, keep default result.
992 | b <3
993 |5:
994 | checknil TMP1
995 | checkok ->fff_restv // Ditto for nil value.
996 | evmr CRET1, TMP1 // Return value of mt.__metatable.
997 | b ->fff_restv
998 |
999 |6:
1000 | cmpwi TMP1, LJ_TUDATA
1001 | not TMP1, TMP1
1002 | beq <1
1003 | checknum CARG1
1004 | slwi TMP1, TMP1, 2
1005 | li TMP2, 4*~LJ_TNUMX
1006 | isellt TMP1, TMP2, TMP1
1007 | la TMP2, DISPATCH_GL(gcroot[GCROOT_BASEMT])(DISPATCH)
1008 | lwzx TAB:RB, TMP2, TMP1
1009 | b <2
1010 |
1011 |.ffunc_2 setmetatable
1012 | // Fast path: no mt for table yet and not clearing the mt.
1013 | evmergehi TMP0, TAB:CARG1, TAB:CARG2
1014 | checktab TMP0
1015 | checkanyfail ->fff_fallback
1016 | lwz TAB:TMP1, TAB:CARG1->metatable
1017 | cmplwi TAB:TMP1, 0
1018 | lbz TMP3, TAB:CARG1->marked
1019 | bne ->fff_fallback
1020 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
1021 | stw TAB:CARG2, TAB:CARG1->metatable
1022 | beq ->fff_restv
1023 | barrierback TAB:CARG1, TMP3, TMP0
1024 | b ->fff_restv
1025 |
1026 |.ffunc rawget
1027 | cmplwi NARGS8:RC, 16
1028 | evldd CARG2, 0(BASE)
1029 | blt ->fff_fallback
1030 | checktab CARG2
1031 | la CARG3, 8(BASE)
1032 | checkfail ->fff_fallback
1033 | mr CARG1, L
1034 | bl extern lj_tab_get // (lua_State *L, GCtab *t, cTValue *key)
1035 | // Returns cTValue *.
1036 | evldd CRET1, 0(CRET1)
1037 | b ->fff_restv
1038 |
1039 |//-- Base library: conversions ------------------------------------------
1040 |
1041 |.ffunc tonumber
1042 | // Only handles the number case inline (without a base argument).
1043 | cmplwi NARGS8:RC, 8
1044 | evldd CARG1, 0(BASE)
1045 | bne ->fff_fallback // Exactly one argument.
1046 | checknum CARG1
1047 | checkok ->fff_restv
1048 | b ->fff_fallback
1049 |
1050 |.ffunc_1 tostring
1051 | // Only handles the string or number case inline.
1052 | checkstr CARG1
1053 | // A __tostring method in the string base metatable is ignored.
1054 | checkok ->fff_restv // String key?
1055 | // Handle numbers inline, unless a number base metatable is present.
1056 | lwz TMP0, DISPATCH_GL(gcroot[GCROOT_BASEMT_NUM])(DISPATCH)
1057 | checknum CARG1
1058 | cmplwi cr1, TMP0, 0
1059 | stw BASE, L->base // Add frame since C call can throw.
1060 | crand 4*cr0+eq, 4*cr0+lt, 4*cr1+eq
1061 | stw PC, SAVE_PC // Redundant (but a defined value).
1062 | bne ->fff_fallback
1063 | ffgccheck
1064 | mr CARG1, L
1065 | mr CARG2, BASE
1066 | bl extern lj_str_fromnum // (lua_State *L, lua_Number *np)
1067 | // Returns GCstr *.
1068 | evmergelo STR:CRET1, TISSTR, STR:CRET1
1069 | b ->fff_restv
1070 |
1071 |//-- Base library: iterators -------------------------------------------
1072 |
1073 |.ffunc next
1074 | cmplwi NARGS8:RC, 8
1075 | evldd CARG2, 0(BASE)
1076 | blt ->fff_fallback
1077 | evstddx TISNIL, BASE, NARGS8:RC // Set missing 2nd arg to nil.
1078 | checktab TAB:CARG2
1079 | lwz PC, FRAME_PC(BASE)
1080 | checkfail ->fff_fallback
1081 | stw BASE, L->base // Add frame since C call can throw.
1082 | mr CARG1, L
1083 | stw BASE, L->top // Dummy frame length is ok.
1084 | la CARG3, 8(BASE)
1085 | stw PC, SAVE_PC
1086 | bl extern lj_tab_next // (lua_State *L, GCtab *t, TValue *key)
1087 | // Returns 0 at end of traversal.
1088 | cmplwi CRET1, 0
1089 | evmr CRET1, TISNIL
1090 | beq ->fff_restv // End of traversal: return nil.
1091 | evldd TMP0, 8(BASE) // Copy key and value to results.
1092 | la RA, -8(BASE)
1093 | evldd TMP1, 16(BASE)
1094 | evstdd TMP0, 0(RA)
1095 | li RD, (2+1)*8
1096 | evstdd TMP1, 8(RA)
1097 | b ->fff_res
1098 |
1099 |.ffunc_1 pairs
1100 | checktab TAB:CARG1
1101 | lwz PC, FRAME_PC(BASE)
1102 | checkfail ->fff_fallback
1103#ifdef LUAJIT_ENABLE_LUA52COMPAT
1104 | lwz TAB:TMP2, TAB:CARG1->metatable
1105 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1106 | cmplwi TAB:TMP2, 0
1107 | la RA, -8(BASE)
1108 | bne ->fff_fallback
1109#else
1110 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1111 | la RA, -8(BASE)
1112#endif
1113 | evstdd TISNIL, 8(BASE)
1114 | li RD, (3+1)*8
1115 | evstdd CFUNC:TMP0, 0(RA)
1116 | b ->fff_res
1117 |
1118 |.ffunc_2 ipairs_aux
1119 | checktab TAB:CARG1
1120 | lwz PC, FRAME_PC(BASE)
1121 | checkfail ->fff_fallback
1122 | checknum CARG2
1123 | lus TMP3, 0x3ff0
1124 | checkfail ->fff_fallback
1125 | efdctsi TMP2, CARG2
1126 | lwz TMP0, TAB:CARG1->asize
1127 | evmergelo TMP3, TMP3, ZERO
1128 | lwz TMP1, TAB:CARG1->array
1129 | efdadd CARG2, CARG2, TMP3
1130 | addi TMP2, TMP2, 1
1131 | la RA, -8(BASE)
1132 | cmplw TMP0, TMP2
1133 | slwi TMP3, TMP2, 3
1134 | evstdd CARG2, 0(RA)
1135 | ble >2 // Not in array part?
1136 | evlddx TMP1, TMP1, TMP3
1137 |1:
1138 | checknil TMP1
1139 | li RD, (0+1)*8
1140 | checkok ->fff_res // End of iteration, return 0 results.
1141 | li RD, (2+1)*8
1142 | evstdd TMP1, 8(RA)
1143 | b ->fff_res
1144 |2: // Check for empty hash part first. Otherwise call C function.
1145 | lwz TMP0, TAB:CARG1->hmask
1146 | cmplwi TMP0, 0
1147 | li RD, (0+1)*8
1148 | beq ->fff_res
1149 | mr CARG2, TMP2
1150 | bl extern lj_tab_getinth // (GCtab *t, int32_t key)
1151 | // Returns cTValue * or NULL.
1152 | cmplwi CRET1, 0
1153 | li RD, (0+1)*8
1154 | beq ->fff_res
1155 | evldd TMP1, 0(CRET1)
1156 | b <1
1157 |
1158 |.ffunc_1 ipairs
1159 | checktab TAB:CARG1
1160 | lwz PC, FRAME_PC(BASE)
1161 | checkfail ->fff_fallback
1162#ifdef LUAJIT_ENABLE_LUA52COMPAT
1163 | lwz TAB:TMP2, TAB:CARG1->metatable
1164 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1165 | cmplwi TAB:TMP2, 0
1166 | la RA, -8(BASE)
1167 | bne ->fff_fallback
1168#else
1169 | evldd CFUNC:TMP0, CFUNC:RB->upvalue[0]
1170 | la RA, -8(BASE)
1171#endif
1172 | evsplati TMP1, 0
1173 | li RD, (3+1)*8
1174 | evstdd TMP1, 8(BASE)
1175 | evstdd CFUNC:TMP0, 0(RA)
1176 | b ->fff_res
1177 |
1178 |//-- Base library: catch errors ----------------------------------------
1179 |
1180 |.ffunc pcall
1181 | cmplwi NARGS8:RC, 8
1182 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1183 | blt ->fff_fallback
1184 | mr TMP2, BASE
1185 | la BASE, 8(BASE)
1186 | // Remember active hook before pcall.
1187 | rlwinm TMP3, TMP3, 32-HOOK_ACTIVE_SHIFT, 31, 31
1188 | subi NARGS8:RC, NARGS8:RC, 8
1189 | addi PC, TMP3, 8+FRAME_PCALL
1190 | b ->vm_call_dispatch
1191 |
1192 |.ffunc_2 xpcall
1193 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1194 | mr TMP2, BASE
1195 | checkfunc CARG2 // Traceback must be a function.
1196 | checkfail ->fff_fallback
1197 | la BASE, 16(BASE)
1198 | // Remember active hook before pcall.
1199 | rlwinm TMP3, TMP3, 32-HOOK_ACTIVE_SHIFT, 31, 31
1200 | evstdd CARG2, 0(TMP2) // Swap function and traceback.
1201 | subi NARGS8:RC, NARGS8:RC, 16
1202 | evstdd CARG1, 8(TMP2)
1203 | addi PC, TMP3, 16+FRAME_PCALL
1204 | b ->vm_call_dispatch
1205 |
1206 |//-- Coroutine library --------------------------------------------------
1207 |
1208 |.macro coroutine_resume_wrap, resume
1209 |.if resume
1210 |.ffunc_1 coroutine_resume
1211 | evmergehi TMP0, L:CARG1, L:CARG1
1212 |.else
1213 |.ffunc coroutine_wrap_aux
1214 | lwz L:CARG1, CFUNC:RB->upvalue[0].gcr
1215 |.endif
1216 |.if resume
1217 | cmpwi TMP0, LJ_TTHREAD
1218 | bne ->fff_fallback
1219 |.endif
1220 | lbz TMP0, L:CARG1->status
1221 | lwz TMP1, L:CARG1->cframe
1222 | lwz CARG2, L:CARG1->top
1223 | cmplwi cr0, TMP0, LUA_YIELD
1224 | lwz TMP2, L:CARG1->base
1225 | cmplwi cr1, TMP1, 0
1226 | lwz TMP0, L:CARG1->maxstack
1227 | cmplw cr7, CARG2, TMP2
1228 | lwz PC, FRAME_PC(BASE)
1229 | crorc 4*cr6+lt, 4*cr0+gt, 4*cr1+eq // st>LUA_YIELD || cframe!=0
1230 | add TMP2, CARG2, NARGS8:RC
1231 | crandc 4*cr6+gt, 4*cr7+eq, 4*cr0+eq // base==top && st!=LUA_YIELD
1232 | cmplw cr1, TMP2, TMP0
1233 | cror 4*cr6+lt, 4*cr6+lt, 4*cr6+gt
1234 | stw PC, SAVE_PC
1235 | cror 4*cr6+lt, 4*cr6+lt, 4*cr1+gt // cond1 || cond2 || stackov
1236 | stw BASE, L->base
1237 | blt cr6, ->fff_fallback
1238 |1:
1239 |.if resume
1240 | addi BASE, BASE, 8 // Keep resumed thread in stack for GC.
1241 | subi NARGS8:RC, NARGS8:RC, 8
1242 | subi TMP2, TMP2, 8
1243 |.endif
1244 | stw TMP2, L:CARG1->top
1245 | li TMP1, 0
1246 | stw BASE, L->top
1247 |2: // Move args to coroutine.
1248 | cmpw TMP1, NARGS8:RC
1249 | evlddx TMP0, BASE, TMP1
1250 | beq >3
1251 | evstddx TMP0, CARG2, TMP1
1252 | addi TMP1, TMP1, 8
1253 | b <2
1254 |3:
1255 | li CARG3, 0
1256 | mr L:SAVE0, L:CARG1
1257 | li CARG4, 0
1258 | bl ->vm_resume // (lua_State *L, TValue *base, 0, 0)
1259 | // Returns thread status.
1260 |4:
1261 | lwz TMP2, L:SAVE0->base
1262 | cmplwi CRET1, LUA_YIELD
1263 | lwz TMP3, L:SAVE0->top
1264 | li_vmstate INTERP
1265 | lwz BASE, L->base
1266 | st_vmstate
1267 | bgt >8
1268 | sub RD, TMP3, TMP2
1269 | lwz TMP0, L->maxstack
1270 | cmplwi RD, 0
1271 | add TMP1, BASE, RD
1272 | beq >6 // No results?
1273 | cmplw TMP1, TMP0
1274 | li TMP1, 0
1275 | bgt >9 // Need to grow stack?
1276 |
1277 | subi TMP3, RD, 8
1278 | stw TMP2, L:SAVE0->top // Clear coroutine stack.
1279 |5: // Move results from coroutine.
1280 | cmplw TMP1, TMP3
1281 | evlddx TMP0, TMP2, TMP1
1282 | evstddx TMP0, BASE, TMP1
1283 | addi TMP1, TMP1, 8
1284 | bne <5
1285 |6:
1286 | andi. TMP0, PC, FRAME_TYPE
1287 |.if resume
1288 | li TMP1, LJ_TTRUE
1289 | la RA, -8(BASE)
1290 | stw TMP1, -8(BASE) // Prepend true to results.
1291 | addi RD, RD, 16
1292 |.else
1293 | mr RA, BASE
1294 | addi RD, RD, 8
1295 |.endif
1296 |7:
1297 | stw PC, SAVE_PC
1298 | mr MULTRES, RD
1299 | beq ->BC_RET_Z
1300 | b ->vm_return
1301 |
1302 |8: // Coroutine returned with error (at co->top-1).
1303 |.if resume
1304 | andi. TMP0, PC, FRAME_TYPE
1305 | la TMP3, -8(TMP3)
1306 | li TMP1, LJ_TFALSE
1307 | evldd TMP0, 0(TMP3)
1308 | stw TMP3, L:SAVE0->top // Remove error from coroutine stack.
1309 | li RD, (2+1)*8
1310 | stw TMP1, -8(BASE) // Prepend false to results.
1311 | la RA, -8(BASE)
1312 | evstdd TMP0, 0(BASE) // Copy error message.
1313 | b <7
1314 |.else
1315 | mr CARG1, L
1316 | mr CARG2, L:SAVE0
1317 | bl extern lj_ffh_coroutine_wrap_err // (lua_State *L, lua_State *co)
1318 |.endif
1319 |
1320 |9: // Handle stack expansion on return from yield.
1321 | mr CARG1, L
1322 | srwi CARG2, RD, 3
1323 | bl extern lj_state_growstack // (lua_State *L, int n)
1324 | li CRET1, 0
1325 | b <4
1326 |.endmacro
1327 |
1328 | coroutine_resume_wrap 1 // coroutine.resume
1329 | coroutine_resume_wrap 0 // coroutine.wrap
1330 |
1331 |.ffunc coroutine_yield
1332 | lwz TMP0, L->cframe
1333 | add TMP1, BASE, NARGS8:RC
1334 | stw BASE, L->base
1335 | andi. TMP0, TMP0, CFRAME_RESUME
1336 | stw TMP1, L->top
1337 | li CRET1, LUA_YIELD
1338 | beq ->fff_fallback
1339 | stw ZERO, L->cframe
1340 | stb CRET1, L->status
1341 | b ->vm_leave_unw
1342 |
1343 |//-- Math library -------------------------------------------------------
1344 |
1345 |.ffunc_n math_abs
1346 | efdabs CRET1, CARG1
1347 | // Fallthrough.
1348 |
1349 |->fff_restv:
1350 | // CRET1 = TValue result.
1351 | lwz PC, FRAME_PC(BASE)
1352 | la RA, -8(BASE)
1353 | evstdd CRET1, 0(RA)
1354 |->fff_res1:
1355 | // RA = results, PC = return.
1356 | li RD, (1+1)*8
1357 |->fff_res:
1358 | // RA = results, RD = (nresults+1)*8, PC = return.
1359 | andi. TMP0, PC, FRAME_TYPE
1360 | mr MULTRES, RD
1361 | bne ->vm_return
1362 | lwz INS, -4(PC)
1363 | decode_RB8 RB, INS
1364 |5:
1365 | cmplw RB, RD // More results expected?
1366 | decode_RA8 TMP0, INS
1367 | bgt >6
1368 | ins_next1
1369 | // Adjust BASE. KBASE is assumed to be set for the calling frame.
1370 | sub BASE, RA, TMP0
1371 | ins_next2
1372 |
1373 |6: // Fill up results with nil.
1374 | subi TMP1, RD, 8
1375 | addi RD, RD, 8
1376 | evstddx TISNIL, RA, TMP1
1377 | b <5
1378 |
1379 |.macro math_extern, func
1380 | .ffunc math_ .. func
1381 | cmplwi NARGS8:RC, 8
1382 | evldd CARG2, 0(BASE)
1383 | blt ->fff_fallback
1384 | checknum CARG2
1385 | evmergehi CARG1, CARG2, CARG2
1386 | checkfail ->fff_fallback
1387 | bl extern func
1388 | evmergelo CRET1, CRET1, CRET2
1389 | b ->fff_restv
1390 |.endmacro
1391 |
1392 |.macro math_extern2, func
1393 | .ffunc math_ .. func
1394 | cmplwi NARGS8:RC, 16
1395 | evldd CARG2, 0(BASE)
1396 | evldd CARG4, 8(BASE)
1397 | blt ->fff_fallback
1398 | evmergehi CARG1, CARG4, CARG2
1399 | checknum CARG1
1400 | evmergehi CARG3, CARG4, CARG4
1401 | checkanyfail ->fff_fallback
1402 | bl extern func
1403 | evmergelo CRET1, CRET1, CRET2
1404 | b ->fff_restv
1405 |.endmacro
1406 |
1407 |.macro math_round, func
1408 | .ffunc math_ .. func
1409 | cmplwi NARGS8:RC, 8
1410 | evldd CARG2, 0(BASE)
1411 | blt ->fff_fallback
1412 | checknum CARG2
1413 | evmergehi CARG1, CARG2, CARG2
1414 | checkfail ->fff_fallback
1415 | lwz PC, FRAME_PC(BASE)
1416 | bl ->vm_..func.._hilo;
1417 | la RA, -8(BASE)
1418 | evstdd CRET2, 0(RA)
1419 | b ->fff_res1
1420 |.endmacro
1421 |
1422 | math_round floor
1423 | math_round ceil
1424 |
1425 | math_extern sqrt
1426 | math_extern log
1427 | math_extern log10
1428 | math_extern exp
1429 | math_extern sin
1430 | math_extern cos
1431 | math_extern tan
1432 | math_extern asin
1433 | math_extern acos
1434 | math_extern atan
1435 | math_extern sinh
1436 | math_extern cosh
1437 | math_extern tanh
1438 | math_extern2 pow
1439 | math_extern2 atan2
1440 | math_extern2 fmod
1441 |
1442 |->ff_math_deg:
1443 |.ffunc_n math_rad
1444 | evldd CARG2, CFUNC:RB->upvalue[0]
1445 | efdmul CRET1, CARG1, CARG2
1446 | b ->fff_restv
1447 |
1448 |.ffunc math_ldexp
1449 | cmplwi NARGS8:RC, 16
1450 | evldd CARG2, 0(BASE)
1451 | evldd CARG4, 8(BASE)
1452 | blt ->fff_fallback
1453 | evmergehi CARG1, CARG4, CARG2
1454 | checknum CARG1
1455 | checkanyfail ->fff_fallback
1456 | efdctsi CARG3, CARG4
1457 | bl extern ldexp
1458 | evmergelo CRET1, CRET1, CRET2
1459 | b ->fff_restv
1460 |
1461 |.ffunc math_frexp
1462 | cmplwi NARGS8:RC, 8
1463 | evldd CARG2, 0(BASE)
1464 | blt ->fff_fallback
1465 | checknum CARG2
1466 | evmergehi CARG1, CARG2, CARG2
1467 | checkfail ->fff_fallback
1468 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
1469 | lwz PC, FRAME_PC(BASE)
1470 | bl extern frexp
1471 | lwz TMP1, DISPATCH_GL(tmptv)(DISPATCH)
1472 | evmergelo CRET1, CRET1, CRET2
1473 | efdcfsi CRET2, TMP1
1474 | la RA, -8(BASE)
1475 | evstdd CRET1, 0(RA)
1476 | li RD, (2+1)*8
1477 | evstdd CRET2, 8(RA)
1478 | b ->fff_res
1479 |
1480 |.ffunc math_modf
1481 | cmplwi NARGS8:RC, 8
1482 | evldd CARG2, 0(BASE)
1483 | blt ->fff_fallback
1484 | checknum CARG2
1485 | evmergehi CARG1, CARG2, CARG2
1486 | checkfail ->fff_fallback
1487 | la CARG3, -8(BASE)
1488 | lwz PC, FRAME_PC(BASE)
1489 | bl extern modf
1490 | evmergelo CRET1, CRET1, CRET2
1491 | la RA, -8(BASE)
1492 | evstdd CRET1, 0(BASE)
1493 | li RD, (2+1)*8
1494 | b ->fff_res
1495 |
1496 |.macro math_minmax, name, cmpop
1497 | .ffunc_1 name
1498 | checknum CARG1
1499 | li TMP1, 8
1500 | checkfail ->fff_fallback
1501 |1:
1502 | evlddx CARG2, BASE, TMP1
1503 | cmplw cr1, TMP1, NARGS8:RC
1504 | checknum CARG2
1505 | bge cr1, ->fff_restv // Ok, since CRET1 = CARG1.
1506 | checkfail ->fff_fallback
1507 | cmpop CARG2, CARG1
1508 | addi TMP1, TMP1, 8
1509 | crmove 4*cr0+lt, 4*cr0+gt
1510 | evsel CARG1, CARG2, CARG1
1511 | b <1
1512 |.endmacro
1513 |
1514 | math_minmax math_min, efdtstlt
1515 | math_minmax math_max, efdtstgt
1516 |
1517 |//-- String library -----------------------------------------------------
1518 |
1519 |.ffunc_1 string_len
1520 | checkstr STR:CARG1
1521 | checkfail ->fff_fallback
1522 | lwz TMP0, STR:CARG1->len
1523 | efdcfsi CRET1, TMP0
1524 | b ->fff_restv
1525 |
1526 |.ffunc string_byte // Only handle the 1-arg case here.
1527 | cmplwi NARGS8:RC, 8
1528 | evldd STR:CARG1, 0(BASE)
1529 | bne ->fff_fallback // Need exactly 1 argument.
1530 | checkstr STR:CARG1
1531 | la RA, -8(BASE)
1532 | checkfail ->fff_fallback
1533 | lwz TMP0, STR:CARG1->len
1534 | li RD, (0+1)*8
1535 | lbz TMP1, STR:CARG1[1] // Access is always ok (NUL at end).
1536 | li TMP2, (1+1)*8
1537 | cmplwi TMP0, 0
1538 | lwz PC, FRAME_PC(BASE)
1539 | efdcfsi CRET1, TMP1
1540 | iseleq RD, RD, TMP2
1541 | evstdd CRET1, 0(RA)
1542 | b ->fff_res
1543 |
1544 |.ffunc string_char // Only handle the 1-arg case here.
1545 | ffgccheck
1546 | cmplwi NARGS8:RC, 8
1547 | evldd CARG1, 0(BASE)
1548 | bne ->fff_fallback // Exactly 1 argument.
1549 | checknum CARG1
1550 | la CARG2, DISPATCH_GL(tmptv)(DISPATCH)
1551 | checkfail ->fff_fallback
1552 | efdctsiz TMP0, CARG1
1553 | li CARG3, 1
1554 | cmplwi TMP0, 255
1555 | stb TMP0, 0(CARG2)
1556 | bgt ->fff_fallback
1557 |->fff_newstr:
1558 | mr CARG1, L
1559 | stw BASE, L->base
1560 | stw PC, SAVE_PC
1561 | bl extern lj_str_new // (lua_State *L, char *str, size_t l)
1562 | // Returns GCstr *.
1563 | lwz BASE, L->base
1564 | evmergelo STR:CRET1, TISSTR, STR:CRET1
1565 | b ->fff_restv
1566 |
1567 |.ffunc string_sub
1568 | ffgccheck
1569 | cmplwi NARGS8:RC, 16
1570 | evldd CARG3, 16(BASE)
1571 | evldd STR:CARG1, 0(BASE)
1572 | blt ->fff_fallback
1573 | evldd CARG2, 8(BASE)
1574 | li TMP2, -1
1575 | beq >1
1576 | checknum CARG3
1577 | checkfail ->fff_fallback
1578 | efdctsiz TMP2, CARG3
1579 |1:
1580 | checknum CARG2
1581 | checkfail ->fff_fallback
1582 | checkstr STR:CARG1
1583 | efdctsiz TMP1, CARG2
1584 | checkfail ->fff_fallback
1585 | lwz TMP0, STR:CARG1->len
1586 | cmplw TMP0, TMP2 // len < end? (unsigned compare)
1587 | add TMP3, TMP2, TMP0
1588 | blt >5
1589 |2:
1590 | cmpwi TMP1, 0 // start <= 0?
1591 | add TMP3, TMP1, TMP0
1592 | ble >7
1593 |3:
1594 | sub. CARG3, TMP2, TMP1
1595 | addi CARG2, STR:CARG1, #STR-1
1596 | addi CARG3, CARG3, 1
1597 | add CARG2, CARG2, TMP1
1598 | isellt CARG3, r0, CARG3
1599 | b ->fff_newstr
1600 |
1601 |5: // Negative end or overflow.
1602 | cmpw TMP0, TMP2
1603 | addi TMP3, TMP3, 1
1604 | iselgt TMP2, TMP3, TMP0 // end = end > len ? len : end+len+1
1605 | b <2
1606 |
1607 |7: // Negative start or underflow.
1608 | cmpwi cr1, TMP3, 0
1609 | iseleq TMP1, r0, TMP3
1610 | isel TMP1, r0, TMP1, 4*cr1+lt
1611 | addi TMP1, TMP1, 1 // start = 1 + (start ? start+len : 0)
1612 | b <3
1613 |
1614 |.ffunc string_rep // Only handle the 1-char case inline.
1615 | ffgccheck
1616 | cmplwi NARGS8:RC, 16
1617 | evldd CARG1, 0(BASE)
1618 | evldd CARG2, 8(BASE)
1619 | blt ->fff_fallback
1620 | checknum CARG2
1621 | checkfail ->fff_fallback
1622 | checkstr STR:CARG1
1623 | efdctsiz CARG3, CARG2
1624 | checkfail ->fff_fallback
1625 | lwz TMP0, STR:CARG1->len
1626 | cmpwi CARG3, 0
1627 | lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1628 | ble >2 // Count <= 0? (or non-int)
1629 | cmplwi TMP0, 1
1630 | subi TMP2, CARG3, 1
1631 | blt >2 // Zero length string?
1632 | cmplw cr1, TMP1, CARG3
1633 | bne ->fff_fallback // Fallback for > 1-char strings.
1634 | lbz TMP0, STR:CARG1[1]
1635 | lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1636 | blt cr1, ->fff_fallback
1637 |1: // Fill buffer with char. Yes, this is suboptimal code (do you care?).
1638 | cmplwi TMP2, 0
1639 | stbx TMP0, CARG2, TMP2
1640 | subi TMP2, TMP2, 1
1641 | bne <1
1642 | b ->fff_newstr
1643 |2: // Return empty string.
1644 | la STR:CRET1, DISPATCH_GL(strempty)(DISPATCH)
1645 | evmergelo CRET1, TISSTR, STR:CRET1
1646 | b ->fff_restv
1647 |
1648 |.ffunc string_reverse
1649 | ffgccheck
1650 | cmplwi NARGS8:RC, 8
1651 | evldd CARG1, 0(BASE)
1652 | blt ->fff_fallback
1653 | checkstr STR:CARG1
1654 | lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1655 | checkfail ->fff_fallback
1656 | lwz CARG3, STR:CARG1->len
1657 | la CARG1, #STR(STR:CARG1)
1658 | lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1659 | li TMP2, 0
1660 | cmplw TMP1, CARG3
1661 | subi TMP3, CARG3, 1
1662 | blt ->fff_fallback
1663 |1: // Reverse string copy.
1664 | cmpwi TMP3, 0
1665 | lbzx TMP1, CARG1, TMP2
1666 | blt ->fff_newstr
1667 | stbx TMP1, CARG2, TMP3
1668 | subi TMP3, TMP3, 1
1669 | addi TMP2, TMP2, 1
1670 | b <1
1671 |
1672 |.macro ffstring_case, name, lo
1673 | .ffunc name
1674 | ffgccheck
1675 | cmplwi NARGS8:RC, 8
1676 | evldd CARG1, 0(BASE)
1677 | blt ->fff_fallback
1678 | checkstr STR:CARG1
1679 | lwz TMP1, DISPATCH_GL(tmpbuf.sz)(DISPATCH)
1680 | checkfail ->fff_fallback
1681 | lwz CARG3, STR:CARG1->len
1682 | la CARG1, #STR(STR:CARG1)
1683 | lwz CARG2, DISPATCH_GL(tmpbuf.buf)(DISPATCH)
1684 | cmplw TMP1, CARG3
1685 | li TMP2, 0
1686 | blt ->fff_fallback
1687 |1: // ASCII case conversion.
1688 | cmplw TMP2, CARG3
1689 | lbzx TMP1, CARG1, TMP2
1690 | bge ->fff_newstr
1691 | subi TMP0, TMP1, lo
1692 | xori TMP3, TMP1, 0x20
1693 | cmplwi TMP0, 26
1694 | isellt TMP1, TMP3, TMP1
1695 | stbx TMP1, CARG2, TMP2
1696 | addi TMP2, TMP2, 1
1697 | b <1
1698 |.endmacro
1699 |
1700 |ffstring_case string_lower, 65
1701 |ffstring_case string_upper, 97
1702 |
1703 |//-- Table library ------------------------------------------------------
1704 |
1705 |.ffunc_1 table_getn
1706 | checktab CARG1
1707 | checkfail ->fff_fallback
1708 | bl extern lj_tab_len // (GCtab *t)
1709 | // Returns uint32_t (but less than 2^31).
1710 | efdcfsi CRET1, CRET1
1711 | b ->fff_restv
1712 |
1713 |//-- Bit library --------------------------------------------------------
1714 |
1715 |.macro .ffunc_bit, name
1716 | .ffunc_n bit_..name
1717 | efdadd CARG1, CARG1, TOBIT
1718 |.endmacro
1719 |
1720 |.ffunc_bit tobit
1721 |->fff_resbit:
1722 | efdcfsi CRET1, CARG1
1723 | b ->fff_restv
1724 |
1725 |.macro .ffunc_bit_op, name, ins
1726 | .ffunc_bit name
1727 | li TMP1, 8
1728 |1:
1729 | evlddx CARG2, BASE, TMP1
1730 | cmplw cr1, TMP1, NARGS8:RC
1731 | checknum CARG2
1732 | bge cr1, ->fff_resbit
1733 | checkfail ->fff_fallback
1734 | efdadd CARG2, CARG2, TOBIT
1735 | ins CARG1, CARG1, CARG2
1736 | addi TMP1, TMP1, 8
1737 | b <1
1738 |.endmacro
1739 |
1740 |.ffunc_bit_op band, and
1741 |.ffunc_bit_op bor, or
1742 |.ffunc_bit_op bxor, xor
1743 |
1744 |.ffunc_bit bswap
1745 | rotlwi TMP0, CARG1, 8
1746 | rlwimi TMP0, CARG1, 24, 0, 7
1747 | rlwimi TMP0, CARG1, 24, 16, 23
1748 | efdcfsi CRET1, TMP0
1749 | b ->fff_restv
1750 |
1751 |.ffunc_bit bnot
1752 | not TMP0, CARG1
1753 | efdcfsi CRET1, TMP0
1754 | b ->fff_restv
1755 |
1756 |.macro .ffunc_bit_sh, name, ins, shmod
1757 | .ffunc_nn bit_..name
1758 | efdadd CARG2, CARG2, TOBIT
1759 | efdadd CARG1, CARG1, TOBIT
1760 |.if shmod == 1
1761 | rlwinm CARG2, CARG2, 0, 27, 31
1762 |.elif shmod == 2
1763 | neg CARG2, CARG2
1764 |.endif
1765 | ins TMP0, CARG1, CARG2
1766 | efdcfsi CRET1, TMP0
1767 | b ->fff_restv
1768 |.endmacro
1769 |
1770 |.ffunc_bit_sh lshift, slw, 1
1771 |.ffunc_bit_sh rshift, srw, 1
1772 |.ffunc_bit_sh arshift, sraw, 1
1773 |.ffunc_bit_sh rol, rotlw, 0
1774 |.ffunc_bit_sh ror, rotlw, 2
1775 |
1776 |//-----------------------------------------------------------------------
1777 |
1778 |->fff_fallback: // Call fast function fallback handler.
1779 | // BASE = new base, RB = CFUNC, RC = nargs*8
1780 | lwz TMP3, CFUNC:RB->f
1781 | add TMP1, BASE, NARGS8:RC
1782 | lwz PC, FRAME_PC(BASE) // Fallback may overwrite PC.
1783 | addi TMP0, TMP1, 8*LUA_MINSTACK
1784 | lwz TMP2, L->maxstack
1785 | stw PC, SAVE_PC // Redundant (but a defined value).
1786 | cmplw TMP0, TMP2
1787 | stw BASE, L->base
1788 | stw TMP1, L->top
1789 | mr CARG1, L
1790 | bgt >5 // Need to grow stack.
1791 | mtctr TMP3
1792 | bctrl // (lua_State *L)
1793 | // Either throws an error, or recovers and returns -1, 0 or nresults+1.
1794 | lwz BASE, L->base
1795 | cmpwi CRET1, 0
1796 | slwi RD, CRET1, 3
1797 | la RA, -8(BASE)
1798 | bgt ->fff_res // Returned nresults+1?
1799 |1: // Returned 0 or -1: retry fast path.
1800 | lwz TMP0, L->top
1801 | lwz LFUNC:RB, FRAME_FUNC(BASE)
1802 | sub NARGS8:RC, TMP0, BASE
1803 | bne ->vm_call_tail // Returned -1?
1804 | ins_callt // Returned 0: retry fast path.
1805 |
1806 |// Reconstruct previous base for vmeta_call during tailcall.
1807 |->vm_call_tail:
1808 | andi. TMP0, PC, FRAME_TYPE
1809 | rlwinm TMP1, PC, 0, 0, 28
1810 | bne >3
1811 | lwz INS, -4(PC)
1812 | decode_RA8 TMP1, INS
1813 |3:
1814 | sub TMP2, BASE, TMP1
1815 | b ->vm_call_dispatch // Resolve again for tailcall.
1816 |
1817 |5: // Grow stack for fallback handler.
1818 | li CARG2, LUA_MINSTACK
1819 | bl extern lj_state_growstack // (lua_State *L, int n)
1820 | lwz BASE, L->base
1821 | cmpw TMP0, TMP0 // Set 4*cr0+eq to force retry.
1822 | b <1
1823 |
1824 |->fff_gcstep: // Call GC step function.
1825 | // BASE = new base, RC = nargs*8
1826 | mflr SAVE0
1827 | stw BASE, L->base
1828 | add TMP0, BASE, NARGS8:RC
1829 | stw PC, SAVE_PC // Redundant (but a defined value).
1830 | stw TMP0, L->top
1831 | mr CARG1, L
1832 | bl extern lj_gc_step // (lua_State *L)
1833 | lwz BASE, L->base
1834 | mtlr SAVE0
1835 | lwz TMP0, L->top
1836 | sub NARGS8:RC, TMP0, BASE
1837 | lwz CFUNC:RB, FRAME_FUNC(BASE)
1838 | blr
1839 |
1840 |//-----------------------------------------------------------------------
1841 |//-- Special dispatch targets -------------------------------------------
1842 |//-----------------------------------------------------------------------
1843 |
1844 |->vm_record: // Dispatch target for recording phase.
1845#if LJ_HASJIT
1846 | NYI
1847#endif
1848 |
1849 |->vm_rethook: // Dispatch target for return hooks.
1850 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1851 | andi. TMP0, TMP3, HOOK_ACTIVE // Hook already active?
1852 | beq >1
1853 |5: // Re-dispatch to static ins.
1854 | addi TMP1, TMP1, GG_DISP2STATIC // Assumes decode_OP4 TMP1, INS.
1855 | lwzx TMP0, DISPATCH, TMP1
1856 | mtctr TMP0
1857 | bctr
1858 |
1859 |->vm_inshook: // Dispatch target for instr/line hooks.
1860 | lbz TMP3, DISPATCH_GL(hookmask)(DISPATCH)
1861 | lwz TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1862 | andi. TMP0, TMP3, HOOK_ACTIVE // Hook already active?
1863 | rlwinm TMP0, TMP3, 31-LUA_HOOKLINE, 31, 0
1864 | bne <5
1865 |
1866 | cmpwi cr1, TMP0, 0
1867 | addic. TMP2, TMP2, -1
1868 | beq cr1, <5
1869 | stw TMP2, DISPATCH_GL(hookcount)(DISPATCH)
1870 | beq >1
1871 | bge cr1, <5
1872 |1:
1873 | mr CARG1, L
1874 | stw MULTRES, SAVE_MULTRES
1875 | mr CARG2, PC
1876 | stw BASE, L->base
1877 | // SAVE_PC must hold the _previous_ PC. The callee updates it with PC.
1878 | bl extern lj_dispatch_ins // (lua_State *L, const BCIns *pc)
1879 |3:
1880 | lwz BASE, L->base
1881 |4: // Re-dispatch to static ins.
1882 | lwz INS, -4(PC)
1883 | decode_OP4 TMP1, INS
1884 | decode_RB8 RB, INS
1885 | addi TMP1, TMP1, GG_DISP2STATIC
1886 | decode_RD8 RD, INS
1887 | lwzx TMP0, DISPATCH, TMP1
1888 | decode_RA8 RA, INS
1889 | decode_RC8 RC, INS
1890 | mtctr TMP0
1891 | bctr
1892 |
1893 |->cont_hook: // Continue from hook yield.
1894 | addi PC, PC, 4
1895 | lwz MULTRES, -20(RB) // Restore MULTRES for *M ins.
1896 | b <4
1897 |
1898 |->vm_hotloop: // Hot loop counter underflow.
1899#if LJ_HASJIT
1900 | NYI
1901#endif
1902 |
1903 |->vm_callhook: // Dispatch target for call hooks.
1904 | mr CARG2, PC
1905#if LJ_HASJIT
1906 | b >1
1907#endif
1908 |
1909 |->vm_hotcall: // Hot call counter underflow.
1910#if LJ_HASJIT
1911 | ori CARG2, PC, 1
1912 |1:
1913#endif
1914 | add TMP0, BASE, RC
1915 | stw PC, SAVE_PC
1916 | mr CARG1, L
1917 | stw BASE, L->base
1918 | sub RA, RA, BASE
1919 | stw TMP0, L->top
1920 | bl extern lj_dispatch_call // (lua_State *L, const BCIns *pc)
1921 | // Returns ASMFunction.
1922 | lwz BASE, L->base
1923 | lwz TMP0, L->top
1924 | stw ZERO, SAVE_PC // Invalidate for subsequent line hook.
1925 | sub NARGS8:RC, TMP0, BASE
1926 | add RA, BASE, RA
1927 | lwz LFUNC:RB, FRAME_FUNC(BASE)
1928 | mtctr CRET1
1929 | bctr
1930 |
1931 |//-----------------------------------------------------------------------
1932 |//-- Trace exit handler -------------------------------------------------
1933 |//-----------------------------------------------------------------------
1934 |
1935 |->vm_exit_handler:
1936#if LJ_HASJIT
1937 | NYI
1938#endif
1939 |->vm_exit_interp:
1940#if LJ_HASJIT
1941 | NYI
1942#endif
1943 |
1944 |//-----------------------------------------------------------------------
1945 |//-- Math helper functions ----------------------------------------------
1946 |//-----------------------------------------------------------------------
1947 |
1948 |// FP value rounding. Called by math.floor/math.ceil fast functions
1949 |// and from JIT code.
1950 |//
1951 |// This can be inlined if the CPU has the frin/friz/frip/frim instructions.
1952 |// The alternative hard-float approaches have a deep dependency chain.
1953 |// The resulting latency is at least 3x-7x the double-precision FP latency
1954 |// (e500v2: 6cy, e600: 5cy, Cell: 10cy) or around 20-70 cycles.
1955 |//
1956 |// The soft-float approach is tedious, but much faster (e500v2: ~11cy/~6cy).
1957 |// However it relies on a fast way to transfer the FP value to GPRs
1958 |// (e500v2: 0cy for lo-word, 1cy for hi-word).
1959 |//
1960 |.macro vm_round, name, mode
1961 | // Used temporaries: TMP0, TMP1, TMP2, TMP3.
1962 |->name.._efd: // Input: CARG2, output: CRET2
1963 | evmergehi CARG1, CARG2, CARG2
1964 |->name.._hilo:
1965 | // Input: CARG1 (hi), CARG2 (hi, lo), output: CRET2
1966 | rlwinm TMP2, CARG1, 12, 21, 31
1967 | addic. TMP2, TMP2, -1023 // exp = exponent(x) - 1023
1968 | li TMP1, -1
1969 | cmplwi cr1, TMP2, 51 // 0 <= exp <= 51?
1970 | subfic TMP0, TMP2, 52
1971 | bgt cr1, >1
1972 | lus TMP3, 0xfff0
1973 | slw TMP0, TMP1, TMP0 // lomask = -1 << (52-exp)
1974 | sraw TMP1, TMP3, TMP2 // himask = (int32_t)0xfff00000 >> exp
1975 |.if mode == 2 // trunc(x):
1976 | evmergelo TMP0, TMP1, TMP0
1977 | evand CRET2, CARG2, TMP0 // hi &= himask, lo &= lomask
1978 |.else
1979 | andc TMP2, CARG2, TMP0
1980 | andc TMP3, CARG1, TMP1
1981 | or TMP2, TMP2, TMP3 // ztest = (hi&~himask) | (lo&~lomask)
1982 | srawi TMP3, CARG1, 31 // signmask = (int32_t)hi >> 31
1983 |.if mode == 0 // floor(x):
1984 | and. TMP2, TMP2, TMP3 // iszero = ((ztest & signmask) == 0)
1985 |.else // ceil(x):
1986 | andc. TMP2, TMP2, TMP3 // iszero = ((ztest & ~signmask) == 0)
1987 |.endif
1988 | and CARG2, CARG2, TMP0 // lo &= lomask
1989 | and CARG1, CARG1, TMP1 // hi &= himask
1990 | subc TMP0, CARG2, TMP0
1991 | iseleq TMP0, CARG2, TMP0 // lo = iszero ? lo : lo-lomask
1992 | sube TMP1, CARG1, TMP1
1993 | iseleq TMP1, CARG1, TMP1 // hi = iszero ? hi : hi-himask+carry
1994 | evmergelo CRET2, TMP1, TMP0
1995 |.endif
1996 | blr
1997 |1:
1998 | bgtlr // Already done if >=2^52, +-inf or nan.
1999 |.if mode == 2 // trunc(x):
2000 | rlwinm TMP1, CARG1, 0, 0, 0 // hi = sign(x)
2001 | li TMP0, 0
2002 | evmergelo CRET2, TMP1, TMP0
2003 |.else
2004 | rlwinm TMP2, CARG1, 0, 1, 31
2005 | srawi TMP0, CARG1, 31 // signmask = (int32_t)hi >> 31
2006 | or TMP2, TMP2, CARG2 // ztest = abs(hi) | lo
2007 | lus TMP1, 0x3ff0
2008 |.if mode == 0 // floor(x):
2009 | and. TMP2, TMP2, TMP0 // iszero = ((ztest & signmask) == 0)
2010 |.else // ceil(x):
2011 | andc. TMP2, TMP2, TMP0 // iszero = ((ztest & ~signmask) == 0)
2012 |.endif
2013 | li TMP0, 0
2014 | iseleq TMP1, r0, TMP1
2015 | rlwimi CARG1, TMP1, 0, 1, 31 // hi = sign(x) | (iszero ? 0.0 : 1.0)
2016 | evmergelo CRET2, CARG1, TMP0
2017 |.endif
2018 | blr
2019 |.endmacro
2020 |
2021 |->vm_floor:
2022 | mflr CARG3
2023 | bl ->vm_floor_hilo
2024 | mtlr CARG3
2025 | evmergehi CRET1, CRET2, CRET2
2026 | blr
2027 |
2028 | vm_round vm_floor, 0
2029 | vm_round vm_ceil, 1
2030#if LJ_HASJIT
2031 | vm_round vm_trunc, 2
2032#else
2033 |->vm_trunc_efd:
2034 |->vm_trunc_hilo:
2035#endif
2036 |
2037 |->vm_powi:
2038#if LJ_HASJIT
2039 | NYI
2040#endif
2041 |
2042 |->vm_foldfpm:
2043#if LJ_HASJIT
2044 | NYI
2045#endif
2046 |
2047 |// Callable from C: double lj_vm_foldarith(double x, double y, int op)
2048 |// Compute x op y for basic arithmetic operators (+ - * / % ^ and unary -)
2049 |// and basic math functions. ORDER ARITH
2050 |->vm_foldarith:
2051 | evmergelo CARG2, CARG1, CARG2
2052 | cmplwi CARG5, 1
2053 | evmergelo CARG4, CARG3, CARG4
2054 | beq >1; bgt >2
2055 | efdadd CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2056 |1:
2057 | efdsub CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2058 |2:
2059 | cmplwi CARG5, 3; beq >1; bgt >2
2060 | efdmul CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2061 |1:
2062 | efddiv CRET2, CARG2, CARG4; evmergehi CRET1, CRET2, CRET2; blr
2063 |2:
2064 | cmplwi CARG5, 5; beq >1; bgt >2
2065 | evmr CARG3, CARG2; efddiv CRET2, CARG2, CARG4; evmr RB, CARG4
2066 | mflr RC; bl ->vm_floor_efd; mtlr RC
2067 | efdmul CRET2, CRET2, RB; efdsub CRET2, CARG3, CRET2
2068 | evmergehi CRET1, CRET2, CRET2; blr
2069 |1:
2070 | b extern pow
2071 |2:
2072 | cmplwi CARG5, 7; beq >1; bgt >2
2073 | xoris CARG1, CARG1, 0x8000; blr
2074 |1:
2075 | rlwinm CARG1, CARG1, 0, 1, 31; blr
2076 |2:
2077 | NYI // Other operations only needed by JIT compiler.
2078 |
2079 |//-----------------------------------------------------------------------
2080 |//-- Miscellaneous functions --------------------------------------------
2081 |//-----------------------------------------------------------------------
2082 |
2083 |//-----------------------------------------------------------------------
2084 |//-- FFI helper functions -----------------------------------------------
2085 |//-----------------------------------------------------------------------
2086 |
2087 |->vm_ffi_call:
2088#if LJ_HASFFI
2089 | NYI
2090#endif
2091 |
2092 |//-----------------------------------------------------------------------
2093}
2094
2095/* Generate the code for a single instruction. */
2096static void build_ins(BuildCtx *ctx, BCOp op, int defop)
2097{
2098 int vk = 0;
2099 |=>defop:
2100
2101 switch (op) {
2102
2103 /* -- Comparison ops ---------------------------------------------------- */
2104
2105 /* Remember: all ops branch for a true comparison, fall through otherwise. */
2106
2107 case BC_ISLT: case BC_ISGE: case BC_ISLE: case BC_ISGT:
2108 | // RA = src1*8, RD = src2*8, JMP with RD = target
2109 | evlddx TMP0, BASE, RA
2110 | addi PC, PC, 4
2111 | evlddx TMP1, BASE, RD
2112 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2113 | lwz TMP2, -4(PC)
2114 | evmergehi RB, TMP0, TMP1
2115 | decode_RD4 TMP2, TMP2
2116 | checknum RB
2117 | add TMP2, TMP2, TMP3
2118 | checkanyfail ->vmeta_comp
2119 | efdcmplt TMP0, TMP1
2120 if (op == BC_ISLE || op == BC_ISGT) {
2121 | efdcmpeq cr1, TMP0, TMP1
2122 | cror 4*cr0+gt, 4*cr0+gt, 4*cr1+gt
2123 }
2124 if (op == BC_ISLT || op == BC_ISLE) {
2125 | iselgt PC, TMP2, PC
2126 } else {
2127 | iselgt PC, PC, TMP2
2128 }
2129 | ins_next
2130 break;
2131
2132 case BC_ISEQV: case BC_ISNEV:
2133 vk = op == BC_ISEQV;
2134 | // RA = src1*8, RD = src2*8, JMP with RD = target
2135 | evlddx CARG2, BASE, RA
2136 | addi PC, PC, 4
2137 | evlddx CARG3, BASE, RD
2138 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2139 | lwz TMP2, -4(PC)
2140 | evmergehi RB, CARG2, CARG3
2141 | decode_RD4 TMP2, TMP2
2142 | checknum RB
2143 | add TMP2, TMP2, TMP3
2144 | checkanyfail >5
2145 | efdcmpeq CARG2, CARG3
2146 if (vk) {
2147 | iselgt PC, TMP2, PC
2148 } else {
2149 | iselgt PC, PC, TMP2
2150 }
2151 |1:
2152 | ins_next
2153 |
2154 |5: // Either or both types are not numbers.
2155 | evcmpeq CARG2, CARG3
2156 | not TMP3, RB
2157 | cmplwi cr1, TMP3, ~LJ_TISPRI // Primitive?
2158 | crorc 4*cr7+lt, 4*cr0+so, 4*cr0+lt // 1: Same tv or different type.
2159 | cmplwi cr6, TMP3, ~LJ_TISTABUD // Table or userdata?
2160 | crandc 4*cr7+gt, 4*cr0+lt, 4*cr1+gt // 2: Same type and primitive.
2161 | mr SAVE0, PC
2162 if (vk) {
2163 | isel PC, TMP2, PC, 4*cr7+gt
2164 } else {
2165 | isel TMP2, PC, TMP2, 4*cr7+gt
2166 }
2167 | cror 4*cr7+lt, 4*cr7+lt, 4*cr7+gt // 1 or 2.
2168 if (vk) {
2169 | isel PC, TMP2, PC, 4*cr0+so
2170 } else {
2171 | isel PC, PC, TMP2, 4*cr0+so
2172 }
2173 | blt cr7, <1 // Done if 1 or 2.
2174 | blt cr6, <1 // Done if not tab/ud.
2175 |
2176 | // Different tables or userdatas. Need to check __eq metamethod.
2177 | // Field metatable must be at same offset for GCtab and GCudata!
2178 | lwz TAB:TMP2, TAB:CARG2->metatable
2179 | li CARG4, 1-vk // ne = 0 or 1.
2180 | cmplwi TAB:TMP2, 0
2181 | beq <1 // No metatable?
2182 | lbz TMP2, TAB:TMP2->nomm
2183 | andi. TMP2, TMP2, 1<<MM_eq
2184 | bne <1 // Or 'no __eq' flag set?
2185 | mr PC, SAVE0 // Restore old PC.
2186 | b ->vmeta_equal // Handle __eq metamethod.
2187 break;
2188
2189 case BC_ISEQS: case BC_ISNES:
2190 vk = op == BC_ISEQS;
2191 | // RA = src*8, RD = str_const*8 (~), JMP with RD = target
2192 | evlddx TMP0, BASE, RA
2193 | srwi RD, RD, 1
2194 | lwz INS, 0(PC)
2195 | subfic RD, RD, -4
2196 | addi PC, PC, 4
2197 | lwzx STR:TMP1, KBASE, RD // KBASE-4-str_const*4
2198 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2199 | decode_RD4 TMP2, INS
2200 | evmergelo STR:TMP1, TISSTR, STR:TMP1
2201 | add TMP2, TMP2, TMP3
2202 | evcmpeq TMP0, STR:TMP1
2203 if (vk) {
2204 | isel PC, TMP2, PC, 4*cr0+so
2205 } else {
2206 | isel PC, PC, TMP2, 4*cr0+so
2207 }
2208 | ins_next
2209 break;
2210
2211 case BC_ISEQN: case BC_ISNEN:
2212 vk = op == BC_ISEQN;
2213 | // RA = src*8, RD = num_const*8, JMP with RD = target
2214 | evlddx TMP0, BASE, RA
2215 | addi PC, PC, 4
2216 | evlddx TMP1, KBASE, RD
2217 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2218 | lwz INS, -4(PC)
2219 | checknum TMP0
2220 | checkfail >5
2221 | efdcmpeq TMP0, TMP1
2222 |1:
2223 | decode_RD4 TMP2, INS
2224 | add TMP2, TMP2, TMP3
2225 if (vk) {
2226 | iselgt PC, TMP2, PC
2227 |5:
2228 } else {
2229 | iselgt PC, PC, TMP2
2230 }
2231 |3:
2232 | ins_next
2233 if (!vk) {
2234 |5:
2235 | decode_RD4 TMP2, INS
2236 | add PC, TMP2, TMP3
2237 | b <3
2238 }
2239 break;
2240
2241 case BC_ISEQP: case BC_ISNEP:
2242 vk = op == BC_ISEQP;
2243 | // RA = src*8, RD = primitive_type*8 (~), JMP with RD = target
2244 | lwzx TMP0, BASE, RA
2245 | srwi TMP1, RD, 3
2246 | lwz INS, 0(PC)
2247 | addi PC, PC, 4
2248 | not TMP1, TMP1
2249 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2250 | cmplw TMP0, TMP1
2251 | decode_RD4 TMP2, INS
2252 | add TMP2, TMP2, TMP3
2253 if (vk) {
2254 | iseleq PC, TMP2, PC
2255 } else {
2256 | iseleq PC, PC, TMP2
2257 }
2258 | ins_next
2259 break;
2260
2261 /* -- Unary test and copy ops ------------------------------------------- */
2262
2263 case BC_ISTC: case BC_ISFC: case BC_IST: case BC_ISF:
2264 | // RA = dst*8 or unused, RD = src*8, JMP with RD = target
2265 | evlddx TMP0, BASE, RD
2266 | evaddw TMP1, TISNIL, TISNIL // Synthesize LJ_TFALSE.
2267 | lwz INS, 0(PC)
2268 | evcmpltu TMP0, TMP1
2269 | addi PC, PC, 4
2270 if (op == BC_IST || op == BC_ISF) {
2271 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
2272 | decode_RD4 TMP2, INS
2273 | add TMP2, TMP2, TMP3
2274 if (op == BC_IST) {
2275 | isellt PC, TMP2, PC
2276 } else {
2277 | isellt PC, PC, TMP2
2278 }
2279 } else {
2280 if (op == BC_ISTC) {
2281 | checkfail >1
2282 } else {
2283 | checkok >1
2284 }
2285 | addis PC, PC, -(BCBIAS_J*4 >> 16)
2286 | decode_RD4 TMP2, INS
2287 | evstddx TMP0, BASE, RA
2288 | add PC, PC, TMP2
2289 |1:
2290 }
2291 | ins_next
2292 break;
2293
2294 /* -- Unary ops --------------------------------------------------------- */
2295
2296 case BC_MOV:
2297 | // RA = dst*8, RD = src*8
2298 | ins_next1
2299 | evlddx TMP0, BASE, RD
2300 | evstddx TMP0, BASE, RA
2301 | ins_next2
2302 break;
2303 case BC_NOT:
2304 | // RA = dst*8, RD = src*8
2305 | ins_next1
2306 | lwzx TMP0, BASE, RD
2307 | subfic TMP1, TMP0, LJ_TTRUE
2308 | adde TMP0, TMP0, TMP1
2309 | stwx TMP0, BASE, RA
2310 | ins_next2
2311 break;
2312 case BC_UNM:
2313 | // RA = dst*8, RD = src*8
2314 | evlddx TMP0, BASE, RD
2315 | checknum TMP0
2316 | checkfail ->vmeta_unm
2317 | efdneg TMP0, TMP0
2318 | ins_next1
2319 | evstddx TMP0, BASE, RA
2320 | ins_next2
2321 break;
2322 case BC_LEN:
2323 | // RA = dst*8, RD = src*8
2324 | evlddx CARG1, BASE, RD
2325 | checkstr CARG1
2326 | checkfail >2
2327 | lwz CRET1, STR:CARG1->len
2328 |1:
2329 | ins_next1
2330 | efdcfsi TMP0, CRET1
2331 | evstddx TMP0, BASE, RA
2332 | ins_next2
2333 |2:
2334 | checktab CARG1
2335 | checkfail ->vmeta_len
2336#ifdef LUAJIT_ENABLE_LUA52COMPAT
2337 | lwz TAB:TMP2, TAB:CARG1->metatable
2338 | cmplwi TAB:TMP2, 0
2339 | bne >9
2340 |3:
2341#endif
2342 |->BC_LEN_Z:
2343 | bl extern lj_tab_len // (GCtab *t)
2344 | // Returns uint32_t (but less than 2^31).
2345 | b <1
2346#ifdef LUAJIT_ENABLE_LUA52COMPAT
2347 |9:
2348 | lbz TMP0, TAB:TMP2->nomm
2349 | andi. TMP0, TMP0, 1<<MM_len
2350 | bne <3 // 'no __len' flag set: done.
2351 | b ->vmeta_len
2352#endif
2353 break;
2354
2355 /* -- Binary ops -------------------------------------------------------- */
2356
2357 |.macro ins_arithpre, t0, t1
2358 | // RA = dst*8, RB = src1*8, RC = src2*8 | num_const*8
2359 ||vk = ((int)op - BC_ADDVN) / (BC_ADDNV-BC_ADDVN);
2360 ||switch (vk) {
2361 ||case 0:
2362 | evlddx t0, BASE, RB
2363 | checknum t0
2364 | evlddx t1, KBASE, RC
2365 | checkfail ->vmeta_arith_vn
2366 || break;
2367 ||case 1:
2368 | evlddx t1, BASE, RB
2369 | checknum t1
2370 | evlddx t0, KBASE, RC
2371 | checkfail ->vmeta_arith_nv
2372 || break;
2373 ||default:
2374 | evlddx t0, BASE, RB
2375 | evlddx t1, BASE, RC
2376 | evmergehi TMP2, t0, t1
2377 | checknum TMP2
2378 | checkanyfail ->vmeta_arith_vv
2379 || break;
2380 ||}
2381 |.endmacro
2382 |
2383 |.macro ins_arith, ins
2384 | ins_arithpre TMP0, TMP1
2385 | ins_next1
2386 | ins TMP0, TMP0, TMP1
2387 | evstddx TMP0, BASE, RA
2388 | ins_next2
2389 |.endmacro
2390
2391 case BC_ADDVN: case BC_ADDNV: case BC_ADDVV:
2392 | ins_arith efdadd
2393 break;
2394 case BC_SUBVN: case BC_SUBNV: case BC_SUBVV:
2395 | ins_arith efdsub
2396 break;
2397 case BC_MULVN: case BC_MULNV: case BC_MULVV:
2398 | ins_arith efdmul
2399 break;
2400 case BC_DIVVN: case BC_DIVNV: case BC_DIVVV:
2401 | ins_arith efddiv
2402 break;
2403 case BC_MODVN:
2404 | ins_arithpre RD, SAVE0
2405 |->BC_MODVN_Z:
2406 | efddiv CARG2, RD, SAVE0
2407 | bl ->vm_floor_efd // floor(b/c)
2408 | efdmul TMP0, CRET2, SAVE0
2409 | ins_next1
2410 | efdsub TMP0, RD, TMP0 // b - floor(b/c)*c
2411 | evstddx TMP0, BASE, RA
2412 | ins_next2
2413 break;
2414 case BC_MODNV: case BC_MODVV:
2415 | ins_arithpre RD, SAVE0
2416 | b ->BC_MODVN_Z // Avoid 3 copies. It's slow anyway.
2417 break;
2418 case BC_POW:
2419 | evlddx CARG2, BASE, RB
2420 | evlddx CARG4, BASE, RC
2421 | evmergehi CARG1, CARG4, CARG2
2422 | checknum CARG1
2423 | evmergehi CARG3, CARG4, CARG4
2424 | checkanyfail ->vmeta_arith_vv
2425 | bl extern pow
2426 | evmergelo CRET2, CRET1, CRET2
2427 | evstddx CRET2, BASE, RA
2428 | ins_next
2429 break;
2430
2431 case BC_CAT:
2432 | // RA = dst*8, RB = src_start*8, RC = src_end*8
2433 | sub CARG3, RC, RB
2434 | stw BASE, L->base
2435 | add CARG2, BASE, RC
2436 | mr SAVE0, RB
2437 |->BC_CAT_Z:
2438 | stw PC, SAVE_PC
2439 | mr CARG1, L
2440 | srwi CARG3, CARG3, 3
2441 | bl extern lj_meta_cat // (lua_State *L, TValue *top, int left)
2442 | // Returns NULL (finished) or TValue * (metamethod).
2443 | cmplwi CRET1, 0
2444 | lwz BASE, L->base
2445 | bne ->vmeta_binop
2446 | evlddx TMP0, BASE, SAVE0 // Copy result from RB to RA.
2447 | evstddx TMP0, BASE, RA
2448 | ins_next
2449 break;
2450
2451 /* -- Constant ops ------------------------------------------------------ */
2452
2453 case BC_KSTR:
2454 | // RA = dst*8, RD = str_const*8 (~)
2455 | ins_next1
2456 | srwi TMP1, RD, 1
2457 | subfic TMP1, TMP1, -4
2458 | lwzx TMP0, KBASE, TMP1 // KBASE-4-str_const*4
2459 | evmergelo TMP0, TISSTR, TMP0
2460 | evstddx TMP0, BASE, RA
2461 | ins_next2
2462 break;
2463 case BC_KCDATA:
2464#if LJ_HASFFI
2465 | // RA = dst*8, RD = cdata_const*8 (~)
2466 | ins_next1
2467 | srwi TMP1, RD, 1
2468 | subfic TMP1, TMP1, -4
2469 | lwzx TMP0, KBASE, TMP1 // KBASE-4-cdata_const*4
2470 | li TMP2, LJ_TCDATA
2471 | evmergelo TMP0, TMP2, TMP0
2472 | evstddx TMP0, BASE, RA
2473 | ins_next2
2474#endif
2475 break;
2476 case BC_KSHORT:
2477 | // RA = dst*8, RD = int16_literal*8
2478 | srwi TMP1, RD, 3
2479 | extsh TMP1, TMP1
2480 | ins_next1
2481 | efdcfsi TMP0, TMP1
2482 | evstddx TMP0, BASE, RA
2483 | ins_next2
2484 break;
2485 case BC_KNUM:
2486 | // RA = dst*8, RD = num_const*8
2487 | evlddx TMP0, KBASE, RD
2488 | ins_next1
2489 | evstddx TMP0, BASE, RA
2490 | ins_next2
2491 break;
2492 case BC_KPRI:
2493 | // RA = dst*8, RD = primitive_type*8 (~)
2494 | srwi TMP1, RD, 3
2495 | not TMP0, TMP1
2496 | ins_next1
2497 | stwx TMP0, BASE, RA
2498 | ins_next2
2499 break;
2500 case BC_KNIL:
2501 | // RA = base*8, RD = end*8
2502 | evstddx TISNIL, BASE, RA
2503 | addi RA, RA, 8
2504 |1:
2505 | evstddx TISNIL, BASE, RA
2506 | cmpw RA, RD
2507 | addi RA, RA, 8
2508 | blt <1
2509 | ins_next_
2510 break;
2511
2512 /* -- Upvalue and function ops ------------------------------------------ */
2513
2514 case BC_UGET:
2515 | // RA = dst*8, RD = uvnum*8
2516 | ins_next1
2517 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2518 | srwi RD, RD, 1
2519 | addi RD, RD, offsetof(GCfuncL, uvptr)
2520 | lwzx UPVAL:RB, LFUNC:RB, RD
2521 | lwz TMP1, UPVAL:RB->v
2522 | evldd TMP0, 0(TMP1)
2523 | evstddx TMP0, BASE, RA
2524 | ins_next2
2525 break;
2526 case BC_USETV:
2527 | // RA = uvnum*8, RD = src*8
2528 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2529 | srwi RA, RA, 1
2530 | addi RA, RA, offsetof(GCfuncL, uvptr)
2531 | evlddx TMP1, BASE, RD
2532 | lwzx UPVAL:RB, LFUNC:RB, RA
2533 | lbz TMP3, UPVAL:RB->marked
2534 | lwz CARG2, UPVAL:RB->v
2535 | andi. TMP3, TMP3, LJ_GC_BLACK // isblack(uv)
2536 | lbz TMP0, UPVAL:RB->closed
2537 | evmergehi TMP2, TMP1, TMP1
2538 | evstdd TMP1, 0(CARG2)
2539 | cmplwi cr1, TMP0, 0
2540 | cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
2541 | subi TMP2, TMP2, (LJ_TISNUM+1)
2542 | bne >2 // Upvalue is closed and black?
2543 |1:
2544 | ins_next
2545 |
2546 |2: // Check if new value is collectable.
2547 | cmplwi TMP2, LJ_TISGCV - (LJ_TISNUM+1)
2548 | bge <1 // tvisgcv(v)
2549 | lbz TMP3, GCOBJ:TMP1->gch.marked
2550 | andi. TMP3, TMP3, LJ_GC_WHITES // iswhite(v)
2551 | la CARG1, GG_DISP2G(DISPATCH)
2552 | // Crossed a write barrier. Move the barrier forward.
2553 | beq <1
2554 | bl extern lj_gc_barrieruv // (global_State *g, TValue *tv)
2555 | b <1
2556 break;
2557 case BC_USETS:
2558 | // RA = uvnum*8, RD = str_const*8 (~)
2559 | ins_next1
2560 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2561 | srwi TMP1, RD, 1
2562 | srwi RA, RA, 1
2563 | subfic TMP1, TMP1, -4
2564 | addi RA, RA, offsetof(GCfuncL, uvptr)
2565 | lwzx STR:TMP1, KBASE, TMP1 // KBASE-4-str_const*4
2566 | lwzx UPVAL:RB, LFUNC:RB, RA
2567 | evmergelo STR:TMP1, TISSTR, STR:TMP1
2568 | lbz TMP3, UPVAL:RB->marked
2569 | lwz CARG2, UPVAL:RB->v
2570 | andi. TMP3, TMP3, LJ_GC_BLACK // isblack(uv)
2571 | lbz TMP3, STR:TMP1->marked
2572 | lbz TMP2, UPVAL:RB->closed
2573 | evstdd STR:TMP1, 0(CARG2)
2574 | bne >2
2575 |1:
2576 | ins_next2
2577 |
2578 |2: // Check if string is white and ensure upvalue is closed.
2579 | andi. TMP3, TMP3, LJ_GC_WHITES // iswhite(str)
2580 | cmplwi cr1, TMP2, 0
2581 | cror 4*cr0+eq, 4*cr0+eq, 4*cr1+eq
2582 | la CARG1, GG_DISP2G(DISPATCH)
2583 | // Crossed a write barrier. Move the barrier forward.
2584 | beq <1
2585 | bl extern lj_gc_barrieruv // (global_State *g, TValue *tv)
2586 | b <1
2587 break;
2588 case BC_USETN:
2589 | // RA = uvnum*8, RD = num_const*8
2590 | ins_next1
2591 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2592 | srwi RA, RA, 1
2593 | addi RA, RA, offsetof(GCfuncL, uvptr)
2594 | evlddx TMP0, KBASE, RD
2595 | lwzx UPVAL:RB, LFUNC:RB, RA
2596 | lwz TMP1, UPVAL:RB->v
2597 | evstdd TMP0, 0(TMP1)
2598 | ins_next2
2599 break;
2600 case BC_USETP:
2601 | // RA = uvnum*8, RD = primitive_type*8 (~)
2602 | ins_next1
2603 | lwz LFUNC:RB, FRAME_FUNC(BASE)
2604 | srwi RA, RA, 1
2605 | addi RA, RA, offsetof(GCfuncL, uvptr)
2606 | srwi TMP0, RD, 3
2607 | lwzx UPVAL:RB, LFUNC:RB, RA
2608 | not TMP0, TMP0
2609 | lwz TMP1, UPVAL:RB->v
2610 | stw TMP0, 0(TMP1)
2611 | ins_next2
2612 break;
2613
2614 case BC_UCLO:
2615 | // RA = level*8, RD = target
2616 | lwz TMP1, L->openupval
2617 | branch_RD // Do this first since RD is not saved.
2618 | stw BASE, L->base
2619 | cmplwi TMP1, 0
2620 | mr CARG1, L
2621 | beq >1
2622 | add CARG2, BASE, RA
2623 | bl extern lj_func_closeuv // (lua_State *L, TValue *level)
2624 | lwz BASE, L->base
2625 |1:
2626 | ins_next
2627 break;
2628
2629 case BC_FNEW:
2630 | // RA = dst*8, RD = proto_const*8 (~) (holding function prototype)
2631 | srwi TMP1, RD, 1
2632 | stw BASE, L->base
2633 | subfic TMP1, TMP1, -4
2634 | stw PC, SAVE_PC
2635 | lwzx CARG2, KBASE, TMP1 // KBASE-4-tab_const*4
2636 | mr CARG1, L
2637 | lwz CARG3, FRAME_FUNC(BASE)
2638 | // (lua_State *L, GCproto *pt, GCfuncL *parent)
2639 | bl extern lj_func_newL_gc
2640 | // Returns GCfuncL *.
2641 | lwz BASE, L->base
2642 | evmergelo LFUNC:CRET1, TISFUNC, LFUNC:CRET1
2643 | evstddx LFUNC:CRET1, BASE, RA
2644 | ins_next
2645 break;
2646
2647 /* -- Table ops --------------------------------------------------------- */
2648
2649 case BC_TNEW:
2650 case BC_TDUP:
2651 | // RA = dst*8, RD = (hbits|asize)*8 | tab_const*8 (~)
2652 | lwz TMP0, DISPATCH_GL(gc.total)(DISPATCH)
2653 | mr CARG1, L
2654 | lwz TMP1, DISPATCH_GL(gc.threshold)(DISPATCH)
2655 | stw BASE, L->base
2656 | cmplw TMP0, TMP1
2657 | stw PC, SAVE_PC
2658 | bge >5
2659 |1:
2660 if (op == BC_TNEW) {
2661 | rlwinm CARG2, RD, 29, 21, 31
2662 | rlwinm CARG3, RD, 18, 27, 31
2663 | cmpwi CARG2, 0x7ff
2664 | li TMP1, 0x801
2665 | iseleq CARG2, TMP1, CARG2
2666 | bl extern lj_tab_new // (lua_State *L, int32_t asize, uint32_t hbits)
2667 | // Returns Table *.
2668 } else {
2669 | srwi TMP1, RD, 1
2670 | subfic TMP1, TMP1, -4
2671 | lwzx CARG2, KBASE, TMP1 // KBASE-4-tab_const*4
2672 | bl extern lj_tab_dup // (lua_State *L, Table *kt)
2673 | // Returns Table *.
2674 }
2675 | lwz BASE, L->base
2676 | evmergelo TAB:CRET1, TISTAB, TAB:CRET1
2677 | evstddx TAB:CRET1, BASE, RA
2678 | ins_next
2679 |5:
2680 | mr SAVE0, RD
2681 | bl extern lj_gc_step_fixtop // (lua_State *L)
2682 | mr RD, SAVE0
2683 | mr CARG1, L
2684 | b <1
2685 break;
2686
2687 case BC_GGET:
2688 | // RA = dst*8, RD = str_const*8 (~)
2689 case BC_GSET:
2690 | // RA = src*8, RD = str_const*8 (~)
2691 | lwz LFUNC:TMP2, FRAME_FUNC(BASE)
2692 | srwi TMP1, RD, 1
2693 | lwz TAB:RB, LFUNC:TMP2->env
2694 | subfic TMP1, TMP1, -4
2695 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
2696 if (op == BC_GGET) {
2697 | b ->BC_TGETS_Z
2698 } else {
2699 | b ->BC_TSETS_Z
2700 }
2701 break;
2702
2703 case BC_TGETV:
2704 | // RA = dst*8, RB = table*8, RC = key*8
2705 | evlddx TAB:RB, BASE, RB
2706 | evlddx RC, BASE, RC
2707 | checktab TAB:RB
2708 | checkfail ->vmeta_tgetv
2709 | checknum RC
2710 | checkfail >5
2711 | // Convert number key to integer
2712 | efdctsi TMP2, RC
2713 | lwz TMP0, TAB:RB->asize
2714 | efdcfsi TMP1, TMP2
2715 | cmplw cr0, TMP0, TMP2
2716 | efdcmpeq cr1, RC, TMP1
2717 | lwz TMP1, TAB:RB->array
2718 | crand 4*cr0+gt, 4*cr0+gt, 4*cr1+gt
2719 | slwi TMP2, TMP2, 3
2720 | ble ->vmeta_tgetv // Integer key and in array part?
2721 | evlddx TMP1, TMP1, TMP2
2722 | checknil TMP1
2723 | checkok >2
2724 |1:
2725 | evstddx TMP1, BASE, RA
2726 | ins_next
2727 |
2728 |2: // Check for __index if table value is nil.
2729 | lwz TAB:TMP2, TAB:RB->metatable
2730 | cmplwi TAB:TMP2, 0
2731 | beq <1 // No metatable: done.
2732 | lbz TMP0, TAB:TMP2->nomm
2733 | andi. TMP0, TMP0, 1<<MM_index
2734 | bne <1 // 'no __index' flag set: done.
2735 | b ->vmeta_tgetv
2736 |
2737 |5:
2738 | checkstr STR:RC // String key?
2739 | checkok ->BC_TGETS_Z
2740 | b ->vmeta_tgetv
2741 break;
2742 case BC_TGETS:
2743 | // RA = dst*8, RB = table*8, RC = str_const*8 (~)
2744 | evlddx TAB:RB, BASE, RB
2745 | srwi TMP1, RC, 1
2746 | checktab TAB:RB
2747 | subfic TMP1, TMP1, -4
2748 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
2749 | checkfail ->vmeta_tgets1
2750 |->BC_TGETS_Z:
2751 | // TAB:RB = GCtab *, STR:RC = GCstr *, RA = dst*8
2752 | lwz TMP0, TAB:RB->hmask
2753 | lwz TMP1, STR:RC->hash
2754 | lwz NODE:TMP2, TAB:RB->node
2755 | evmergelo STR:RC, TISSTR, STR:RC
2756 | and TMP1, TMP1, TMP0 // idx = str->hash & tab->hmask
2757 | slwi TMP0, TMP1, 5
2758 | slwi TMP1, TMP1, 3
2759 | sub TMP1, TMP0, TMP1
2760 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
2761 |1:
2762 | evldd TMP0, NODE:TMP2->key
2763 | evldd TMP1, NODE:TMP2->val
2764 | evcmpeq TMP0, STR:RC
2765 | checkanyfail >4
2766 | checknil TMP1
2767 | checkok >5 // Key found, but nil value?
2768 |3:
2769 | evstddx TMP1, BASE, RA
2770 | ins_next
2771 |
2772 |4: // Follow hash chain.
2773 | lwz NODE:TMP2, NODE:TMP2->next
2774 | cmplwi NODE:TMP2, 0
2775 | bne <1
2776 | // End of hash chain: key not found, nil result.
2777 | evmr TMP1, TISNIL
2778 |
2779 |5: // Check for __index if table value is nil.
2780 | lwz TAB:TMP2, TAB:RB->metatable
2781 | cmplwi TAB:TMP2, 0
2782 | beq <3 // No metatable: done.
2783 | lbz TMP0, TAB:TMP2->nomm
2784 | andi. TMP0, TMP0, 1<<MM_index
2785 | bne <3 // 'no __index' flag set: done.
2786 | b ->vmeta_tgets
2787 break;
2788 case BC_TGETB:
2789 | // RA = dst*8, RB = table*8, RC = index*8
2790 | evlddx TAB:RB, BASE, RB
2791 | srwi TMP0, RC, 3
2792 | checktab TAB:RB
2793 | checkfail ->vmeta_tgetb
2794 | lwz TMP1, TAB:RB->asize
2795 | lwz TMP2, TAB:RB->array
2796 | cmplw TMP0, TMP1
2797 | bge ->vmeta_tgetb
2798 | evlddx TMP1, TMP2, RC
2799 | checknil TMP1
2800 | checkok >5
2801 |1:
2802 | ins_next1
2803 | evstddx TMP1, BASE, RA
2804 | ins_next2
2805 |
2806 |5: // Check for __index if table value is nil.
2807 | lwz TAB:TMP2, TAB:RB->metatable
2808 | cmplwi TAB:TMP2, 0
2809 | beq <1 // No metatable: done.
2810 | lbz TMP2, TAB:TMP2->nomm
2811 | andi. TMP2, TMP2, 1<<MM_index
2812 | bne <1 // 'no __index' flag set: done.
2813 | b ->vmeta_tgetb // Caveat: preserve TMP0!
2814 break;
2815
2816 case BC_TSETV:
2817 | // RA = src*8, RB = table*8, RC = key*8
2818 | evlddx TAB:RB, BASE, RB
2819 | evlddx RC, BASE, RC
2820 | checktab TAB:RB
2821 | checkfail ->vmeta_tsetv
2822 | checknum RC
2823 | checkfail >5
2824 | // Convert number key to integer
2825 | efdctsi TMP2, RC
2826 | evlddx SAVE0, BASE, RA
2827 | lwz TMP0, TAB:RB->asize
2828 | efdcfsi TMP1, TMP2
2829 | cmplw cr0, TMP0, TMP2
2830 | efdcmpeq cr1, RC, TMP1
2831 | lwz TMP1, TAB:RB->array
2832 | crand 4*cr0+gt, 4*cr0+gt, 4*cr1+gt
2833 | slwi TMP0, TMP2, 3
2834 | ble ->vmeta_tsetv // Integer key and in array part?
2835 | lbz TMP3, TAB:RB->marked
2836 | evlddx TMP2, TMP1, TMP0
2837 | checknil TMP2
2838 | checkok >3
2839 |1:
2840 | andi. TMP2, TMP3, LJ_GC_BLACK // isblack(table)
2841 | evstddx SAVE0, TMP1, TMP0
2842 | bne >7
2843 |2:
2844 | ins_next
2845 |
2846 |3: // Check for __newindex if previous value is nil.
2847 | lwz TAB:TMP2, TAB:RB->metatable
2848 | cmplwi TAB:TMP2, 0
2849 | beq <1 // No metatable: done.
2850 | lbz TMP2, TAB:TMP2->nomm
2851 | andi. TMP2, TMP2, 1<<MM_newindex
2852 | bne <1 // 'no __newindex' flag set: done.
2853 | b ->vmeta_tsetv
2854 |
2855 |5:
2856 | checkstr STR:RC // String key?
2857 | checkok ->BC_TSETS_Z
2858 | b ->vmeta_tsetv
2859 |
2860 |7: // Possible table write barrier for the value. Skip valiswhite check.
2861 | barrierback TAB:RB, TMP3, TMP0
2862 | b <2
2863 break;
2864 case BC_TSETS:
2865 | // RA = src*8, RB = table*8, RC = str_const*8 (~)
2866 | evlddx TAB:RB, BASE, RB
2867 | srwi TMP1, RC, 1
2868 | checktab TAB:RB
2869 | subfic TMP1, TMP1, -4
2870 | lwzx STR:RC, KBASE, TMP1 // KBASE-4-str_const*4
2871 | checkfail ->vmeta_tsets1
2872 |->BC_TSETS_Z:
2873 | // TAB:RB = GCtab *, STR:RC = GCstr *, RA = src*8
2874 | lwz TMP0, TAB:RB->hmask
2875 | lwz TMP1, STR:RC->hash
2876 | lwz NODE:TMP2, TAB:RB->node
2877 | evmergelo STR:RC, TISSTR, STR:RC
2878 | stb ZERO, TAB:RB->nomm // Clear metamethod cache.
2879 | and TMP1, TMP1, TMP0 // idx = str->hash & tab->hmask
2880 | evlddx SAVE0, BASE, RA
2881 | slwi TMP0, TMP1, 5
2882 | slwi TMP1, TMP1, 3
2883 | sub TMP1, TMP0, TMP1
2884 | lbz TMP3, TAB:RB->marked
2885 | add NODE:TMP2, NODE:TMP2, TMP1 // node = tab->node + (idx*32-idx*8)
2886 |1:
2887 | evldd TMP0, NODE:TMP2->key
2888 | evldd TMP1, NODE:TMP2->val
2889 | evcmpeq TMP0, STR:RC
2890 | checkanyfail >5
2891 | checknil TMP1
2892 | checkok >4 // Key found, but nil value?
2893 |2:
2894 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
2895 | evstdd SAVE0, NODE:TMP2->val
2896 | bne >7
2897 |3:
2898 | ins_next
2899 |
2900 |4: // Check for __newindex if previous value is nil.
2901 | lwz TAB:TMP1, TAB:RB->metatable
2902 | cmplwi TAB:TMP1, 0
2903 | beq <2 // No metatable: done.
2904 | lbz TMP0, TAB:TMP1->nomm
2905 | andi. TMP0, TMP0, 1<<MM_newindex
2906 | bne <2 // 'no __newindex' flag set: done.
2907 | b ->vmeta_tsets
2908 |
2909 |5: // Follow hash chain.
2910 | lwz NODE:TMP2, NODE:TMP2->next
2911 | cmplwi NODE:TMP2, 0
2912 | bne <1
2913 | // End of hash chain: key not found, add a new one.
2914 |
2915 | // But check for __newindex first.
2916 | lwz TAB:TMP1, TAB:RB->metatable
2917 | la CARG3, DISPATCH_GL(tmptv)(DISPATCH)
2918 | stw PC, SAVE_PC
2919 | mr CARG1, L
2920 | cmplwi TAB:TMP1, 0
2921 | stw BASE, L->base
2922 | beq >6 // No metatable: continue.
2923 | lbz TMP0, TAB:TMP1->nomm
2924 | andi. TMP0, TMP0, 1<<MM_newindex
2925 | beq ->vmeta_tsets // 'no __newindex' flag NOT set: check.
2926 |6:
2927 | mr CARG2, TAB:RB
2928 | evstdd STR:RC, 0(CARG3)
2929 | bl extern lj_tab_newkey // (lua_State *L, GCtab *t, TValue *k)
2930 | // Returns TValue *.
2931 | lwz BASE, L->base
2932 | evstdd SAVE0, 0(CRET1)
2933 | b <3 // No 2nd write barrier needed.
2934 |
2935 |7: // Possible table write barrier for the value. Skip valiswhite check.
2936 | barrierback TAB:RB, TMP3, TMP0
2937 | b <3
2938 break;
2939 case BC_TSETB:
2940 | // RA = src*8, RB = table*8, RC = index*8
2941 | evlddx TAB:RB, BASE, RB
2942 | srwi TMP0, RC, 3
2943 | checktab TAB:RB
2944 | checkfail ->vmeta_tsetb
2945 | lwz TMP1, TAB:RB->asize
2946 | lwz TMP2, TAB:RB->array
2947 | lbz TMP3, TAB:RB->marked
2948 | cmplw TMP0, TMP1
2949 | evlddx SAVE0, BASE, RA
2950 | bge ->vmeta_tsetb
2951 | evlddx TMP1, TMP2, RC
2952 | checknil TMP1
2953 | checkok >5
2954 |1:
2955 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
2956 | evstddx SAVE0, TMP2, RC
2957 | bne >7
2958 |2:
2959 | ins_next
2960 |
2961 |5: // Check for __newindex if previous value is nil.
2962 | lwz TAB:TMP1, TAB:RB->metatable
2963 | cmplwi TAB:TMP1, 0
2964 | beq <1 // No metatable: done.
2965 | lbz TMP1, TAB:TMP1->nomm
2966 | andi. TMP1, TMP1, 1<<MM_newindex
2967 | bne <1 // 'no __newindex' flag set: done.
2968 | b ->vmeta_tsetb // Caveat: preserve TMP0!
2969 |
2970 |7: // Possible table write barrier for the value. Skip valiswhite check.
2971 | barrierback TAB:RB, TMP3, TMP0
2972 | b <2
2973 break;
2974
2975 case BC_TSETM:
2976 | // RA = base*8 (table at base-1), RD = num_const*8 (start index)
2977 | add RA, BASE, RA
2978 |1:
2979 | add TMP3, KBASE, RD
2980 | lwz TAB:CARG2, -4(RA) // Guaranteed to be a table.
2981 | addic. TMP0, MULTRES, -8
2982 | lwz TMP3, 4(TMP3) // Integer constant is in lo-word.
2983 | srwi CARG3, TMP0, 3
2984 | beq >4 // Nothing to copy?
2985 | add CARG3, CARG3, TMP3
2986 | lwz TMP2, TAB:CARG2->asize
2987 | slwi TMP1, TMP3, 3
2988 | lbz TMP3, TAB:CARG2->marked
2989 | cmplw CARG3, TMP2
2990 | add TMP2, RA, TMP0
2991 | lwz TMP0, TAB:CARG2->array
2992 | bgt >5
2993 | add TMP1, TMP1, TMP0
2994 | andi. TMP0, TMP3, LJ_GC_BLACK // isblack(table)
2995 |3: // Copy result slots to table.
2996 | evldd TMP0, 0(RA)
2997 | addi RA, RA, 8
2998 | cmpw cr1, RA, TMP2
2999 | evstdd TMP0, 0(TMP1)
3000 | addi TMP1, TMP1, 8
3001 | blt cr1, <3
3002 | bne >7
3003 |4:
3004 | ins_next
3005 |
3006 |5: // Need to resize array part.
3007 | stw BASE, L->base
3008 | mr CARG1, L
3009 | stw PC, SAVE_PC
3010 | mr SAVE0, RD
3011 | bl extern lj_tab_reasize // (lua_State *L, GCtab *t, int nasize)
3012 | // Must not reallocate the stack.
3013 | mr RD, SAVE0
3014 | b <1
3015 |
3016 |7: // Possible table write barrier for any value. Skip valiswhite check.
3017 | barrierback TAB:RB, TMP3, TMP0
3018 | b <4
3019 break;
3020
3021 /* -- Calls and vararg handling ----------------------------------------- */
3022
3023 case BC_CALLM:
3024 | // RA = base*8, (RB = (nresults+1)*8,) RC = extra_nargs*8
3025 | add NARGS8:RC, NARGS8:RC, MULTRES
3026 | // Fall through. Assumes BC_CALL follows.
3027 break;
3028 case BC_CALL:
3029 | // RA = base*8, (RB = (nresults+1)*8,) RC = (nargs+1)*8
3030 | evlddx LFUNC:RB, BASE, RA
3031 | mr TMP2, BASE
3032 | add BASE, BASE, RA
3033 | subi NARGS8:RC, NARGS8:RC, 8
3034 | checkfunc LFUNC:RB
3035 | addi BASE, BASE, 8
3036 | checkfail ->vmeta_call
3037 | ins_call
3038 break;
3039
3040 case BC_CALLMT:
3041 | // RA = base*8, (RB = 0,) RC = extra_nargs*8
3042 | add NARGS8:RC, NARGS8:RC, MULTRES
3043 | // Fall through. Assumes BC_CALLT follows.
3044 break;
3045 case BC_CALLT:
3046 | // RA = base*8, (RB = 0,) RC = (nargs+1)*8
3047 | evlddx LFUNC:RB, BASE, RA
3048 | add RA, BASE, RA
3049 | lwz TMP1, FRAME_PC(BASE)
3050 | subi NARGS8:RC, NARGS8:RC, 8
3051 | checkfunc LFUNC:RB
3052 | addi RA, RA, 8
3053 | checkfail ->vmeta_callt
3054 |->BC_CALLT_Z:
3055 | andi. TMP0, TMP1, FRAME_TYPE // Caveat: preserve cr0 until the crand.
3056 | lbz TMP3, LFUNC:RB->ffid
3057 | xori TMP2, TMP1, FRAME_VARG
3058 | cmplwi cr1, NARGS8:RC, 0
3059 | bne >7
3060 |1:
3061 | stw LFUNC:RB, FRAME_FUNC(BASE) // Copy function down, but keep PC.
3062 | li TMP2, 0
3063 | cmplwi cr7, TMP3, 1 // (> FF_C) Calling a fast function?
3064 | beq cr1, >3
3065 |2:
3066 | addi TMP3, TMP2, 8
3067 | evlddx TMP0, RA, TMP2
3068 | cmplw cr1, TMP3, NARGS8:RC
3069 | evstddx TMP0, BASE, TMP2
3070 | mr TMP2, TMP3
3071 | bne cr1, <2
3072 |3:
3073 | crand 4*cr0+eq, 4*cr0+eq, 4*cr7+gt
3074 | beq >5
3075 |4:
3076 | ins_callt
3077 |
3078 |5: // Tailcall to a fast function with a Lua frame below.
3079 | lwz INS, -4(TMP1)
3080 | decode_RA8 RA, INS
3081 | sub TMP1, BASE, RA
3082 | lwz LFUNC:TMP1, FRAME_FUNC-8(TMP1)
3083 | lwz TMP1, LFUNC:TMP1->pc
3084 | lwz KBASE, PC2PROTO(k)(TMP1) // Need to prepare KBASE.
3085 | b <4
3086 |
3087 |7: // Tailcall from a vararg function.
3088 | andi. TMP0, TMP2, FRAME_TYPEP
3089 | bne <1 // Vararg frame below?
3090 | sub BASE, BASE, TMP2 // Relocate BASE down.
3091 | lwz TMP1, FRAME_PC(BASE)
3092 | andi. TMP0, TMP1, FRAME_TYPE
3093 | b <1
3094 break;
3095
3096 case BC_ITERC:
3097 | // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 ((2+1)*8))
3098 | subi RA, RA, 24 // evldd doesn't support neg. offsets.
3099 | mr TMP2, BASE
3100 | evlddx LFUNC:RB, BASE, RA
3101 | add BASE, BASE, RA
3102 | evldd TMP0, 8(BASE)
3103 | evldd TMP1, 16(BASE)
3104 | evstdd LFUNC:RB, 24(BASE) // Copy callable.
3105 | checkfunc LFUNC:RB
3106 | evstdd TMP0, 32(BASE) // Copy state.
3107 | li NARGS8:RC, 16 // Iterators get 2 arguments.
3108 | evstdd TMP1, 40(BASE) // Copy control var.
3109 | addi BASE, BASE, 32
3110 | checkfail ->vmeta_call
3111 | ins_call
3112 break;
3113
3114 case BC_ITERN:
3115 | // RA = base*8, (RB = (nresults+1)*8, RC = (nargs+1)*8 (2+1)*8)
3116#if LJ_HASJIT
3117 | // NYI: add hotloop, record BC_ITERN.
3118#endif
3119 | add RA, BASE, RA
3120 | lwz TAB:RB, -12(RA)
3121 | lwz RC, -4(RA) // Get index from control var.
3122 | lwz TMP0, TAB:RB->asize
3123 | lwz TMP1, TAB:RB->array
3124 | addi PC, PC, 4
3125 |1: // Traverse array part.
3126 | cmplw RC, TMP0
3127 | slwi TMP3, RC, 3
3128 | bge >5 // Index points after array part?
3129 | evlddx TMP2, TMP1, TMP3
3130 | checknil TMP2
3131 | lwz INS, -4(PC)
3132 | checkok >4
3133 | efdcfsi TMP0, RC
3134 | addi RC, RC, 1
3135 | addis TMP3, PC, -(BCBIAS_J*4 >> 16)
3136 | evstdd TMP2, 8(RA)
3137 | decode_RD4 TMP1, INS
3138 | stw RC, -4(RA) // Update control var.
3139 | add PC, TMP1, TMP3
3140 | evstdd TMP0, 0(RA)
3141 |3:
3142 | ins_next
3143 |
3144 |4: // Skip holes in array part.
3145 | addi RC, RC, 1
3146 | b <1
3147 |
3148 |5: // Traverse hash part.
3149 | lwz TMP1, TAB:RB->hmask
3150 | sub RC, RC, TMP0
3151 | lwz TMP2, TAB:RB->node
3152 |6:
3153 | cmplw RC, TMP1 // End of iteration? Branch to ITERL+1.
3154 | slwi TMP3, RC, 5
3155 | bgt <3
3156 | slwi RB, RC, 3
3157 | sub TMP3, TMP3, RB
3158 | evlddx RB, TMP2, TMP3
3159 | add NODE:TMP3, TMP2, TMP3
3160 | checknil RB
3161 | lwz INS, -4(PC)
3162 | checkok >7
3163 | evldd TMP3, NODE:TMP3->key
3164 | addis TMP2, PC, -(BCBIAS_J*4 >> 16)
3165 | evstdd RB, 8(RA)
3166 | add RC, RC, TMP0
3167 | decode_RD4 TMP1, INS
3168 | evstdd TMP3, 0(RA)
3169 | addi RC, RC, 1
3170 | add PC, TMP1, TMP2
3171 | stw RC, -4(RA) // Update control var.
3172 | b <3
3173 |
3174 |7: // Skip holes in hash part.
3175 | addi RC, RC, 1
3176 | b <6
3177 break;
3178
3179 case BC_ISNEXT:
3180 | // RA = base*8, RD = target (points to ITERN)
3181 | add RA, BASE, RA
3182 | li TMP2, -24
3183 | evlddx CFUNC:TMP1, RA, TMP2
3184 | lwz TMP2, -16(RA)
3185 | lwz TMP3, -8(RA)
3186 | evmergehi TMP0, CFUNC:TMP1, CFUNC:TMP1
3187 | cmpwi cr0, TMP2, LJ_TTAB
3188 | cmpwi cr1, TMP0, LJ_TFUNC
3189 | cmpwi cr6, TMP3, LJ_TNIL
3190 | bne cr1, >5
3191 | lbz TMP1, CFUNC:TMP1->ffid
3192 | crand 4*cr0+eq, 4*cr0+eq, 4*cr6+eq
3193 | cmpwi cr7, TMP1, FF_next_N
3194 | srwi TMP0, RD, 1
3195 | crand 4*cr0+eq, 4*cr0+eq, 4*cr7+eq
3196 | add TMP3, PC, TMP0
3197 | bne cr0, >5
3198 | stw ZERO, -4(RA) // Initialize control var.
3199 | addis PC, TMP3, -(BCBIAS_J*4 >> 16)
3200 |1:
3201 | ins_next
3202 |5: // Despecialize bytecode if any of the checks fail.
3203 | li TMP0, BC_JMP
3204 | li TMP1, BC_ITERC
3205 | stb TMP0, -1(PC)
3206 | addis PC, TMP3, -(BCBIAS_J*4 >> 16)
3207 | stb TMP1, 3(PC)
3208 | b <1
3209 break;
3210
3211 case BC_VARG:
3212 | // RA = base*8, RB = (nresults+1)*8, RC = numparams*8
3213 | lwz TMP0, FRAME_PC(BASE)
3214 | add RC, BASE, RC
3215 | add RA, BASE, RA
3216 | addi RC, RC, FRAME_VARG
3217 | add TMP2, RA, RB
3218 | subi TMP3, BASE, 8 // TMP3 = vtop
3219 | sub RC, RC, TMP0 // RC = vbase
3220 | // Note: RC may now be even _above_ BASE if nargs was < numparams.
3221 | cmplwi cr1, RB, 0
3222 | sub. TMP1, TMP3, RC
3223 | beq cr1, >5 // Copy all varargs?
3224 | subi TMP2, TMP2, 16
3225 | ble >2 // No vararg slots?
3226 |1: // Copy vararg slots to destination slots.
3227 | evldd TMP0, 0(RC)
3228 | addi RC, RC, 8
3229 | evstdd TMP0, 0(RA)
3230 | cmplw RA, TMP2
3231 | cmplw cr1, RC, TMP3
3232 | bge >3 // All destination slots filled?
3233 | addi RA, RA, 8
3234 | blt cr1, <1 // More vararg slots?
3235 |2: // Fill up remainder with nil.
3236 | evstdd TISNIL, 0(RA)
3237 | cmplw RA, TMP2
3238 | addi RA, RA, 8
3239 | blt <2
3240 |3:
3241 | ins_next
3242 |
3243 |5: // Copy all varargs.
3244 | lwz TMP0, L->maxstack
3245 | li MULTRES, 8 // MULTRES = (0+1)*8
3246 | ble <3 // No vararg slots?
3247 | add TMP2, RA, TMP1
3248 | cmplw TMP2, TMP0
3249 | addi MULTRES, TMP1, 8
3250 | bgt >7
3251 |6:
3252 | evldd TMP0, 0(RC)
3253 | addi RC, RC, 8
3254 | evstdd TMP0, 0(RA)
3255 | cmplw RC, TMP3
3256 | addi RA, RA, 8
3257 | blt <6 // More vararg slots?
3258 | b <3
3259 |
3260 |7: // Grow stack for varargs.
3261 | mr CARG1, L
3262 | stw RA, L->top
3263 | sub SAVE0, RC, BASE // Need delta, because BASE may change.
3264 | stw BASE, L->base
3265 | sub RA, RA, BASE
3266 | stw PC, SAVE_PC
3267 | srwi CARG2, TMP1, 3
3268 | bl extern lj_state_growstack // (lua_State *L, int n)
3269 | lwz BASE, L->base
3270 | add RA, BASE, RA
3271 | add RC, BASE, SAVE0
3272 | subi TMP3, BASE, 8
3273 | b <6
3274 break;
3275
3276 /* -- Returns ----------------------------------------------------------- */
3277
3278 case BC_RETM:
3279 | // RA = results*8, RD = extra_nresults*8
3280 | add RD, RD, MULTRES // MULTRES >= 8, so RD >= 8.
3281 | // Fall through. Assumes BC_RET follows.
3282 break;
3283
3284 case BC_RET:
3285 | // RA = results*8, RD = (nresults+1)*8
3286 | lwz PC, FRAME_PC(BASE)
3287 | add RA, BASE, RA
3288 | mr MULTRES, RD
3289 |1:
3290 | andi. TMP0, PC, FRAME_TYPE
3291 | xori TMP1, PC, FRAME_VARG
3292 | bne ->BC_RETV_Z
3293 |
3294 |->BC_RET_Z:
3295 | // BASE = base, RA = resultptr, RD = (nresults+1)*8, PC = return
3296 | lwz INS, -4(PC)
3297 | cmpwi RD, 8
3298 | subi TMP2, BASE, 8
3299 | subi RC, RD, 8
3300 | decode_RB8 RB, INS
3301 | beq >3
3302 | li TMP1, 0
3303 |2:
3304 | addi TMP3, TMP1, 8
3305 | evlddx TMP0, RA, TMP1
3306 | cmpw TMP3, RC
3307 | evstddx TMP0, TMP2, TMP1
3308 | beq >3
3309 | addi TMP1, TMP3, 8
3310 | evlddx TMP0, RA, TMP3
3311 | cmpw TMP1, RC
3312 | evstddx TMP0, TMP2, TMP3
3313 | bne <2
3314 |3:
3315 |5:
3316 | cmplw RB, RD
3317 | decode_RA8 RA, INS
3318 | bgt >6
3319 | sub BASE, TMP2, RA
3320 | lwz LFUNC:TMP1, FRAME_FUNC(BASE)
3321 | ins_next1
3322 | lwz TMP1, LFUNC:TMP1->pc
3323 | lwz KBASE, PC2PROTO(k)(TMP1)
3324 | ins_next2
3325 |
3326 |6: // Fill up results with nil.
3327 | subi TMP1, RD, 8
3328 | addi RD, RD, 8
3329 | evstddx TISNIL, TMP2, TMP1
3330 | b <5
3331 |
3332 |->BC_RETV_Z: // Non-standard return case.
3333 | andi. TMP2, TMP1, FRAME_TYPEP
3334 | bne ->vm_return
3335 | // Return from vararg function: relocate BASE down.
3336 | sub BASE, BASE, TMP1
3337 | lwz PC, FRAME_PC(BASE)
3338 | b <1
3339 break;
3340
3341 case BC_RET0: case BC_RET1:
3342 | // RA = results*8, RD = (nresults+1)*8
3343 | lwz PC, FRAME_PC(BASE)
3344 | add RA, BASE, RA
3345 | mr MULTRES, RD
3346 | andi. TMP0, PC, FRAME_TYPE
3347 | xori TMP1, PC, FRAME_VARG
3348 | bne ->BC_RETV_Z
3349 |
3350 | lwz INS, -4(PC)
3351 | subi TMP2, BASE, 8
3352 | decode_RB8 RB, INS
3353 if (op == BC_RET1) {
3354 | evldd TMP0, 0(RA)
3355 | evstdd TMP0, 0(TMP2)
3356 }
3357 |5:
3358 | cmplw RB, RD
3359 | decode_RA8 RA, INS
3360 | bgt >6
3361 | sub BASE, TMP2, RA
3362 | lwz LFUNC:TMP1, FRAME_FUNC(BASE)
3363 | ins_next1
3364 | lwz TMP1, LFUNC:TMP1->pc
3365 | lwz KBASE, PC2PROTO(k)(TMP1)
3366 | ins_next2
3367 |
3368 |6: // Fill up results with nil.
3369 | subi TMP1, RD, 8
3370 | addi RD, RD, 8
3371 | evstddx TISNIL, TMP2, TMP1
3372 | b <5
3373 break;
3374
3375 /* -- Loops and branches ------------------------------------------------ */
3376
3377 case BC_FORL:
3378#if LJ_HASJIT
3379 | hotloop
3380#endif
3381 | // Fall through. Assumes BC_IFORL follows.
3382 break;
3383
3384 case BC_JFORI:
3385 case BC_JFORL:
3386#if !LJ_HASJIT
3387 break;
3388#endif
3389 case BC_FORI:
3390 case BC_IFORL:
3391 | // RA = base*8, RD = target (after end of loop or start of loop)
3392 vk = (op == BC_IFORL || op == BC_JFORL);
3393 | add RA, BASE, RA
3394 | evldd TMP1, FORL_IDX*8(RA)
3395 | evldd TMP3, FORL_STEP*8(RA)
3396 | evldd TMP2, FORL_STOP*8(RA)
3397 if (!vk) {
3398 | evcmpgtu cr0, TMP1, TISNUM
3399 | evcmpgtu cr7, TMP3, TISNUM
3400 | evcmpgtu cr1, TMP2, TISNUM
3401 | cror 4*cr0+lt, 4*cr0+lt, 4*cr7+lt
3402 | cror 4*cr0+lt, 4*cr0+lt, 4*cr1+lt
3403 | blt ->vmeta_for
3404 }
3405 if (vk) {
3406 | efdadd TMP1, TMP1, TMP3
3407 | evstdd TMP1, FORL_IDX*8(RA)
3408 }
3409 | evcmpgts TMP3, TISNIL
3410 | evstdd TMP1, FORL_EXT*8(RA)
3411 | bge >2
3412 | efdcmpgt TMP1, TMP2
3413 |1:
3414 if (op != BC_JFORL) {
3415 | srwi RD, RD, 1
3416 | add RD, PC, RD
3417 if (op == BC_JFORI) {
3418 | addis PC, RD, -(BCBIAS_J*4 >> 16)
3419 } else {
3420 | addis RD, RD, -(BCBIAS_J*4 >> 16)
3421 }
3422 }
3423 if (op == BC_FORI) {
3424 | iselgt PC, RD, PC
3425 } else if (op == BC_IFORL) {
3426 | iselgt PC, PC, RD
3427 } else {
3428 | ble =>BC_JLOOP
3429 }
3430 | ins_next
3431 |2:
3432 | efdcmpgt TMP2, TMP1
3433 | b <1
3434 break;
3435
3436 case BC_ITERL:
3437#if LJ_HASJIT
3438 | hotloop
3439#endif
3440 | // Fall through. Assumes BC_IITERL follows.
3441 break;
3442
3443 case BC_JITERL:
3444#if !LJ_HASJIT
3445 break;
3446#endif
3447 case BC_IITERL:
3448 | // RA = base*8, RD = target
3449 | evlddx TMP1, BASE, RA
3450 | subi RA, RA, 8
3451 | checknil TMP1
3452 | checkok >1 // Stop if iterator returned nil.
3453 if (op == BC_JITERL) {
3454 | NYI
3455 } else {
3456 | branch_RD // Otherwise save control var + branch.
3457 | evstddx TMP1, BASE, RA
3458 }
3459 |1:
3460 | ins_next
3461 break;
3462
3463 case BC_LOOP:
3464 | // RA = base*8, RD = target (loop extent)
3465 | // Note: RA/RD is only used by trace recorder to determine scope/extent
3466 | // This opcode does NOT jump, it's only purpose is to detect a hot loop.
3467#if LJ_HASJIT
3468 | hotloop
3469#endif
3470 | // Fall through. Assumes BC_ILOOP follows.
3471 break;
3472
3473 case BC_ILOOP:
3474 | // RA = base*8, RD = target (loop extent)
3475 | ins_next
3476 break;
3477
3478 case BC_JLOOP:
3479#if LJ_HASJIT
3480 | NYI
3481#endif
3482 break;
3483
3484 case BC_JMP:
3485 | // RA = base*8 (only used by trace recorder), RD = target
3486 | branch_RD
3487 | ins_next
3488 break;
3489
3490 /* -- Function headers -------------------------------------------------- */
3491
3492 case BC_FUNCF:
3493#if LJ_HASJIT
3494 | hotcall
3495#endif
3496 case BC_FUNCV: /* NYI: compiled vararg functions. */
3497 | // Fall through. Assumes BC_IFUNCF/BC_IFUNCV follow.
3498 break;
3499
3500 case BC_JFUNCF:
3501#if !LJ_HASJIT
3502 break;
3503#endif
3504 case BC_IFUNCF:
3505 | // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
3506 | lwz TMP2, L->maxstack
3507 | lbz TMP1, -4+PC2PROTO(numparams)(PC)
3508 | lwz KBASE, -4+PC2PROTO(k)(PC)
3509 | cmplw RA, TMP2
3510 | slwi TMP1, TMP1, 3
3511 | bgt ->vm_growstack_l
3512 | ins_next1
3513 |2:
3514 | cmplw NARGS8:RC, TMP1 // Check for missing parameters.
3515 | ble >3
3516 if (op == BC_JFUNCF) {
3517 | NYI
3518 } else {
3519 | ins_next2
3520 }
3521 |
3522 |3: // Clear missing parameters.
3523 | evstddx TISNIL, BASE, NARGS8:RC
3524 | addi NARGS8:RC, NARGS8:RC, 8
3525 | b <2
3526 break;
3527
3528 case BC_JFUNCV:
3529#if !LJ_HASJIT
3530 break;
3531#endif
3532 | NYI // NYI: compiled vararg functions
3533 break; /* NYI: compiled vararg functions. */
3534
3535 case BC_IFUNCV:
3536 | // BASE = new base, RA = BASE+framesize*8, RB = LFUNC, RC = nargs*8
3537 | lwz TMP2, L->maxstack
3538 | add TMP1, BASE, RC
3539 | add TMP0, RA, RC
3540 | stw LFUNC:RB, 4(TMP1) // Store copy of LFUNC.
3541 | addi TMP3, RC, 8+FRAME_VARG
3542 | lwz KBASE, -4+PC2PROTO(k)(PC)
3543 | cmplw TMP0, TMP2
3544 | stw TMP3, 0(TMP1) // Store delta + FRAME_VARG.
3545 | bge ->vm_growstack_l
3546 | lbz TMP2, -4+PC2PROTO(numparams)(PC)
3547 | mr RA, BASE
3548 | mr RC, TMP1
3549 | ins_next1
3550 | cmpwi TMP2, 0
3551 | addi BASE, TMP1, 8
3552 | beq >3
3553 |1:
3554 | cmplw RA, RC // Less args than parameters?
3555 | evldd TMP0, 0(RA)
3556 | bge >4
3557 | evstdd TISNIL, 0(RA) // Clear old fixarg slot (help the GC).
3558 | addi RA, RA, 8
3559 |2:
3560 | addic. TMP2, TMP2, -1
3561 | evstdd TMP0, 8(TMP1)
3562 | addi TMP1, TMP1, 8
3563 | bne <1
3564 |3:
3565 | ins_next2
3566 |
3567 |4: // Clear missing parameters.
3568 | evmr TMP0, TISNIL
3569 | b <2
3570 break;
3571
3572 case BC_FUNCC:
3573 case BC_FUNCCW:
3574 | // BASE = new base, RA = BASE+framesize*8, RB = CFUNC, RC = nargs*8
3575 if (op == BC_FUNCC) {
3576 | lwz TMP3, CFUNC:RB->f
3577 } else {
3578 | lwz TMP3, DISPATCH_GL(wrapf)(DISPATCH)
3579 }
3580 | add TMP1, RA, NARGS8:RC
3581 | lwz TMP2, L->maxstack
3582 | add RC, BASE, NARGS8:RC
3583 | stw BASE, L->base
3584 | cmplw TMP1, TMP2
3585 | stw RC, L->top
3586 | li_vmstate C
3587 | mtctr TMP3
3588 if (op == BC_FUNCCW) {
3589 | lwz CARG2, CFUNC:RB->f
3590 }
3591 | mr CARG1, L
3592 | bgt ->vm_growstack_c // Need to grow stack.
3593 | st_vmstate
3594 | bctrl // (lua_State *L [, lua_CFunction f])
3595 | // Returns nresults.
3596 | lwz TMP1, L->top
3597 | slwi RD, CRET1, 3
3598 | lwz BASE, L->base
3599 | li_vmstate INTERP
3600 | lwz PC, FRAME_PC(BASE) // Fetch PC of caller.
3601 | sub RA, TMP1, RD // RA = L->top - nresults*8
3602 | st_vmstate
3603 | b ->vm_returnc
3604 break;
3605
3606 /* ---------------------------------------------------------------------- */
3607
3608 default:
3609 fprintf(stderr, "Error: undefined opcode BC_%s\n", bc_names[op]);
3610 exit(2);
3611 break;
3612 }
3613}
3614
3615static int build_backend(BuildCtx *ctx)
3616{
3617 int op;
3618
3619 dasm_growpc(Dst, BC__MAX);
3620
3621 build_subroutines(ctx);
3622
3623 |.code_op
3624 for (op = 0; op < BC__MAX; op++)
3625 build_ins(ctx, (BCOp)op, op);
3626
3627 return BC__MAX;
3628}
3629
3630/* Emit pseudo frame-info for all assembler functions. */
3631static void emit_asm_debug(BuildCtx *ctx)
3632{
3633 int i;
3634 switch (ctx->mode) {
3635 case BUILD_elfasm:
3636 fprintf(ctx->fp, "\t.section .debug_frame,\"\",@progbits\n");
3637 fprintf(ctx->fp,
3638 ".Lframe0:\n"
3639 "\t.long .LECIE0-.LSCIE0\n"
3640 ".LSCIE0:\n"
3641 "\t.long 0xffffffff\n"
3642 "\t.byte 0x1\n"
3643 "\t.string \"\"\n"
3644 "\t.uleb128 0x1\n"
3645 "\t.sleb128 -4\n"
3646 "\t.byte 65\n"
3647 "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
3648 "\t.align 2\n"
3649 ".LECIE0:\n\n");
3650 fprintf(ctx->fp,
3651 ".LSFDE0:\n"
3652 "\t.long .LEFDE0-.LASFDE0\n"
3653 ".LASFDE0:\n"
3654 "\t.long .Lframe0\n"
3655 "\t.long .Lbegin\n"
3656 "\t.long %d\n"
3657 "\t.byte 0xe\n\t.uleb128 %d\n"
3658 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n",
3659 (int)ctx->codesz, CFRAME_SIZE);
3660 for (i = 14; i <= 31; i++)
3661 fprintf(ctx->fp,
3662 "\t.byte %d\n\t.uleb128 %d\n"
3663 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n",
3664 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i));
3665 fprintf(ctx->fp,
3666 "\t.align 2\n"
3667 ".LEFDE0:\n\n");
3668 fprintf(ctx->fp, "\t.section .eh_frame,\"a\",@progbits\n");
3669 fprintf(ctx->fp,
3670 ".Lframe1:\n"
3671 "\t.long .LECIE1-.LSCIE1\n"
3672 ".LSCIE1:\n"
3673 "\t.long 0\n"
3674 "\t.byte 0x1\n"
3675 "\t.string \"zPR\"\n"
3676 "\t.uleb128 0x1\n"
3677 "\t.sleb128 -4\n"
3678 "\t.byte 65\n"
3679 "\t.uleb128 6\n" /* augmentation length */
3680 "\t.byte 0x1b\n" /* pcrel|sdata4 */
3681 "\t.long lj_err_unwind_dwarf-.\n"
3682 "\t.byte 0x1b\n" /* pcrel|sdata4 */
3683 "\t.byte 0xc\n\t.uleb128 1\n\t.uleb128 0\n"
3684 "\t.align 2\n"
3685 ".LECIE1:\n\n");
3686 fprintf(ctx->fp,
3687 ".LSFDE1:\n"
3688 "\t.long .LEFDE1-.LASFDE1\n"
3689 ".LASFDE1:\n"
3690 "\t.long .LASFDE1-.Lframe1\n"
3691 "\t.long .Lbegin-.\n"
3692 "\t.long %d\n"
3693 "\t.uleb128 0\n" /* augmentation length */
3694 "\t.byte 0xe\n\t.uleb128 %d\n"
3695 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n",
3696 (int)ctx->codesz, CFRAME_SIZE);
3697 for (i = 14; i <= 31; i++)
3698 fprintf(ctx->fp,
3699 "\t.byte %d\n\t.uleb128 %d\n"
3700 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n",
3701 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i));
3702 fprintf(ctx->fp,
3703 "\t.align 2\n"
3704 ".LEFDE1:\n\n");
3705 break;
3706 default:
3707 break;
3708 }
3709}
3710
diff --git a/src/buildvm_ppcspe.h b/src/buildvm_ppcspe.h
index 257fe353..6dde1956 100644
--- a/src/buildvm_ppcspe.h
+++ b/src/buildvm_ppcspe.h
@@ -2,7 +2,7 @@
2** This file has been pre-processed with DynASM. 2** This file has been pre-processed with DynASM.
3** http://luajit.org/dynasm.html 3** http://luajit.org/dynasm.html
4** DynASM version 1.3.0, DynASM ppc version 1.3.0 4** DynASM version 1.3.0, DynASM ppc version 1.3.0
5** DO NOT EDIT! The original file is in "buildvm_ppc.dasc". 5** DO NOT EDIT! The original file is in "buildvm_ppcspe.dasc".
6*/ 6*/
7 7
8#if DASM_VERSION != 10300 8#if DASM_VERSION != 10300
@@ -6048,14 +6048,10 @@ static void emit_asm_debug(BuildCtx *ctx)
6048 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n", 6048 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n",
6049 (int)ctx->codesz, CFRAME_SIZE); 6049 (int)ctx->codesz, CFRAME_SIZE);
6050 for (i = 14; i <= 31; i++) 6050 for (i = 14; i <= 31; i++)
6051#if LJ_TARGET_PPCSPE
6052 fprintf(ctx->fp, 6051 fprintf(ctx->fp,
6053 "\t.byte %d\n\t.uleb128 %d\n" 6052 "\t.byte %d\n\t.uleb128 %d\n"
6054 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n", 6053 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n",
6055 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i)); 6054 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i));
6056#else
6057#error "missing frame info for saved registers"
6058#endif
6059 fprintf(ctx->fp, 6055 fprintf(ctx->fp,
6060 "\t.align 2\n" 6056 "\t.align 2\n"
6061 ".LEFDE0:\n\n"); 6057 ".LEFDE0:\n\n");
@@ -6089,14 +6085,10 @@ static void emit_asm_debug(BuildCtx *ctx)
6089 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n", 6085 "\t.byte 0x11\n\t.uleb128 65\n\t.sleb128 -1\n",
6090 (int)ctx->codesz, CFRAME_SIZE); 6086 (int)ctx->codesz, CFRAME_SIZE);
6091 for (i = 14; i <= 31; i++) 6087 for (i = 14; i <= 31; i++)
6092#if LJ_TARGET_PPCSPE
6093 fprintf(ctx->fp, 6088 fprintf(ctx->fp,
6094 "\t.byte %d\n\t.uleb128 %d\n" 6089 "\t.byte %d\n\t.uleb128 %d\n"
6095 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n", 6090 "\t.byte 5\n\t.uleb128 %d\n\t.uleb128 %d\n",
6096 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i)); 6091 0x80+i, 1+2*(31-i), 1200+i, 2+2*(31-i));
6097#else
6098#error "missing frame info for saved registers"
6099#endif
6100 fprintf(ctx->fp, 6092 fprintf(ctx->fp,
6101 "\t.align 2\n" 6093 "\t.align 2\n"
6102 ".LEFDE1:\n\n"); 6094 ".LEFDE1:\n\n");
generated by cgit v1.2.3-55-g6feb (git 2.39.1) at 2025-03-21 02:07:50 +0000