1 files changed, 21 insertions, 76 deletions

diff --git a/configure.ac b/configure.ac
index eca3134..6ae06a1 100644
--- a/configure.ac
+++ b/configure.ac
@@ -58,75 +58,26 @@ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 )
 CFLAGS="$save_cflags $AM_CFLAGS"
 
-AC_CHECK_FUNC(strlcpy,
-        AM_CONDITIONAL(NO_STRLCPY, false),
-        AC_DEFINE(NO_STRLCPY)
-        AM_CONDITIONAL(NO_STRLCPY, true))
-
-AC_CHECK_FUNC(strlcat,
-        AM_CONDITIONAL(NO_STRLCAT, false),
-        AC_DEFINE(NO_STRLCAT)
-        AM_CONDITIONAL(NO_STRLCAT, true))
-
-AC_CHECK_FUNC(strndup,
-        AM_CONDITIONAL(NO_STRNDUP, false),
-        AC_DEFINE(NO_STRNDUP)
-        AM_CONDITIONAL(NO_STRNDUP, true))
-
-AC_CHECK_FUNC(strnlen,
-        AM_CONDITIONAL(NO_STRNLEN, false),
-        AC_DEFINE(NO_STRNLEN)
-        AM_CONDITIONAL(NO_STRNLEN, true))
-
-AC_CHECK_FUNC(asprintf,
-        AM_CONDITIONAL(NO_ASPRINTF, false),
-        AC_DEFINE(NO_ASPRINTF)
-        AM_CONDITIONAL(NO_ASPRINTF, true))
-
-AC_CHECK_FUNC(reallocarray,
-        AM_CONDITIONAL(NO_REALLOCARRAY, false),
-        AC_DEFINE(NO_REALLOCARRAY)
-        AM_CONDITIONAL(NO_REALLOCARRAY, true))
-
-AC_CHECK_FUNC(timingsafe_bcmp,
-        AM_CONDITIONAL(NO_TIMINGSAFE_BCMP, false),
-        AC_DEFINE(NO_TIMINGSAFE_BCMP)
-        AM_CONDITIONAL(NO_TIMINGSAFE_BCMP, true))
-
-AC_CHECK_FUNC(timingsafe_memcmp,
-        AM_CONDITIONAL(NO_TIMINGSAFE_MEMCMP, false),
-        AC_DEFINE(NO_TIMINGSAFE_MEMCMP)
-        AM_CONDITIONAL(NO_TIMINGSAFE_MEMCMP, true))
-
-AC_CHECK_FUNC(arc4random_buf,
-        AM_CONDITIONAL(NO_ARC4RANDOM_BUF, false),
-        AC_DEFINE(NO_ARC4RANDOM_BUF)
-        AM_CONDITIONAL(NO_ARC4RANDOM_BUF, true))
-
-AC_CHECK_FUNC(getentropy,
-        AM_CONDITIONAL(NO_GETENTROPY, false),
-        AC_DEFINE(NO_GETENTROPY)
-        AM_CONDITIONAL(NO_GETENTROPY, true))
-
-AC_CHECK_FUNC(issetugid,
-        AM_CONDITIONAL(NO_ISSETUGID, false),
-        AC_DEFINE(NO_ISSETUGID)
-        AM_CONDITIONAL(NO_ISSETUGID, true))
-
-AC_CHECK_FUNC(strtonum,
-        AM_CONDITIONAL(NO_STRTONUM, false),
-        AC_DEFINE(NO_STRTONUM)
-        AM_CONDITIONAL(NO_STRTONUM, true))
-
-AC_CHECK_FUNC(memmem,
-        AM_CONDITIONAL(NO_MEMMEM, false),
-        AC_DEFINE(NO_MEMMEM)
-        AM_CONDITIONAL(NO_MEMMEM, true))
-
-AC_CHECK_FUNC(explicit_bzero,
-        AM_CONDITIONAL(NO_EXPLICIT_BZERO, false),
-        AC_DEFINE(NO_EXPLICIT_BZERO)
-        AM_CONDITIONAL(NO_EXPLICIT_BZERO, true))
+AC_CHECK_FUNCS([arc4random_buf asprintf explicit_bzero funopen getauxval])
+AC_CHECK_FUNCS([getentropy issetugid memmem reallocarray])
+AC_CHECK_FUNCS([strlcat strlcpy strndup strnlen strtonum])
+AC_CHECK_FUNCS([timingsafe_bcmp timingsafe_memcmp])
+
+# Share test results with automake
+AM_CONDITIONAL([HAVE_ARC4RANDOM_BUF], [test "x$ac_cv_func_arc4random_buf" = xyes])
+AM_CONDITIONAL([HAVE_ASPRINTF], [test "x$ac_cv_func_asprintf" = xyes])
+AM_CONDITIONAL([HAVE_EXPLICIT_BZERO], [test "x$ac_cv_func_explicit_bzero" = xyes])
+AM_CONDITIONAL([HAVE_GETENTROPY], [test "x$ac_cv_func_getentropy" = xyes])
+AM_CONDITIONAL([HAVE_ISSETUGID], [test "x$ac_cv_func_issetugid" = xyes])
+AM_CONDITIONAL([HAVE_MEMMEM], [test "x$ac_cv_func_memmem" = xyes])
+AM_CONDITIONAL([HAVE_REALLOCARRAY], [test "x$ac_cv_func_reallocarray" = xyes])
+AM_CONDITIONAL([HAVE_STRLCAT], [test "x$ac_cv_func_strlcat" = xyes])
+AM_CONDITIONAL([HAVE_STRLCPY], [test "x$ac_cv_func_strlcpy" = xyes])
+AM_CONDITIONAL([HAVE_STRNDUP], [test "x$ac_cv_func_strndup" = xyes])
+AM_CONDITIONAL([HAVE_STRNLEN], [test "x$ac_cv_func_strnlen" = xyes])
+AM_CONDITIONAL([HAVE_STRTONUM], [test "x$ac_cv_func_strtonum" = xyes])
+AM_CONDITIONAL([HAVE_TIMINGSAFE_BCMP], [test "x$ac_cv_func_timingsafe_bcmp" = xyes])
+AM_CONDITIONAL([HAVE_TIMINGSAFE_MEMCMP], [test "x$ac_cv_func_timingsafe_memcmp" = xyes])
 
 AC_CACHE_CHECK([whether va_copy exists], ac_cv_have_va_copy, [
         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
@@ -153,13 +104,7 @@ if test "x$ac_cv_have___va_copy" = "xyes" ; then
         AC_DEFINE([HAVE___VA_COPY], [1], [Define if __va_copy exists])
 fi
 
-AC_CHECK_FUNC(getauxval, AC_DEFINE(HAVE_GETAUXVAL))
-
-AC_CHECK_FUNC(funopen, AC_DEFINE(HAVE_FUNOPEN))
-
-AC_CHECK_HEADER(sys/sysctl.h, AC_DEFINE(HAVE_SYS_SYSCTL_H))
-
-AC_CHECK_HEADER(err.h, AC_DEFINE(HAVE_ERR_H))
+AC_CHECK_HEADERS([sys/sysctl.h err.h])
 
 AC_ARG_WITH([openssldir],
         AS_HELP_STRING([--with-openssldir], [Set the default openssl directory]),