blob: d81959cc05518cac934fd55f22c3a8fadc836520 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
@setlocal
@pushd %~dp0
@set _C=Debug
@set _L=%~dp0..\..\..\build\logs
:parse_args
@if /i "%1"=="release" set _C=Release
@if /i "%1"=="inc" set _INC=1
@if /i "%1"=="clean" set _CLEAN=1
@if not "%1"=="" shift & goto parse_args
@set _B=%~dp0..\..\..\build\NetFx.wixext\%_C%
:: Clean
@if "%_INC%"=="" call :clean
@if NOT "%_CLEAN%"=="" goto :end
@echo NetFx.wixext build %_C%
:: Restore
nuget restore netcoresearch\packages.config || exit /b
:: Build
msbuild -Restore -p:Configuration=%_C% -tl -nologo -warnaserror -bl:%_L%\ext_netfx_build.binlog || exit /b
:: Test
dotnet test ^
%_B%\net6.0\WixToolsetTest.NetFx.dll ^
--nologo -l "trx;LogFileName=%_L%\TestResults\netfx.wixext.trx" || exit /b
:: Pack
msbuild -t:Pack -p:Configuration=%_C% -tl -nologo -warnaserror -p:NoBuild=true wixext\WixToolset.Netfx.wixext.csproj || exit /b
@goto :end
:clean
@rd /s/q "..\..\build\NetFx.wixext" 2> nul
@del "..\..\build\artifacts\WixToolset.NetFx.wixext.*.nupkg" 2> nul
@del "%_L%\ext_netfx_build.binlog" 2> nul
@del "%_L%\TestResults\netfx.wixext.trx" 2> nul
@rd /s/q "%USERPROFILE%\.nuget\packages\wixtoolset.netfx.wixext" 2> nul
@exit /b
:end
@popd
@endlocal
|
