aboutsummaryrefslogtreecommitdiff
path: root/old
diff options
context:
space:
mode:
authorMark Adler <madler@alumni.caltech.edu>2011-09-09 23:27:26 -0700
committerMark Adler <madler@alumni.caltech.edu>2011-09-09 23:27:26 -0700
commit7751bd4c715ea8478113e34b49b5a794a4642e8e (patch)
tree537ba82b3780f933c2f17028febd6fe3a2332190 /old
parente0ff940e1adb68d3575705ebf1546d9f07ad3b4a (diff)
downloadzlib-7751bd4c715ea8478113e34b49b5a794a4642e8e.tar.gz
zlib-7751bd4c715ea8478113e34b49b5a794a4642e8e.tar.bz2
zlib-7751bd4c715ea8478113e34b49b5a794a4642e8e.zip
zlib 1.2.3.9v1.2.3.9
Diffstat (limited to 'old')
-rw-r--r--old/as400/bndsrc132
-rw-r--r--old/as400/compile.clp123
-rw-r--r--old/as400/readme.txt111
-rw-r--r--old/as400/zlib.inc331
4 files changed, 697 insertions, 0 deletions
diff --git a/old/as400/bndsrc b/old/as400/bndsrc
new file mode 100644
index 0000000..9cf94bb
--- /dev/null
+++ b/old/as400/bndsrc
@@ -0,0 +1,132 @@
1STRPGMEXP PGMLVL(*CURRENT) SIGNATURE('ZLIB')
2
3/*@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@*/
4/* Version 1.1.3 entry points. */
5/*@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@*/
6
7/********************************************************************/
8/* *MODULE ADLER32 ZLIB 01/02/01 00:15:09 */
9/********************************************************************/
10
11 EXPORT SYMBOL("adler32")
12
13/********************************************************************/
14/* *MODULE COMPRESS ZLIB 01/02/01 00:15:09 */
15/********************************************************************/
16
17 EXPORT SYMBOL("compress")
18 EXPORT SYMBOL("compress2")
19
20/********************************************************************/
21/* *MODULE CRC32 ZLIB 01/02/01 00:15:09 */
22/********************************************************************/
23
24 EXPORT SYMBOL("crc32")
25 EXPORT SYMBOL("get_crc_table")
26
27/********************************************************************/
28/* *MODULE DEFLATE ZLIB 01/02/01 00:15:09 */
29/********************************************************************/
30
31 EXPORT SYMBOL("deflate")
32 EXPORT SYMBOL("deflateEnd")
33 EXPORT SYMBOL("deflateSetDictionary")
34 EXPORT SYMBOL("deflateCopy")
35 EXPORT SYMBOL("deflateReset")
36 EXPORT SYMBOL("deflateParams")
37 EXPORT SYMBOL("deflatePrime")
38 EXPORT SYMBOL("deflateInit_")
39 EXPORT SYMBOL("deflateInit2_")
40
41/********************************************************************/
42/* *MODULE GZIO ZLIB 01/02/01 00:15:09 */
43/********************************************************************/
44
45 EXPORT SYMBOL("gzopen")
46 EXPORT SYMBOL("gzdopen")
47 EXPORT SYMBOL("gzsetparams")
48 EXPORT SYMBOL("gzread")
49 EXPORT SYMBOL("gzwrite")
50 EXPORT SYMBOL("gzprintf")
51 EXPORT SYMBOL("gzputs")
52 EXPORT SYMBOL("gzgets")
53 EXPORT SYMBOL("gzputc")
54 EXPORT SYMBOL("gzgetc")
55 EXPORT SYMBOL("gzflush")
56 EXPORT SYMBOL("gzseek")
57 EXPORT SYMBOL("gzrewind")
58 EXPORT SYMBOL("gztell")
59 EXPORT SYMBOL("gzeof")
60 EXPORT SYMBOL("gzclose")
61 EXPORT SYMBOL("gzerror")
62
63/********************************************************************/
64/* *MODULE INFLATE ZLIB 01/02/01 00:15:09 */
65/********************************************************************/
66
67 EXPORT SYMBOL("inflate")
68 EXPORT SYMBOL("inflateEnd")
69 EXPORT SYMBOL("inflateSetDictionary")
70 EXPORT SYMBOL("inflateSync")
71 EXPORT SYMBOL("inflateReset")
72 EXPORT SYMBOL("inflateInit_")
73 EXPORT SYMBOL("inflateInit2_")
74 EXPORT SYMBOL("inflateSyncPoint")
75
76/********************************************************************/
77/* *MODULE UNCOMPR ZLIB 01/02/01 00:15:09 */
78/********************************************************************/
79
80 EXPORT SYMBOL("uncompress")
81
82/********************************************************************/
83/* *MODULE ZUTIL ZLIB 01/02/01 00:15:09 */
84/********************************************************************/
85
86 EXPORT SYMBOL("zlibVersion")
87 EXPORT SYMBOL("zError")
88
89/*@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@*/
90/* Version 1.2.1 additional entry points. */
91/*@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@*/
92
93/********************************************************************/
94/* *MODULE COMPRESS ZLIB 01/02/01 00:15:09 */
95/********************************************************************/
96
97 EXPORT SYMBOL("compressBound")
98
99/********************************************************************/
100/* *MODULE DEFLATE ZLIB 01/02/01 00:15:09 */
101/********************************************************************/
102
103 EXPORT SYMBOL("deflateBound")
104
105/********************************************************************/
106/* *MODULE GZIO ZLIB 01/02/01 00:15:09 */
107/********************************************************************/
108
109 EXPORT SYMBOL("gzungetc")
110 EXPORT SYMBOL("gzclearerr")
111
112/********************************************************************/
113/* *MODULE INFBACK ZLIB 01/02/01 00:15:09 */
114/********************************************************************/
115
116 EXPORT SYMBOL("inflateBack")
117 EXPORT SYMBOL("inflateBackEnd")
118 EXPORT SYMBOL("inflateBackInit_")
119
120/********************************************************************/
121/* *MODULE INFLATE ZLIB 01/02/01 00:15:09 */
122/********************************************************************/
123
124 EXPORT SYMBOL("inflateCopy")
125
126/********************************************************************/
127/* *MODULE ZUTIL ZLIB 01/02/01 00:15:09 */
128/********************************************************************/
129
130 EXPORT SYMBOL("zlibCompileFlags")
131
132ENDPGMEXP
diff --git a/old/as400/compile.clp b/old/as400/compile.clp
new file mode 100644
index 0000000..8554951
--- /dev/null
+++ b/old/as400/compile.clp
@@ -0,0 +1,123 @@
1/******************************************************************************/
2/* */
3/* ZLIB */
4/* */
5/* Compile sources into modules and link them into a service program. */
6/* */
7/******************************************************************************/
8
9 PGM
10
11/* Configuration adjustable parameters. */
12
13 DCL VAR(&SRCLIB) TYPE(*CHAR) LEN(10) +
14 VALUE('ZLIB') /* Source library. */
15 DCL VAR(&SRCFILE) TYPE(*CHAR) LEN(10) +
16 VALUE('SOURCES') /* Source member file. */
17 DCL VAR(&CTLFILE) TYPE(*CHAR) LEN(10) +
18 VALUE('TOOLS') /* Control member file. */
19
20 DCL VAR(&MODLIB) TYPE(*CHAR) LEN(10) +
21 VALUE('ZLIB') /* Module library. */
22
23 DCL VAR(&SRVLIB) TYPE(*CHAR) LEN(10) +
24 VALUE('LGPL') /* Service program library. */
25
26 DCL VAR(&CFLAGS) TYPE(*CHAR) +
27 VALUE('OPTIMIZE(40)') /* Compile options. */
28
29
30/* Working storage. */
31
32 DCL VAR(&CMDLEN) TYPE(*DEC) LEN(15 5) VALUE(300) /* Command length. */
33 DCL VAR(&CMD) TYPE(*CHAR) LEN(512)
34
35
36/* Compile sources into modules. */
37
38 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
39 '/ADLER32) SRCFILE(' *TCAT +
40 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
41 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
42 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
43
44 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
45 '/COMPRESS) SRCFILE(' *TCAT +
46 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
47 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
48 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
49
50 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
51 '/CRC32) SRCFILE(' *TCAT +
52 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
53 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
54 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
55
56 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
57 '/DEFLATE) SRCFILE(' *TCAT +
58 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
59 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
60 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
61
62 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
63 '/GZIO) SRCFILE(' *TCAT +
64 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
65 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
66 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
67
68 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
69 '/INFBACK) SRCFILE(' *TCAT +
70 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
71 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
72 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
73
74 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
75 '/INFFAST) SRCFILE(' *TCAT +
76 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
77 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
78 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
79
80 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
81 '/INFLATE) SRCFILE(' *TCAT +
82 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
83 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
84 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
85
86 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
87 '/INFTREES) SRCFILE(' *TCAT +
88 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
89 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
90 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
91
92 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
93 '/TREES) SRCFILE(' *TCAT +
94 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
95 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
96 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
97
98 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
99 '/UNCOMPR) SRCFILE(' *TCAT +
100 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
101 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
102 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
103
104 CHGVAR VAR(&CMD) VALUE('CRTCMOD MODULE(' *TCAT &MODLIB *TCAT +
105 '/ZUTIL) SRCFILE(' *TCAT +
106 &SRCLIB *TCAT '/' *TCAT &SRCFILE *TCAT +
107 ') SYSIFCOPT(*IFSIO)' *BCAT &CFLAGS)
108 CALL PGM(QCMDEXC) PARM(&CMD &CMDLEN)
109
110
111/* Link modules into a service program. */
112
113 CRTSRVPGM SRVPGM(&SRVLIB/ZLIB) +
114 MODULE(&MODLIB/ADLER32 &MODLIB/COMPRESS +
115 &MODLIB/CRC32 &MODLIB/DEFLATE +
116 &MODLIB/GZIO &MODLIB/INFBACK +
117 &MODLIB/INFFAST &MODLIB/INFLATE +
118 &MODLIB/INFTREES &MODLIB/TREES +
119 &MODLIB/UNCOMPR &MODLIB/ZUTIL) +
120 SRCFILE(&SRCLIB/&CTLFILE) SRCMBR(BNDSRC) +
121 TEXT('ZLIB 1.2.3') TGTRLS(V4R4M0)
122
123 ENDPGM
diff --git a/old/as400/readme.txt b/old/as400/readme.txt
new file mode 100644
index 0000000..beae13f
--- /dev/null
+++ b/old/as400/readme.txt
@@ -0,0 +1,111 @@
1 ZLIB version 1.2.3 for AS400 installation instructions
2
3I) From an AS400 *SAVF file:
4
51) Unpacking archive to an AS400 save file
6
7On the AS400:
8
9_ Create the ZLIB AS400 library:
10
11 CRTLIB LIB(ZLIB) TYPE(PROD) TEXT('ZLIB compression API library')
12
13_ Create a work save file, for example:
14
15 CRTSAVF FILE(ZLIB/ZLIBSAVF)
16
17On a PC connected to the target AS400:
18
19_ Unpack the save file image to a PC file "ZLIBSAVF"
20_ Upload this file into the save file on the AS400, for example
21 using ftp in BINARY mode.
22
23
242) Populating the ZLIB AS400 source library
25
26On the AS400:
27
28_ Extract the saved objects into the ZLIB AS400 library using:
29
30RSTOBJ OBJ(*ALL) SAVLIB(ZLIB) DEV(*SAVF) SAVF(ZLIB/ZLIBSAVF) RSTLIB(ZLIB)
31
32
333) Customize installation:
34
35_ Edit CL member ZLIB/TOOLS(COMPILE) and change parameters if needed,
36 according to the comments.
37
38_ Compile this member with:
39
40 CRTCLPGM PGM(ZLIB/COMPILE) SRCFILE(ZLIB/TOOLS) SRCMBR(COMPILE)
41
42
434) Compile and generate the service program:
44
45_ This can now be done by executing:
46
47 CALL PGM(ZLIB/COMPILE)
48
49
50
51II) From the original source distribution:
52
531) On the AS400, create the source library:
54
55 CRTLIB LIB(ZLIB) TYPE(PROD) TEXT('ZLIB compression API library')
56
572) Create the source files:
58
59 CRTSRCPF FILE(ZLIB/SOURCES) RCDLEN(112) TEXT('ZLIB library modules')
60 CRTSRCPF FILE(ZLIB/H) RCDLEN(112) TEXT('ZLIB library includes')
61 CRTSRCPF FILE(ZLIB/TOOLS) RCDLEN(112) TEXT('ZLIB library control utilities')
62
633) From the machine hosting the distribution files, upload them (with
64 FTP in text mode, for example) according to the following table:
65
66 Original AS400 AS400 AS400 AS400
67 file file member type description
68 SOURCES Original ZLIB C subprogram sources
69 adler32.c ADLER32 C ZLIB - Compute the Adler-32 checksum of a dta strm
70 compress.c COMPRESS C ZLIB - Compress a memory buffer
71 crc32.c CRC32 C ZLIB - Compute the CRC-32 of a data stream
72 deflate.c DEFLATE C ZLIB - Compress data using the deflation algorithm
73 gzio.c GZIO C ZLIB - IO on .gz files
74 infback.c INFBACK C ZLIB - Inflate using a callback interface
75 inffast.c INFFAST C ZLIB - Fast proc. literals & length/distance pairs
76 inflate.c INFLATE C ZLIB - Interface to inflate modules
77 inftrees.c INFTREES C ZLIB - Generate Huffman trees for efficient decode
78 trees.c TREES C ZLIB - Output deflated data using Huffman coding
79 uncompr.c UNCOMPR C ZLIB - Decompress a memory buffer
80 zutil.c ZUTIL C ZLIB - Target dependent utility functions
81 H Original ZLIB C and ILE/RPG include files
82 crc32.h CRC32 C ZLIB - CRC32 tables
83 deflate.h DEFLATE C ZLIB - Internal compression state
84 inffast.h INFFAST C ZLIB - Header to use inffast.c
85 inffixed.h INFFIXED C ZLIB - Table for decoding fixed codes
86 inflate.h INFLATE C ZLIB - Internal inflate state definitions
87 inftrees.h INFTREES C ZLIB - Header to use inftrees.c
88 trees.h TREES C ZLIB - Created automatically with -DGEN_TREES_H
89 zconf.h ZCONF C ZLIB - Compression library configuration
90 zlib.h ZLIB C ZLIB - Compression library C user interface
91 as400/zlib.inc ZLIB.INC RPGLE ZLIB - Compression library ILE RPG user interface
92 zutil.h ZUTIL C ZLIB - Internal interface and configuration
93 TOOLS Building source software & AS/400 README
94 as400/bndsrc BNDSRC Entry point exportation list
95 as400/compile.clp COMPILE CLP Compile sources & generate service program
96 as400/readme.txt README TXT Installation instructions
97
984) Continue as in I)3).
99
100
101
102
103Notes: For AS400 ILE RPG programmers, a /copy member defining the ZLIB
104 API prototypes for ILE RPG can be found in ZLIB/H(ZLIB.INC).
105 Please read comments in this member for more information.
106
107 Remember that most foreign textual data are ASCII coded: this
108 implementation does not handle conversion from/to ASCII, so
109 text data code conversions must be done explicitely.
110
111 Always open zipped files in binary mode.
diff --git a/old/as400/zlib.inc b/old/as400/zlib.inc
new file mode 100644
index 0000000..a9a4f5c
--- /dev/null
+++ b/old/as400/zlib.inc
@@ -0,0 +1,331 @@
1 * ZLIB.INC - Interface to the general purpose compression library
2 *
3 * ILE RPG400 version by Patrick Monnerat, DATASPHERE.
4 * Version 1.2.3.9
5 *
6 *
7 * WARNING:
8 * Procedures inflateInit(), inflateInit2(), deflateInit(),
9 * deflateInit2() and inflateBackInit() need to be called with
10 * two additional arguments:
11 * the package version string and the stream control structure.
12 * size. This is needed because RPG lacks some macro feature.
13 * Call these procedures as:
14 * inflateInit(...: ZLIB_VERSION: %size(z_stream))
15 *
16 /if not defined(ZLIB_H_)
17 /define ZLIB_H_
18 *
19 **************************************************************************
20 * Constants
21 **************************************************************************
22 *
23 * Versioning information.
24 *
25 D ZLIB_VERSION C '1.2.3.9'
26 D ZLIB_VERNUM C X'1239'
27 *
28 * Other equates.
29 *
30 D Z_NO_FLUSH C 0
31 D Z_SYNC_FLUSH C 2
32 D Z_FULL_FLUSH C 3
33 D Z_FINISH C 4
34 D Z_BLOCK C 5
35 *
36 D Z_OK C 0
37 D Z_STREAM_END C 1
38 D Z_NEED_DICT C 2
39 D Z_ERRNO C -1
40 D Z_STREAM_ERROR C -2
41 D Z_DATA_ERROR C -3
42 D Z_MEM_ERROR C -4
43 D Z_BUF_ERROR C -5
44 DZ_VERSION_ERROR C -6
45 *
46 D Z_NO_COMPRESSION...
47 D C 0
48 D Z_BEST_SPEED C 1
49 D Z_BEST_COMPRESSION...
50 D C 9
51 D Z_DEFAULT_COMPRESSION...
52 D C -1
53 *
54 D Z_FILTERED C 1
55 D Z_HUFFMAN_ONLY C 2
56 D Z_RLE C 3
57 D Z_DEFAULT_STRATEGY...
58 D C 0
59 *
60 D Z_BINARY C 0
61 D Z_ASCII C 1
62 D Z_UNKNOWN C 2
63 *
64 D Z_DEFLATED C 8
65 *
66 D Z_NULL C 0
67 *
68 **************************************************************************
69 * Types
70 **************************************************************************
71 *
72 D z_streamp S * Stream struct ptr
73 D gzFile S * File pointer
74 D z_off_t S 10i 0 Stream offsets
75 *
76 **************************************************************************
77 * Structures
78 **************************************************************************
79 *
80 * The GZIP encode/decode stream support structure.
81 *
82 D z_stream DS align based(z_streamp)
83 D zs_next_in * Next input byte
84 D zs_avail_in 10U 0 Byte cnt at next_in
85 D zs_total_in 10U 0 Total bytes read
86 D zs_next_out * Output buffer ptr
87 D zs_avail_out 10U 0 Room left @ next_out
88 D zs_total_out 10U 0 Total bytes written
89 D zs_msg * Last errmsg or null
90 D zs_state * Internal state
91 D zs_zalloc * procptr Int. state allocator
92 D zs_free * procptr Int. state dealloc.
93 D zs_opaque * Private alloc. data
94 D zs_data_type 10i 0 ASC/BIN best guess
95 D zs_adler 10u 0 Uncompr. adler32 val
96 D 10U 0 Reserved
97 D 10U 0 Ptr. alignment
98 *
99 **************************************************************************
100 * Utility function prototypes
101 **************************************************************************
102 *
103 D compress PR 10I 0 extproc('compress')
104 D dest 32767 options(*varsize) Destination buffer
105 D destLen 10U 0 Destination length
106 D source 32767 const options(*varsize) Source buffer
107 D sourceLen 10u 0 value Source length
108 *
109 D compress2 PR 10I 0 extproc('compress2')
110 D dest 32767 options(*varsize) Destination buffer
111 D destLen 10U 0 Destination length
112 D source 32767 const options(*varsize) Source buffer
113 D sourceLen 10U 0 value Source length
114 D level 10I 0 value Compression level
115 *
116 D compressBound PR 10U 0 extproc('compressBound')
117 D sourceLen 10U 0 value
118 *
119 D uncompress PR 10I 0 extproc('uncompress')
120 D dest 32767 options(*varsize) Destination buffer
121 D destLen 10U 0 Destination length
122 D source 32767 const options(*varsize) Source buffer
123 D sourceLen 10U 0 value Source length
124 *
125 D gzopen PR extproc('gzopen')
126 D like(gzFile)
127 D path * value options(*string) File pathname
128 D mode * value options(*string) Open mode
129 *
130 D gzdopen PR extproc('gzdopen')
131 D like(gzFile)
132 D fd 10i 0 value File descriptor
133 D mode * value options(*string) Open mode
134 *
135 D gzsetparams PR 10I 0 extproc('gzsetparams')
136 D file value like(gzFile) File pointer
137 D level 10I 0 value
138 D strategy 10i 0 value
139 *
140 D gzread PR 10I 0 extproc('gzread')
141 D file value like(gzFile) File pointer
142 D buf 32767 options(*varsize) Buffer
143 D len 10u 0 value Buffer length
144 *
145 D gzwrite PR 10I 0 extproc('gzwrite')
146 D file value like(gzFile) File pointer
147 D buf 32767 const options(*varsize) Buffer
148 D len 10u 0 value Buffer length
149 *
150 D gzputs PR 10I 0 extproc('gzputs')
151 D file value like(gzFile) File pointer
152 D s * value options(*string) String to output
153 *
154 D gzgets PR * extproc('gzgets')
155 D file value like(gzFile) File pointer
156 D buf 32767 options(*varsize) Read buffer
157 D len 10i 0 value Buffer length
158 *
159 D gzflush PR 10i 0 extproc('gzflush')
160 D file value like(gzFile) File pointer
161 D flush 10I 0 value Type of flush
162 *
163 D gzseek PR extproc('gzseek')
164 D like(z_off_t)
165 D file value like(gzFile) File pointer
166 D offset value like(z_off_t) Offset
167 D whence 10i 0 value Origin
168 *
169 D gzrewind PR 10i 0 extproc('gzrewind')
170 D file value like(gzFile) File pointer
171 *
172 D gztell PR extproc('gztell')
173 D like(z_off_t)
174 D file value like(gzFile) File pointer
175 *
176 D gzeof PR 10i 0 extproc('gzeof')
177 D file value like(gzFile) File pointer
178 *
179 D gzclose PR 10i 0 extproc('gzclose')
180 D file value like(gzFile) File pointer
181 *
182 D gzerror PR * extproc('gzerror') Error string
183 D file value like(gzFile) File pointer
184 D errnum 10I 0 Error code
185 *
186 D gzclearerr PR extproc('gzclearerr')
187 D file value like(gzFile) File pointer
188 *
189 **************************************************************************
190 * Basic function prototypes
191 **************************************************************************
192 *
193 D zlibVersion PR * extproc('zlibVersion') Version string
194 *
195 D deflateInit PR 10I 0 extproc('deflateInit_') Init. compression
196 D strm like(z_stream) Compression stream
197 D level 10I 0 value Compression level
198 D version * value options(*string) Version string
199 D stream_size 10i 0 value Stream struct. size
200 *
201 D deflate PR 10I 0 extproc('deflate') Compress data
202 D strm like(z_stream) Compression stream
203 D flush 10I 0 value Flush type required
204 *
205 D deflateEnd PR 10I 0 extproc('deflateEnd') Termin. compression
206 D strm like(z_stream) Compression stream
207 *
208 D inflateInit PR 10I 0 extproc('inflateInit_') Init. expansion
209 D strm like(z_stream) Expansion stream
210 D version * value options(*string) Version string
211 D stream_size 10i 0 value Stream struct. size
212 *
213 D inflate PR 10I 0 extproc('inflate') Expand data
214 D strm like(z_stream) Expansion stream
215 D flush 10I 0 value Flush type required
216 *
217 D inflateEnd PR 10I 0 extproc('inflateEnd') Termin. expansion
218 D strm like(z_stream) Expansion stream
219 *
220 **************************************************************************
221 * Advanced function prototypes
222 **************************************************************************
223 *
224 D deflateInit2 PR 10I 0 extproc('deflateInit2_') Init. compression
225 D strm like(z_stream) Compression stream
226 D level 10I 0 value Compression level
227 D method 10I 0 value Compression method
228 D windowBits 10I 0 value log2(window size)
229 D memLevel 10I 0 value Mem/cmpress tradeoff
230 D strategy 10I 0 value Compression stategy
231 D version * value options(*string) Version string
232 D stream_size 10i 0 value Stream struct. size
233 *
234 D deflateSetDictionary...
235 D PR 10I 0 extproc('deflateSetDictionary') Init. dictionary
236 D strm like(z_stream) Compression stream
237 D dictionary 32767 const options(*varsize) Dictionary bytes
238 D dictLength 10U 0 value Dictionary length
239 *
240 D deflateCopy PR 10I 0 extproc('deflateCopy') Compress strm 2 strm
241 D dest like(z_stream) Destination stream
242 D source like(z_stream) Source stream
243 *
244 D deflateReset PR 10I 0 extproc('deflateReset') End and init. stream
245 D strm like(z_stream) Compression stream
246 *
247 D deflateParams PR 10I 0 extproc('deflateParams') Change level & strat
248 D strm like(z_stream) Compression stream
249 D level 10I 0 value Compression level
250 D strategy 10I 0 value Compression stategy
251 *
252 D deflateBound PR 10U 0 extproc('deflateBound') Change level & strat
253 D strm like(z_stream) Compression stream
254 D sourcelen 10U 0 value Compression level
255 *
256 D deflatePrime PR 10I 0 extproc('deflatePrime') Change level & strat
257 D strm like(z_stream) Compression stream
258 D bits 10I 0 value Number of bits to insert
259 D value 10I 0 value Bits to insert
260 *
261 D inflateInit2 PR 10I 0 extproc('inflateInit2_') Init. expansion
262 D strm like(z_stream) Expansion stream
263 D windowBits 10I 0 value log2(window size)
264 D version * value options(*string) Version string
265 D stream_size 10i 0 value Stream struct. size
266 *
267 D inflateSetDictionary...
268 D PR 10I 0 extproc('inflateSetDictionary') Init. dictionary
269 D strm like(z_stream) Expansion stream
270 D dictionary 32767 const options(*varsize) Dictionary bytes
271 D dictLength 10U 0 value Dictionary length
272 *
273 D inflateSync PR 10I 0 extproc('inflateSync') Sync. expansion
274 D strm like(z_stream) Expansion stream
275 *
276 D inflateCopy PR 10I 0 extproc('inflateCopy')
277 D dest like(z_stream) Destination stream
278 D source like(z_stream) Source stream
279 *
280 D inflateReset PR 10I 0 extproc('inflateReset') End and init. stream
281 D strm like(z_stream) Expansion stream
282 *
283 D inflateBackInit...
284 D PR 10I 0 extproc('inflateBackInit_')
285 D strm like(z_stream) Expansion stream
286 D windowBits 10I 0 value Log2(buffer size)
287 D window 32767 options(*varsize) Buffer
288 D version * value options(*string) Version string
289 D stream_size 10i 0 value Stream struct. size
290 *
291 D inflateBack PR 10I 0 extproc('inflateBack')
292 D strm like(z_stream) Expansion stream
293 D in * value procptr Input function
294 D in_desc * value Input descriptor
295 D out * value procptr Output function
296 D out_desc * value Output descriptor
297 *
298 D inflateBackEnd PR 10I 0 extproc('inflateBackEnd')
299 D strm like(z_stream) Expansion stream
300 *
301 D zlibCompileFlags...
302 D PR 10U 0 extproc('zlibCompileFlags')
303 *
304 **************************************************************************
305 * Checksum function prototypes
306 **************************************************************************
307 *
308 D adler32 PR 10U 0 extproc('adler32') New checksum
309 D adler 10U 0 value Old checksum
310 D buf 32767 const options(*varsize) Bytes to accumulate
311 D len 10U 0 value Buffer length
312 *
313 D crc32 PR 10U 0 extproc('crc32') New checksum
314 D crc 10U 0 value Old checksum
315 D buf 32767 const options(*varsize) Bytes to accumulate
316 D len 10U 0 value Buffer length
317 *
318 **************************************************************************
319 * Miscellaneous function prototypes
320 **************************************************************************
321 *
322 D zError PR * extproc('zError') Error string
323 D err 10I 0 value Error code
324 *
325 D inflateSyncPoint...
326 D PR 10I 0 extproc('inflateSyncPoint')
327 D strm like(z_stream) Expansion stream
328 *
329 D get_crc_table PR * extproc('get_crc_table') Ptr to ulongs
330 *
331 /endif
generated by cgit v1.2.3-55-g6feb (git 2.39.1) at 2025-03-15 19:38:18 +0000